Testing/CMakeLists.txt

   1 # CMakeLists for Testing purpose
   2 # Cxx file that need a file to run should be place aproprietly
   3
   4 SET(CXX_TEST_PATH ${EXECUTABLE_OUTPUT_PATH})
   5
   6 SET(GDCM_TESTS ${CXX_TEST_PATH}/gdcmTests)
   7
   8 # add test that does not require data:
   9 # They usally return if no argument is given
  10 SET(TEST_SOURCES
  11   TestBug.cxx
  12   TestHash.cxx
  13   TestTS.cxx
  14   TestVR.cxx
  15 )
  16
  17 # add tests that require data
  18 IF (GDCM_DATA_ROOT)
  19   SET(TEST_SOURCES ${TEST_SOURCES}
  20     TestReadWriteReadCompare.cxx     # includes generated gdcmDataImages.h
  21     PrintAllDocument.cxx             # includes generated gdcmDataImages.h
  22     TestAllReadCompareDicom.cxx      # includes generated gdcmDataImages.h
  23     TestAllEntryVerify.cxx           # includes generated gdcmDataImages.h
  24     PrintDicomDir.cxx
  25     #TestChangeHeader.cxx
  26     TestDicomDir.cxx                 # require DICOMDIR
  27     BuildUpDicomDir.cxx              # writes a file named "NewDICOMDIR"
  28     makeDicomDir.cxx                 # writes a file named "NewDICOMDIR"
  29     TestCopyDicom.cxx
  30   )
  31   # add test that require VTK:
  32   IF(GDCM_VTK)
  33     INCLUDE_DIRECTORIES(
  34       ${GDCM_SOURCE_DIR}/vtk/
  35       )
  36     SET(TEST_SOURCES ${TEST_SOURCES}
  37       ShowDicom.cxx
  38       )
  39   ENDIF(GDCM_VTK)
  40 ENDIF (GDCM_DATA_ROOT)
  41
  42
  43
  44 # include stuff
  45 INCLUDE_DIRECTORIES(
  46   ${GDCM_SOURCE_DIR}/src/
  47   ${GDCM_BINARY_DIR}/
  48 )
  49
  50 CREATE_TEST_SOURCELIST(Tests gdcmTests.cxx ${TEST_SOURCES})
  51 ADD_EXECUTABLE(gdcmTests ${Tests})
  52 IF(GDCM_VTK)
  53   TARGET_LINK_LIBRARIES(gdcmTests vtkgdcm vtkRendering)
  54 ELSE(GDCM_VTK)
  55   TARGET_LINK_LIBRARIES(gdcmTests gdcm)
  56 ENDIF(GDCM_VTK)
  57
  58 SET (TestsToRun ${Tests})
  59 REMOVE (TestsToRun gdcmTests.cxx)
  60
  61 # Loop over files and create executables
  62 FOREACH(file ${TEST_SOURCES})
  63   GET_FILENAME_COMPONENT(name ${file} NAME_WE)
  64 #  IF (GDCM_DATA_ROOT)
  65 #    ADD_TEST(${name} ${GDCM_TESTS} ${name}
  66 #        -D ${GDCM_DATA_ROOT}
  67 #        -T ${GDCM_BINARY_DIR}/Testing/Temporary
  68 #        -V Baseline/gdcm/${name}.png)
  69 #  ELSE (GDCM_DATA_ROOT)
  70     ADD_TEST(${name} ${GDCM_TESTS} ${name})
  71 #  ENDIF (GDCM_DATA_ROOT)
  72 ENDFOREACH(file ${TEST_SOURCES})
  73
  74 #-----------------------------------------------------------------------------
  75
  76 # We need to test the reading of all dicom images in the gdcmData directory
  77 # First parse this directory and extract all images
  78
  79 IF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} GREATER 1.9)
  80   FILE(GLOB GDCM_DATA_IMAGES_GLOB
  81     "${GDCM_DATA_ROOT}/*.acr"
  82     "${GDCM_DATA_ROOT}/*.dcm"
  83     "${GDCM_DATA_ROOT}/*.nema"
  84     "${GDCM_DATA_ROOT}/*.ima"
  85     )
  86 ELSE(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} GREATER 1.9)
  87   # Since there is a bug in cmake 1.8.3, I'll have to do two separate globs
  88   FILE(GLOB GDCM_DATA_IMAGES_GLOB_ACR
  89     "${GDCM_DATA_ROOT}/*.acr"
  90     )
  91   FILE(GLOB GDCM_DATA_IMAGES_GLOB_DCM
  92     "${GDCM_DATA_ROOT}/*.dcm"
  93     )
  94   FILE(GLOB GDCM_DATA_IMAGES_GLOB_NEMA
  95     "${GDCM_DATA_ROOT}/*.nema"
  96     )
  97   FILE(GLOB GDCM_DATA_IMAGES_GLOB_IMA
  98     "${GDCM_DATA_ROOT}/*.ima"
  99     )
 100   SET(GDCM_DATA_IMAGES_GLOB
 101     ${GDCM_DATA_IMAGES_GLOB_DCM} ${GDCM_DATA_IMAGES_GLOB_ACR}
 102     ${GDCM_DATA_IMAGES_GLOB_NEMA} ${GDCM_DATA_IMAGES_GLOB_IMA})
 103   #SET(GDCM_DATA_IMAGES_GLOB  ${GDCM_DATA_IMAGES_GLOB_ACR})
 104 ENDIF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} GREATER 1.9)
 105
 106 # Black list of images known to break lots of readers (efilm, xmedcon ...):
 107 SET(BLACK_LIST
 108   # serial killer (also segfaults vtkgdcmViewer, but NOT PrintFile)
 109   "gdcm-JPEG-LossLessThoravision.dcm"
 110
 111   # Mathieu: temporarily remove as it kills my gnome session (but not kde)
 112   # JPR: also breaks TestReadWriteReadCompare : Pixel differ (as expanded
 113   #      in memory)
 114   "KODAK-12-MONO1-Odd_Terminated_Sequence.dcm"
 115   )
 116
 117
 118 # This is a GLOB expression, change it into a list separated with a comma and \n
 119 SET(GDCM_DATA_IMAGES)
 120 FOREACH(filename ${GDCM_DATA_IMAGES_GLOB})
 121   GET_FILENAME_COMPONENT(filename_temp ${filename} NAME)
 122   STRING(REGEX MATCH ${filename_temp} bad_dicom ${BLACK_LIST})
 123   IF(NOT bad_dicom)
 124     SET(GDCM_DATA_IMAGES "${GDCM_DATA_IMAGES}\n\"${filename_temp}\",")
 125   ENDIF(NOT bad_dicom)
 126 ENDFOREACH(filename)
 127
 128 # Populate GDCM_DATA_IMAGES:
 129 FILE(WRITE "${GDCM_BINARY_DIR}/gdcmDataImages.h"
 130   "const char * const gdcmDataImages[] = { ${GDCM_DATA_IMAGES}\n0 };\n"
 131   )