Testing/CMakeLists.txt

   1 # CMakeLists for Testing purpose
   2 # Cxx file that need a file to run should be place aproprietly
   3
   4 SET(CXX_TEST_PATH ${EXECUTABLE_OUTPUT_PATH})
   5
   6 SET(GDCM_TESTS ${CXX_TEST_PATH}/gdcmTests)
   7
   8 # add test that does not require data:
   9 # They usally return if no argument is given
  10 SET(TEST_SOURCES
  11   TestUtil.cxx
  12   TestBug.cxx
  13   TestHash.cxx
  14   TestTS.cxx
  15   TestVR.cxx
  16   TestDictGroupName.cxx
  17   TestDict.cxx
  18   TestWriteSimple.cxx
  19   TestImageSet.cxx
  20   TestDicomDirElement.cxx
  21   TestDicomString.cxx
  22 )
  23
  24 # add tests that require data
  25 IF (GDCM_DATA_ROOT)
  26   SET(TEST_SOURCES ${TEST_SOURCES}
  27     TestFileAccessors.cxx
  28     TestMakeIcon.cxx
  29     TestPrintAllDocument.cxx         # includes generated gdcmDataImages.h
  30     TestAllEntryVerify.cxx           # includes generated gdcmDataImages.h
  31     TestAllReadCompareDicom.cxx      # includes generated gdcmDataImages.h
  32     TestReadWriteReadCompare.cxx     # includes generated gdcmDataImages.h
  33     #TestCopyDicom.cxx                # includes generated gdcmDataImages.h
  34     TestCopyRescaleDicom.cxx         # includes generated gdcmDataImages.h
  35     #TestChangeHeader.cxx
  36     TestAnonymize.cxx
  37     TestDirList.cxx
  38     TestDicomDir.cxx                 # require DICOMDIR
  39     TestBuildUpDicomDir.cxx          # writes a file named "NewDICOMDIR"
  40     TestMakeDicomDir.cxx             # writes a file named "NewDICOMDIR"
  41     TestSerieHelper.cxx              # uses gdcmData as a default root directory
  42   )
  43   # add test that require VTK:
  44   IF(GDCM_VTK)
  45     # Include the VTK library
  46     INCLUDE(${VTK_USE_FILE})
  47
  48     INCLUDE_DIRECTORIES(
  49       ${GDCM_SOURCE_DIR}/vtk/
  50     )
  51     SET(TEST_SOURCES ${TEST_SOURCES}
  52       VTKTestRead.cxx
  53       VTKTestReadSeq.cxx
  54       VTKTestWrite.cxx
  55       VTKTestWriteSeq.cxx
  56     )
  57   ENDIF(GDCM_VTK)
  58 ENDIF (GDCM_DATA_ROOT)
  59
  60
  61
  62 # include stuff
  63 INCLUDE_DIRECTORIES(
  64   ${GDCM_SOURCE_DIR}/src/
  65   ${GDCM_BINARY_DIR}/
  66 )
  67
  68 CREATE_TEST_SOURCELIST(Tests gdcmTests.cxx ${TEST_SOURCES})
  69 ADD_EXECUTABLE(gdcmTests ${Tests})
  70 IF(GDCM_VTK)
  71   TARGET_LINK_LIBRARIES(gdcmTests vtkgdcm vtkRendering)
  72 ELSE(GDCM_VTK)
  73   TARGET_LINK_LIBRARIES(gdcmTests gdcm)
  74 ENDIF(GDCM_VTK)
  75
  76 SET (TestsToRun ${Tests})
  77 REMOVE (TestsToRun gdcmTests.cxx)
  78
  79 # Loop over files and create executables
  80 FOREACH(file ${TEST_SOURCES})
  81   GET_FILENAME_COMPONENT(name ${file} NAME_WE)
  82   ADD_TEST(${name} ${GDCM_TESTS} ${name})
  83 ENDFOREACH(file ${TEST_SOURCES})
  84
  85 #-----------------------------------------------------------------------------
  86
  87 # We need to test the reading of all dicom images in the gdcmData directory
  88 # First parse this directory and extract all images
  89
  90 IF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} GREATER 1.9)
  91   FILE(GLOB GDCM_DATA_IMAGES_GLOB
  92     "${GDCM_DATA_ROOT}/*.acr"
  93     "${GDCM_DATA_ROOT}/*.dcm"
  94     "${GDCM_DATA_ROOT}/*.nema"
  95     "${GDCM_DATA_ROOT}/*.ima"
  96     )
  97   FILE(GLOB GDCM_DATA_SEQ_IMAGES_GLOB
  98     "${GDCM_DATA_ROOT}/*FileSeq0.acr"
  99     "${GDCM_DATA_ROOT}/*FileSeq0.dcm"
 100     "${GDCM_DATA_ROOT}/*FileSeq0.nema"
 101     "${GDCM_DATA_ROOT}/*FileSeq0.ima"
 102     )
 103 ELSE(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} GREATER 1.9)
 104   # Since there is a bug in cmake 1.8.3, I'll have to do two separate globs
 105   FILE(GLOB GDCM_DATA_IMAGES_GLOB_ACR
 106     "${GDCM_DATA_ROOT}/*.acr"
 107     )
 108   FILE(GLOB GDCM_DATA_IMAGES_GLOB_DCM
 109     "${GDCM_DATA_ROOT}/*.dcm"
 110     )
 111   FILE(GLOB GDCM_DATA_IMAGES_GLOB_NEMA
 112     "${GDCM_DATA_ROOT}/*.nema"
 113     )
 114   FILE(GLOB GDCM_DATA_IMAGES_GLOB_IMA
 115     "${GDCM_DATA_ROOT}/*.ima"
 116     )
 117   SET(GDCM_DATA_IMAGES_GLOB
 118     ${GDCM_DATA_IMAGES_GLOB_DCM} ${GDCM_DATA_IMAGES_GLOB_ACR}
 119     ${GDCM_DATA_IMAGES_GLOB_NEMA} ${GDCM_DATA_IMAGES_GLOB_IMA})
 120
 121   FILE(GLOB GDCM_DATA_SEQ_IMAGES_GLOB_ACR
 122     "${GDCM_DATA_ROOT}/*FileSeq0.acr"
 123     )
 124   FILE(GLOB GDCM_DATA_SEQ_IMAGES_GLOB_DCM
 125     "${GDCM_DATA_ROOT}/*FileSeq0.dcm"
 126     )
 127   FILE(GLOB GDCM_DATA_SEQ_IMAGES_GLOB_NEMA
 128     "${GDCM_DATA_ROOT}/*FileSeq0.nema"
 129     )
 130   FILE(GLOB GDCM_DATA_SEQ_IMAGES_GLOB_IMA
 131     "${GDCM_DATA_ROOT}/*FileSeq0.ima"
 132     )
 133   SET(GDCM_DATA_SEQ_IMAGES_GLOB
 134     ${GDCM_DATA_SEQ_IMAGES_GLOB_DCM} ${GDCM_DATA_SEQ_IMAGES_GLOB_ACR}
 135     ${GDCM_DATA_SEQ_IMAGES_GLOB_NEMA} ${GDCM_DATA_SEQ_IMAGES_GLOB_IMA})
 136 ENDIF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} GREATER 1.9)
 137
 138 # Black list of images known to break lots of readers (efilm, xmedcon ...):
 139 SET(BLACK_LIST
 140
 141   # Multiframe Papyrus format image
 142   # Just to remember this format exists, and is gdcm::File compliant
 143   # (NOT gdcm::FileHelper ...)
 144   # any contribution is welcome
 145   "PET-cardio-Multiframe-Papyrus.dcm"
 146   # From David Clunie's Compresion Dataset
 147   "D_CLUNIE_CT1_JLSN.dcm"
 148   "D_CLUNIE_CT1_JLSL.dcm"
 149   "D_CLUNIE_CT1_J2KR.dcm"
 150   "D_CLUNIE_CT1_J2KI.dcm"
 151   #Not a Dicom Image, but a RT Object
 152   "RS2.16.124.113534.2.3.5.0.120040728.21342.353.12747_anonimized.dcm"
 153   #Dicom MPEG image
 154   "ETIAM_video_002.dcm"
 155   )
 156
 157 # Add a special test that requires dciodvfy from dicom3tools
 158 INCLUDE(${GDCM_SOURCE_DIR}/CMake/FindDicom3Tools.cmake)
 159
 160 # This is a GLOB expression, change it into a list separated with a comma and \n
 161 SET(GDCM_DATA_IMAGES)
 162 FOREACH(filename ${GDCM_DATA_IMAGES_GLOB})
 163   GET_FILENAME_COMPONENT(filename_temp ${filename} NAME)
 164   IF(DCIODVFY_FOUND)
 165     ADD_TEST("DCIODVFY-INPUT-${filename_temp}" "${DCIODVFY_EXECUTABLE}" "${filename}")
 166     ADD_TEST("DCIODVFY-OUTPUT-${filename_temp}" "${DCIODVFY_EXECUTABLE}" "${GDCM_DATA_ROOT}/BaselineDicom/${filename_temp}")
 167   ENDIF(DCIODVFY_FOUND)
 168   STRING(REGEX MATCH ${filename_temp} bad_dicom ${BLACK_LIST})
 169   IF(NOT bad_dicom)
 170     SET(GDCM_DATA_IMAGES "${GDCM_DATA_IMAGES}\n\"${filename_temp}\",")
 171   ENDIF(NOT bad_dicom)
 172 ENDFOREACH(filename)
 173
 174 SET(GDCM_DATA_SEQ_IMAGES)
 175 FOREACH(filename ${GDCM_DATA_SEQ_IMAGES_GLOB})
 176   GET_FILENAME_COMPONENT(filename_temp ${filename} NAME)
 177   STRING(REGEX MATCH ${filename_temp} bad_dicom ${BLACK_LIST})
 178   IF(NOT bad_dicom)
 179     STRING(REGEX REPLACE "(.*)FileSeq0(.*)" "\\1FileSeq%d\\2" filename_temp2 ${filename_temp})
 180
 181     SET(GDCM_DATA_SEQ_IMAGES "${GDCM_DATA_SEQ_IMAGES}\n\"${filename_temp2}\",")
 182   ENDIF(NOT bad_dicom)
 183 ENDFOREACH(filename)
 184
 185 # Populate GDCM_DATA_IMAGES:
 186 FILE(WRITE "${GDCM_BINARY_DIR}/gdcmDataImages.h"
 187   "const char * const gdcmDataImages[] = { ${GDCM_DATA_IMAGES}\n0 };\n"
 188 )
 189
 190 # Populate GDCM_DATA_SEQ_IMAGES:
 191 FILE(WRITE "${GDCM_BINARY_DIR}/gdcmDataSeqImages.h"
 192   "const char * const gdcmDataSeqImages[] = { ${GDCM_DATA_SEQ_IMAGES}\n0 };\n"
 193 )