kernel/cmake/BBTKConfigurePackage_src.cmake

   1  # ---------------------------------------------------------------------
   2  #
   3  # Copyright (c) CREATIS (Centre de Recherche en Acquisition et Traitement de l'Image
   4  #                        pour la SantÈ)
   5  # Authors : Eduardo Davila, Frederic Cervenansky, Claire Mouton
   6  # Previous Authors : Laurent Guigues, Jean-Pierre Roux
   7  # CreaTools website : www.creatis.insa-lyon.fr/site/fr/creatools_accueil
   8  #
   9  #  This software is governed by the CeCILL-B license under French law and
  10  #  abiding by the rules of distribution of free software. You can  use,
  11  #  modify and/ or redistribute the software under the terms of the CeCILL-B
  12  #  license as circulated by CEA, CNRS and INRIA at the following URL
  13  #  http://www.cecill.info/licences/Licence_CeCILL-B_V1-en.html
  14  #  or in the file LICENSE.txt.
  15  #
  16  #  As a counterpart to the access to the source code and  rights to copy,
  17  #  modify and redistribute granted by the license, users are provided only
  18  #  with a limited warranty  and the software's author,  the holder of the
  19  #  economic rights,  and the successive licensors  have only  limited
  20  #  liability.
  21  #
  22  #  The fact that you are presently reading this means that you have had
  23  #  knowledge of the CeCILL-B license and that you accept its terms.
  24  # ------------------------------------------------------------------------ */
  25
  26
  27
  28 #----------------------------------------------------------------------------
  29 # BINARY DIR MUST BE IN INCLUDE DIRS
  30 # TO FIND .h OF AUTOMATICALLY GENERATED FILES (e.g. FROM XML)
  31 INCLUDE_DIRECTORIES( ${CMAKE_CURRENT_BINARY_DIR} )
  32 # SOURCES DIR MUST ALSO BE IN INCLUDE DIRS FOR FILES COMPILED IN BINARY DIR
  33 # WHICH NEED TO INCLUDE OTHER FILES OF THE PACKAGE
  34 INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR} )
  35 #----------------------------------------------------------------------------
  36
  37 #----------------------------------------------------------------------------
  38 # CREATES bb${BBTK_PACKAGE_NAME}_EXPORT.h
  39 CREA_DYNAMIC_LIBRARY_EXPORT(bb${BBTK_PACKAGE_NAME})
  40 INSTALL(
  41   FILES ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}_EXPORT.h
  42   DESTINATION include/bb${BBTK_PACKAGE_NAME}
  43   )
  44 #----------------------------------------------------------------------------
  45
  46 #----------------------------------------------------------------------------
  47 # CREATES bb${BBTK_PACKAGE_NAME}Package.h
  48 CONFIGURE_FILE(
  49   ${BBTK_CMAKE_DIR}/bbPackage.h.in
  50   ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.h
  51   @ONLY IMMEDIATE
  52   )
  53 INSTALL(
  54   FILES ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.h
  55   DESTINATION include/bb${BBTK_PACKAGE_NAME}
  56   )
  57 #----------------------------------------------------------------------------
  58
  59 #----------------------------------------------------------------------------
  60 # CREATES bb${BBTK_PACKAGE_NAME}Package.cxx
  61 CONFIGURE_FILE(
  62   ${BBTK_CMAKE_DIR}/bbPackage.cxx.in
  63   ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.cxx
  64   @ONLY IMMEDIATE
  65   )
  66 #----------------------------------------------------------------------------
  67
  68 #----------------------------------------------------------------------------
  69 SET_SOURCE_FILES_PROPERTIES(
  70   ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.cxx
  71   PROPERTIES GENERATED ON)
  72 #----------------------------------------------------------------------------
  73
  74
  75 #----------------------------------------------------------------------------
  76 IF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_CXX)
  77   FILE(GLOB ${BBTK_PACKAGE_NAME}_CXX_SOURCES "." "*.cxx")
  78   FILE(GLOB ${BBTK_PACKAGE_NAME}_CPP_SOURCES "." "*.cpp")
  79   SET(${BBTK_PACKAGE_NAME}_CXX_SOURCES ${${BBTK_PACKAGE_NAME}_CXX_SOURCES} ${${BBTK_PACKAGE_NAME}_CPP_SOURCES})
  80   FILE(GLOB ${BBTK_PACKAGE_NAME}_H_SOURCES "." "*.h")
  81 ENDIF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_CXX)
  82
  83 IF(NOT PROJECT_BINARY_DIR STREQUAL ${PROJECT_SOURCE_DIR})
  84   SET(${BBTK_PACKAGE_NAME}_CXX_SOURCES
  85     ${${BBTK_PACKAGE_NAME}_CXX_SOURCES}
  86     bb${BBTK_PACKAGE_NAME}Package
  87     )
  88 ENDIF(NOT PROJECT_BINARY_DIR STREQUAL ${PROJECT_SOURCE_DIR})
  89 #----------------------------------------------------------------------------
  90
  91
  92 #----------------------------------------------------------------------------
  93 #----------------------------------------------------------------------------
  94 # bbfy
  95 #----------------------------------------------------------------------------
  96
  97 #----------------------------------------------------------------------------
  98 IF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_XML)
  99   FILE(GLOB ${BBTK_PACKAGE_NAME}_XML_SOURCES "." "*.xml")
 100 ENDIF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_XML)
 101 #----------------------------------------------------------------------------
 102 FOREACH(xmlfile ${${BBTK_PACKAGE_NAME}_XML_SOURCES})
 103   GET_FILENAME_COMPONENT(filename "${xmlfile}" NAME_WE)
 104
 105   SET(BBFY_CXX_OUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.cxx)
 106
 107   IF (WIN32)
 108     MAKE_DLL_PATH()
 109  #   SET(command00 Path=c:/creatis/dlls__RR__%WXWIN%/lib/vc_dll/__RR__%VTK_DIR%__RR__%ITK_DIR%/../../bin/__RR__%PATH%)
 110  #   STRING(REPLACE "__RR__" "\;" SETPATH ${command00} )
 111  #   SET(SETPATH set ${command0} &&)
 112  ADD_CUSTOM_COMMAND(
 113     OUTPUT ${BBFY_CXX_OUT}
 114     COMMAND
 115     set Path=${DLL_PATH} && ${BBTK_BBFY} ${xmlfile} ${BBTK_PACKAGE_NAME} ${CMAKE_CURRENT_BINARY_DIR}/ -q
 116     DEPENDS ${xmlfile}
 117     ${BBTK_BBFY_DEPENDENCY}
 118     )
 119   ELSE(WIN32)
 120     SET(LD_LIBRARY_PATH "$ENV{LD_LIBRARY_PATH}:${LIBRARY_OUTPUT_PATH}")
 121     ADD_CUSTOM_COMMAND(
 122       OUTPUT ${BBFY_CXX_OUT}
 123       COMMAND
 124       export LD_LIBRARY_PATH=${LD_LIBRARY_PATH} && ${BBTK_BBFY} ${xmlfile} ${BBTK_PACKAGE_NAME} ${CMAKE_CURRENT_BINARY_DIR}/ -q
 125       DEPENDS ${xmlfile}
 126       ${BBTK_BBFY_DEPENDENCY}
 127       )
 128
 129   ENDIF(WIN32)
 130
 131
 132   SET_SOURCE_FILES_PROPERTIES(
 133     ${BBFY_CXX_OUT}
 134     PROPERTIES GENERATED ON)
 135
 136
 137  IF(NOT ${BBTK_PACKAGE_NAME}_CXX_SOURCES MATCHES "${filename}.cxx")
 138  # message ("EED Alert BBTKConfigurePackage_src  "  "IF NOT MATCHES" )
 139   SET(${BBTK_PACKAGE_NAME}_CXX_SOURCES
 140       ${${BBTK_PACKAGE_NAME}_CXX_SOURCES}
 141       ${filename}.cxx
 142       )
 143  ENDIF(NOT ${BBTK_PACKAGE_NAME}_CXX_SOURCES MATCHES "${filename}.cxx")
 144
 145   INSTALL(
 146     FILES       ${CMAKE_CURRENT_BINARY_DIR}/${filename}.h
 147     DESTINATION include/bb${BBTK_PACKAGE_NAME})
 148 ENDFOREACH(xmlfile)
 149 #----------------------------------------------------------------------------
 150
 151
 152
 153 #----------------------------------------------------------------------------
 154 # CREATES LIBRARY
 155 #----------------------------------------------------------------------------
 156 # TCL WRAPPING FOR KWWIDGETS
 157 IF(BBTK_USE_KWWIDGETS)
 158 #MESSAGE(STATUS "****TCL=${${BBTK_PACKAGE_NAME}_CXX_SOURCES_WRAP_TCL}")
 159 IF(${BBTK_PACKAGE_NAME}_CXX_SOURCES_WRAP_TCL )
 160 #MESSAGE(STATUS "****TCL OK")
 161 include("${KWWidgets_CMAKE_DIR}/KWWidgetsWrappingMacros.cmake")
 162 kwwidgets_wrap_tcl(bb${BBTK_PACKAGE_NAME} LIB_TCL_SRCS ${${BBTK_PACKAGE_NAME}_CXX_SOURCES_WRAP_TCL} "")
 163 SET(${BBTK_PACKAGE_NAME}_CXX_SOURCES
 164   ${${BBTK_PACKAGE_NAME}_CXX_SOURCES}
 165   ${LIB_TCL_SRCS})
 166 ENDIF(${BBTK_PACKAGE_NAME}_CXX_SOURCES_WRAP_TCL)
 167 ENDIF(BBTK_USE_KWWIDGETS)
 168 #----------------------------------------------------------------------------
 169 #MESSAGE(STATUS ${${BBTK_PACKAGE_NAME}_CXX_SOURCES})
 170
 171 ADD_LIBRARY(bb${BBTK_PACKAGE_NAME} SHARED
 172   ${${BBTK_PACKAGE_NAME}_CXX_SOURCES} ${${BBTK_PACKAGE_NAME}_H_SOURCES}
 173   )
 174
 175
 176 TARGET_LINK_LIBRARIES(bb${BBTK_PACKAGE_NAME}
 177   bbtk
 178   ${${BBTK_PACKAGE_NAME}_LIBS}
 179   )
 180 IF(UNIX)
 181 SET_TARGET_PROPERTIES(bb${BBTK_PACKAGE_NAME} PROPERTIES COMPILE_FLAGS -Wall)
 182 ENDIF(UNIX)
 183 #----------------------------------------------------------------------------
 184
 185
 186 #----------------------------------------------------------------------------
 187 # INSTALLS LIBRARY
 188 FILE(GLOB ${BBTK_PACKAGE_NAME}_HEADERS "*.h")
 189 INSTALL(
 190   FILES ${${BBTK_PACKAGE_NAME}_HEADERS}
 191   DESTINATION include/bb${BBTK_PACKAGE_NAME}
 192   )
 193 INSTALL(
 194   TARGETS bb${BBTK_PACKAGE_NAME}
 195   DESTINATION ${BBTK_PACKAGE_LIB_PATH}
 196   )
 197
 198
 199 # Preparing macro invocation : CREA_ADVANCED_INSTALL_LIBRARY_FOR_CMAKE
 200 SET( LIBRARY_NAME bb${BBTK_PACKAGE_NAME} )
 201 # SET THE LIB VERSION
 202 SET(${LIBRARY_NAME}_MAJOR_VERSION ${${BBTK_PACKAGE_NAME}_MAJOR_VERSION})
 203 SET(${LIBRARY_NAME}_MINOR_VERSION ${${BBTK_PACKAGE_NAME}_MINOR_VERSION})
 204 SET(${LIBRARY_NAME}_BUILD_VERSION ${${BBTK_PACKAGE_NAME}_BUILD_VERSION})
 205 #
 206 SET(${LIBRARY_NAME}_INSTALL_FOLDER bb${BBTK_PACKAGE_NAME})
 207 SET(${LIBRARY_NAME}_LIBRARIES bb${BBTK_PACKAGE_NAME})
 208
 209 FILE(RELATIVE_PATH
 210   ${LIBRARY_NAME}_BUILD_TREE_RELATIVE_INCLUDE_PATHS
 211   ${PROJECT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}
 212   )
 213
 214 IF ( ${PROJECT_BINARY_DIR} STREQUAL ${EXECUTABLE_OUTPUT_PATH} )
 215   SET(CILFC_EXECUTABLE_OUTPUT_REL_PATH ".")
 216 ELSE ( ${PROJECT_BINARY_DIR} STREQUAL ${EXECUTABLE_OUTPUT_PATH} )
 217   FILE(RELATIVE_PATH
 218     CILFC_EXECUTABLE_OUTPUT_REL_PATH
 219     ${PROJECT_BINARY_DIR} ${EXECUTABLE_OUTPUT_PATH})
 220 ENDIF ( ${PROJECT_BINARY_DIR} STREQUAL ${EXECUTABLE_OUTPUT_PATH} )
 221
 222 IF(UNIX)
 223   SET(${LIBRARY_NAME}_BUILD_TREE_RELATIVE_LIBRARY_PATHS
 224     ${CILFC_EXECUTABLE_OUTPUT_REL_PATH})
 225 ELSE(UNIX)
 226   SET(${LIBRARY_NAME}_BUILD_TREE_RELATIVE_LIBRARY_PATHS
 227     ${CILFC_EXECUTABLE_OUTPUT_REL_PATH})
 228 ENDIF(UNIX)
 229
 230 SET(${LIBRARY_NAME}_INSTALL_TREE_RELATIVE_INCLUDE_PATHS
 231   include/bb${BBTK_PACKAGE_NAME})
 232 SET(${LIBRARY_NAME}_INSTALL_TREE_RELATIVE_LIBRARY_PATHS ${BBTK_PACKAGE_LIB_PATH})
 233
 234 # REQUIRED BUILD FLAGS
 235 #SET(${LIBRARY_NAME}_REQUIRED_C_FLAGS "")
 236 #SET(${LIBRARY_NAME}_REQUIRED_CXX_FLAGS "")
 237 #SET(${LIBRARY_NAME}_REQUIRED_LINK_FLAGS "")
 238
 239 # Additional config/use
 240 # Prepare for configure
 241 SET(BBTK_PACKAGE_USE_VTK       ${${BBTK_PACKAGE_NAME}_USE_VTK})
 242 SET(BBTK_PACKAGE_USE_ITK       ${${BBTK_PACKAGE_NAME}_USE_ITK})
 243 SET(BBTK_PACKAGE_USE_QT        ${${BBTK_PACKAGE_NAME}_USE_QT})
 244 SET(BBTK_PACKAGE_USE_GDCM      ${${BBTK_PACKAGE_NAME}_USE_GDCM})
 245 SET(BBTK_PACKAGE_USE_GDCM2     ${${BBTK_PACKAGE_NAME}_USE_GDCM2})
 246 SET(BBTK_PACKAGE_USE_GSMIS     ${${BBTK_PACKAGE_NAME}_USE_GSMIS})
 247 SET(BBTK_PACKAGE_USE_WXWIDGETS ${${BBTK_PACKAGE_NAME}_USE_WXWIDGETS})
 248 SET(BBTK_PACKAGE_USE_PACKAGES  ${${BBTK_PACKAGE_NAME}_USE_PACKAGES})
 249 SET(BBTK_PACKAGE_INCLUDE_DIRS  ${${BBTK_PACKAGE_NAME}_INCLUDE_DIRS})
 250 SET(BBTK_PACKAGE_LIBS          ${${BBTK_PACKAGE_NAME}_LIBS})
 251
 252 SET(${LIBRARY_NAME}_HAS_ADDITIONAL_CONFIG_FILE TRUE)
 253 SET(${LIBRARY_NAME}_ADDITIONAL_CONFIG_FILE
 254   ${${BBTK_PACKAGE_NAME}_SOURCE_DIR}/PackageConfig.cmake.in)
 255 SET(${LIBRARY_NAME}_ADDITIONAL_USE_FILE
 256   ${${BBTK_PACKAGE_NAME}_SOURCE_DIR}/UsePackage.cmake.in)
 257 #-----------------------------------------------------------------------------
 258
 259 #-----------------------------------------------------------------------------
 260 CREA_ADVANCED_INSTALL_LIBRARY_FOR_CMAKE(${LIBRARY_NAME})
 261 #-----------------------------------------------------------------------------
 262
 263 #----------------------------------------------------------------------------
 264
 265
 266
 267
 268 #---------------------------------------------------------------------------
 269 IF(CHCON_LIBRARIES)
 270   # On recent linux running SELinux :
 271   # Have to change the context of the library created
 272   # to be able to load it dynamically and avoid the error :
 273   # "cannot restore segment prot after reloc: Permission denied"
 274   # see e.g.
 275   # http://www.ittvis.com/services/techtip.asp?ttid=3092
 276   # Try to find chcon
 277   FIND_PROGRAM(CHCON_EXECUTABLE
 278     NAMES chcon
 279     PATHS
 280     /usr/bin
 281     /usr/local/bin
 282     )
 283   MARK_AS_ADVANCED(CHCON_EXECUTABLE)
 284   IF(CHCON_EXECUTABLE)
 285     # chcon found
 286     # custom post_build command to change the context of the .so generated
 287     ADD_CUSTOM_COMMAND(
 288       TARGET bb${BBTK_PACKAGE_NAME}
 289       POST_BUILD
 290       COMMAND chcon -t texrel_shlib_t ${LIBRARY_OUTPUT_PATH}/libbb${BBTK_PACKAGE_NAME}.so
 291       )
 292     # custom post-install command to change the context of the .so installed
 293     INSTALL(CODE "EXEC_PROGRAM(chcon ARGS -t texrel_shlib_t ${CMAKE_INSTALL_PREFIX}/lib/libbb${BBTK_PACKAGE_NAME}.so)")
 294   ENDIF(CHCON_EXECUTABLE)
 295 ENDIF(CHCON_LIBRARIES)
 296 #----------------------------------------------------------------------------
 297