kernel/cmake/BBTKConfigurePackage_src.cmake

   1
   2 #----------------------------------------------------------------------------
   3 # BINARY DIR MUST BE IN INCLUDE DIRS
   4 # TO FIND .h OF AUTOMATICALLY GENERATED FILES (e.g. FROM XML)
   5 INCLUDE_DIRECTORIES( ${CMAKE_CURRENT_BINARY_DIR} )
   6 # SOURCES DIR MUST ALSO BE IN INCLUDE DIRS FOR FILES COMPILED IN BINARY DIR
   7 # WHICH NEED TO INCLUDE OTHER FILES OF THE PACKAGE
   8 INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR} )
   9 #----------------------------------------------------------------------------
  10
  11
  12
  13 #----------------------------------------------------------------------------
  14
  15 #----------------------------------------------------------------------------
  16 # CREATES bb${BBTK_PACKAGE_NAME}Package.h
  17 CONFIGURE_FILE(
  18   ${BBTK_CMAKE_DIR}/bbPackage.h.in
  19   ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.h
  20   @ONLY IMMEDIATE
  21   )
  22 INSTALL(
  23   FILES ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.h
  24   DESTINATION include/bb${BBTK_PACKAGE_NAME}
  25   )
  26 #----------------------------------------------------------------------------
  27
  28 #----------------------------------------------------------------------------
  29 # CREATES bb${BBTK_PACKAGE_NAME}Package.cxx
  30 CONFIGURE_FILE(
  31   ${BBTK_CMAKE_DIR}/bbPackage.cxx.in
  32   ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.cxx
  33   @ONLY IMMEDIATE
  34   )
  35 #----------------------------------------------------------------------------
  36
  37 #----------------------------------------------------------------------------
  38 SET_SOURCE_FILES_PROPERTIES(
  39   ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.cxx
  40   PROPERTIES GENERATED ON)
  41 #----------------------------------------------------------------------------
  42
  43
  44 #----------------------------------------------------------------------------
  45 IF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_CXX)
  46   FILE(GLOB ${BBTK_PACKAGE_NAME}_CXX_SOURCES "." "*.cxx")
  47   FILE(GLOB ${BBTK_PACKAGE_NAME}_CPP_SOURCES "." "*.cpp")
  48   SET(${BBTK_PACKAGE_NAME}_CXX_SOURCES ${${BBTK_PACKAGE_NAME}_CXX_SOURCES} ${${BBTK_PACKAGE_NAME}_CPP_SOURCES})
  49   FILE(GLOB ${BBTK_PACKAGE_NAME}_H_SOURCES "." "*.h")
  50 ENDIF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_CXX)
  51 IF(NOT PROJECT_BINARY_DIR STREQUAL ${PROJECT_SOURCE_DIR})
  52   SET(${BBTK_PACKAGE_NAME}_CXX_SOURCES
  53     ${${BBTK_PACKAGE_NAME}_CXX_SOURCES}
  54     bb${BBTK_PACKAGE_NAME}Package
  55     )
  56 ENDIF(NOT PROJECT_BINARY_DIR STREQUAL ${PROJECT_SOURCE_DIR})
  57 #----------------------------------------------------------------------------
  58
  59
  60 #----------------------------------------------------------------------------
  61 #----------------------------------------------------------------------------
  62 # bbfy
  63 #----------------------------------------------------------------------------
  64
  65 #----------------------------------------------------------------------------
  66 IF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_XML)
  67   FILE(GLOB ${BBTK_PACKAGE_NAME}_XML_SOURCES "." "*.xml")
  68 ENDIF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_XML)
  69 #----------------------------------------------------------------------------
  70 FOREACH(xmlfile ${${BBTK_PACKAGE_NAME}_XML_SOURCES})
  71
  72   GET_FILENAME_COMPONENT(filename "${xmlfile}" NAME_WE)
  73
  74   SET(BBFY_CXX_OUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.cxx)
  75
  76   IF (WIN32)
  77     MAKE_DLL_PATH()
  78  #   SET(command00 Path=c:/creatis/dlls__RR__%WXWIN%/lib/vc_dll/__RR__%VTK_DIR%__RR__%ITK_DIR%/../../bin/__RR__%PATH%)
  79  #   STRING(REPLACE "__RR__" "\;" SETPATH ${command00} )
  80  #   SET(SETPATH set ${command0} &&)
  81  ADD_CUSTOM_COMMAND(
  82     OUTPUT ${BBFY_CXX_OUT}
  83     COMMAND
  84     set ${DLL_PATH} && ${BBTK_BBFY} ${xmlfile} ${BBTK_PACKAGE_NAME} ${CMAKE_CURRENT_BINARY_DIR}/ -q
  85     DEPENDS ${xmlfile}
  86     ${BBTK_BBFY_DEPENDENCY}
  87     )
  88   ELSE(WIN32)
  89     SET(LD_LIBRARY_PATH "$ENV{LD_LIBRARY_PATH}:${LIBRARY_OUTPUT_PATH}")
  90     ADD_CUSTOM_COMMAND(
  91       OUTPUT ${BBFY_CXX_OUT}
  92       COMMAND
  93       export LD_LIBRARY_PATH=${LD_LIBRARY_PATH} && ${BBTK_BBFY} ${xmlfile} ${BBTK_PACKAGE_NAME} ${CMAKE_CURRENT_BINARY_DIR}/ -q
  94       DEPENDS ${xmlfile}
  95       ${BBTK_BBFY_DEPENDENCY}
  96       )
  97
  98   ENDIF(WIN32)
  99
 100
 101   SET_SOURCE_FILES_PROPERTIES(
 102     ${BBFY_CXX_OUT}
 103     PROPERTIES GENERATED ON)
 104
 105
 106  IF(NOT ${BBTK_PACKAGE_NAME}_CXX_SOURCES MATCHES "${filename}.cxx")
 107  # message ("EED Alert BBTKConfigurePackage_src  "  "IF NOT MATCHES" )
 108   SET(${BBTK_PACKAGE_NAME}_CXX_SOURCES
 109       ${${BBTK_PACKAGE_NAME}_CXX_SOURCES}
 110       ${filename}.cxx
 111       )
 112  ENDIF(NOT ${BBTK_PACKAGE_NAME}_CXX_SOURCES MATCHES "${filename}.cxx")
 113
 114   INSTALL(
 115     FILES       ${CMAKE_CURRENT_BINARY_DIR}/${filename}.h
 116     DESTINATION include/bb${BBTK_PACKAGE_NAME})
 117 ENDFOREACH(xmlfile)
 118 #----------------------------------------------------------------------------
 119
 120
 121
 122 #----------------------------------------------------------------------------
 123 # CREATES LIBRARY
 124 ADD_LIBRARY(bb${BBTK_PACKAGE_NAME} SHARED
 125   ${${BBTK_PACKAGE_NAME}_CXX_SOURCES} ${${BBTK_PACKAGE_NAME}_H_SOURCES}
 126   )
 127 TARGET_LINK_LIBRARIES(bb${BBTK_PACKAGE_NAME}
 128   bbtk
 129   ${${BBTK_PACKAGE_NAME}_LIBS}
 130   )
 131 IF(UNIX)
 132 SET_TARGET_PROPERTIES(bb${BBTK_PACKAGE_NAME} PROPERTIES COMPILE_FLAGS -Wall)
 133 ENDIF(UNIX)
 134 #----------------------------------------------------------------------------
 135
 136
 137 #----------------------------------------------------------------------------
 138 # INSTALLS LIBRARY
 139 FILE(GLOB ${BBTK_PACKAGE_NAME}_HEADERS "*.h")
 140 INSTALL(
 141   FILES ${${BBTK_PACKAGE_NAME}_HEADERS}
 142   DESTINATION include/bb${BBTK_PACKAGE_NAME}
 143   )
 144 INSTALL(
 145   TARGETS bb${BBTK_PACKAGE_NAME}
 146   DESTINATION lib)
 147
 148 # CreateFindPackage
 149 SET( LIBRARY_NAME bb${BBTK_PACKAGE_NAME} )
 150 # SET THE LIB VERSION
 151 SET(${LIBRARY_NAME}_MAJOR_VERSION ${${BBTK_PACKAGE_NAME}_MAJOR_VERSION})
 152 SET(${LIBRARY_NAME}_MINOR_VERSION ${${BBTK_PACKAGE_NAME}_MINOR_VERSION})
 153 SET(${LIBRARY_NAME}_BUILD_VERSION ${${BBTK_PACKAGE_NAME}_BUILD_VERSION})
 154 #
 155 SET(${LIBRARY_NAME}_INSTALL_FOLDER bb${BBTK_PACKAGE_NAME})
 156 SET(${LIBRARY_NAME}_LIBRARIES bb${BBTK_PACKAGE_NAME})
 157
 158 FILE(RELATIVE_PATH
 159   ${LIBRARY_NAME}_BUILD_TREE_RELATIVE_INCLUDE_PATHS
 160   ${PROJECT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}
 161   )
 162
 163 IF(UNIX)
 164   SET(${LIBRARY_NAME}_BUILD_TREE_RELATIVE_LIBRARY_PATHS
 165     ${EXECUTABLE_OUTPUT_REL_PATH})
 166 ELSE(UNIX)
 167   SET(${LIBRARY_NAME}_BUILD_TREE_RELATIVE_LIBRARY_PATHS
 168     ${EXECUTABLE_OUTPUT_REL_PATH}/Debug
 169     ${EXECUTABLE_OUTPUT_REL_PATH}/Release)
 170 ENDIF(UNIX)
 171 SET(${LIBRARY_NAME}_INSTALL_TREE_RELATIVE_INCLUDE_PATHS
 172   include/bb${BBTK_PACKAGE_NAME})
 173 SET(${LIBRARY_NAME}_INSTALL_TREE_RELATIVE_LIBRARY_PATHS lib)
 174
 175 # REQUIRED BUILD FLAGS
 176 #SET(${LIBRARY_NAME}_REQUIRED_C_FLAGS "")
 177 #SET(${LIBRARY_NAME}_REQUIRED_CXX_FLAGS "")
 178 #SET(${LIBRARY_NAME}_REQUIRED_LINK_FLAGS "")
 179
 180 # Additional config/use
 181 # Prepare for configure
 182 SET(BBTK_PACKAGE_USE_VTK ${${BBTK_PACKAGE_NAME}_USE_VTK})
 183 SET(BBTK_PACKAGE_USE_ITK ${${BBTK_PACKAGE_NAME}_USE_ITK})
 184 SET(BBTK_PACKAGE_USE_GDCM ${${BBTK_PACKAGE_NAME}_USE_GDCM})
 185 SET(BBTK_PACKAGE_USE_GSMIS ${${BBTK_PACKAGE_NAME}_USE_GSMIS})
 186 SET(BBTK_PACKAGE_USE_WXWIDGETS ${${BBTK_PACKAGE_NAME}_USE_WXWIDGETS})
 187 SET(BBTK_PACKAGE_USE_PACKAGES  ${${BBTK_PACKAGE_NAME}_USE_PACKAGES})
 188 SET(BBTK_PACKAGE_INCLUDE_DIRS  ${${BBTK_PACKAGE_NAME}_INCLUDE_DIRS})
 189 SET(BBTK_PACKAGE_LIBS          ${${BBTK_PACKAGE_NAME}_LIBS})
 190
 191 SET(${LIBRARY_NAME}_HAS_ADDITIONAL_CONFIG_FILE TRUE)
 192 SET(${LIBRARY_NAME}_ADDITIONAL_CONFIG_FILE
 193   ${${BBTK_PACKAGE_NAME}_SOURCE_DIR}/PackageConfig.cmake.in)
 194 SET(${LIBRARY_NAME}_ADDITIONAL_USE_FILE
 195   ${${BBTK_PACKAGE_NAME}_SOURCE_DIR}/UsePackage.cmake.in)
 196 #-----------------------------------------------------------------------------
 197
 198 #-----------------------------------------------------------------------------
 199 # Includes CMakeCreateFindPackage
 200 INCLUDE(${CMakeCreateFindPackage_DIR}/CMakeCreateFindPackage.cmake)
 201 CMAKE_CREATE_FIND_PACKAGE(${LIBRARY_NAME})
 202 #-----------------------------------------------------------------------------
 203
 204 #----------------------------------------------------------------------------
 205
 206
 207
 208
 209 #---------------------------------------------------------------------------
 210 IF(CHCON_LIBRARIES)
 211   # On recent linux running SELinux :
 212   # Have to change the context of the library created
 213   # to be able to load it dynamically and avoid the error :
 214   # "cannot restore segment prot after reloc: Permission denied"
 215   # see e.g.
 216   # http://www.ittvis.com/services/techtip.asp?ttid=3092
 217   # Try to find chcon
 218   FIND_PROGRAM(CHCON_EXECUTABLE
 219     NAMES chcon
 220     PATHS
 221     /usr/bin
 222     /usr/local/bin
 223     )
 224   MARK_AS_ADVANCED(CHCON_EXECUTABLE)
 225   IF(CHCON_EXECUTABLE)
 226     # chcon found
 227     # custom post_build command to change the context of the .so generated
 228     ADD_CUSTOM_COMMAND(
 229       TARGET bb${BBTK_PACKAGE_NAME}
 230       POST_BUILD
 231       COMMAND chcon -t texrel_shlib_t ${LIBRARY_OUTPUT_PATH}/libbb${BBTK_PACKAGE_NAME}.so
 232       )
 233     # custom post-install command to change the context of the .so installed
 234     INSTALL(CODE "EXEC_PROGRAM(chcon ARGS -t texrel_shlib_t ${CMAKE_INSTALL_PREFIX}/lib/libbb${BBTK_PACKAGE_NAME}.so)")
 235   ENDIF(CHCON_EXECUTABLE)
 236 ENDIF(CHCON_LIBRARIES)
 237 #----------------------------------------------------------------------------
 238