kernel/cmake/BBTKConfigurePackage_src.cmake

   1  # ---------------------------------------------------------------------
   2  #
   3  # Copyright (c) CREATIS (Centre de Recherche en Acquisition et Traitement de l'Image
   4  #                        pour la SantÈ)
   5  # Authors : Eduardo Davila, Frederic Cervenansky, Claire Mouton
   6  # Previous Authors : Laurent Guigues, Jean-Pierre Roux
   7  # CreaTools website : www.creatis.insa-lyon.fr/site/fr/creatools_accueil
   8  #
   9  #  This software is governed by the CeCILL-B license under French law and
  10  #  abiding by the rules of distribution of free software. You can  use,
  11  #  modify and/ or redistribute the software under the terms of the CeCILL-B
  12  #  license as circulated by CEA, CNRS and INRIA at the following URL
  13  #  http://www.cecill.info/licences/Licence_CeCILL-B_V1-en.html
  14  #  or in the file LICENSE.txt.
  15  #
  16  #  As a counterpart to the access to the source code and  rights to copy,
  17  #  modify and redistribute granted by the license, users are provided only
  18  #  with a limited warranty  and the software's author,  the holder of the
  19  #  economic rights,  and the successive licensors  have only  limited
  20  #  liability.
  21  #
  22  #  The fact that you are presently reading this means that you have had
  23  #  knowledge of the CeCILL-B license and that you accept its terms.
  24  # ------------------------------------------------------------------------ */
  25
  26
  27
  28 #----------------------------------------------------------------------------
  29 # BINARY DIR MUST BE IN INCLUDE DIRS
  30 # TO FIND .h OF AUTOMATICALLY GENERATED FILES (e.g. FROM XML)
  31 INCLUDE_DIRECTORIES( ${CMAKE_CURRENT_BINARY_DIR} )
  32 # SOURCES DIR MUST ALSO BE IN INCLUDE DIRS FOR FILES COMPILED IN BINARY DIR
  33 # WHICH NEED TO INCLUDE OTHER FILES OF THE PACKAGE
  34 INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR} )
  35 #----------------------------------------------------------------------------
  36
  37 #----------------------------------------------------------------------------
  38 # CREATES bb${BBTK_PACKAGE_NAME}_EXPORT.h
  39 CREA_DYNAMIC_LIBRARY_EXPORT(bb${BBTK_PACKAGE_NAME})
  40 INSTALL(
  41   FILES ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}_EXPORT.h
  42   DESTINATION include/bb${BBTK_PACKAGE_NAME}
  43   )
  44 #----------------------------------------------------------------------------
  45
  46 #----------------------------------------------------------------------------
  47 # CREATES bb${BBTK_PACKAGE_NAME}Package.h
  48 CONFIGURE_FILE(
  49   ${BBTK_CMAKE_DIR}/bbPackage.h.in
  50   ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.h
  51   @ONLY IMMEDIATE
  52   )
  53 INSTALL(
  54   FILES ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.h
  55   DESTINATION include/bb${BBTK_PACKAGE_NAME}
  56   )
  57 #----------------------------------------------------------------------------
  58
  59 #----------------------------------------------------------------------------
  60 # CREATES bb${BBTK_PACKAGE_NAME}Package.cxx
  61 CONFIGURE_FILE(
  62   ${BBTK_CMAKE_DIR}/bbPackage.cxx.in
  63   ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.cxx
  64   @ONLY IMMEDIATE
  65   )
  66 #----------------------------------------------------------------------------
  67
  68 #----------------------------------------------------------------------------
  69 SET_SOURCE_FILES_PROPERTIES(
  70   ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.cxx
  71   PROPERTIES GENERATED ON)
  72 #----------------------------------------------------------------------------
  73
  74
  75 #----------------------------------------------------------------------------
  76 IF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_CXX)
  77   FILE(GLOB ${BBTK_PACKAGE_NAME}_CXX_SOURCES "." "*.cxx")
  78   FILE(GLOB ${BBTK_PACKAGE_NAME}_CPP_SOURCES "." "*.cpp")
  79   SET(${BBTK_PACKAGE_NAME}_CXX_SOURCES ${${BBTK_PACKAGE_NAME}_CXX_SOURCES} ${${BBTK_PACKAGE_NAME}_CPP_SOURCES})
  80   FILE(GLOB ${BBTK_PACKAGE_NAME}_H_SOURCES "." "*.h")
  81 ENDIF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_CXX)
  82
  83 IF(NOT PROJECT_BINARY_DIR STREQUAL ${PROJECT_SOURCE_DIR})
  84   SET(${BBTK_PACKAGE_NAME}_CXX_SOURCES
  85     ${${BBTK_PACKAGE_NAME}_CXX_SOURCES}
  86     bb${BBTK_PACKAGE_NAME}Package
  87     )
  88 ENDIF(NOT PROJECT_BINARY_DIR STREQUAL ${PROJECT_SOURCE_DIR})
  89 #----------------------------------------------------------------------------
  90
  91
  92 #----------------------------------------------------------------------------
  93 #----------------------------------------------------------------------------
  94 # bbfy
  95 #----------------------------------------------------------------------------
  96
  97 #----------------------------------------------------------------------------
  98 IF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_XML)
  99   FILE(GLOB ${BBTK_PACKAGE_NAME}_XML_SOURCES "." "*.xml")
 100 ENDIF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_XML)
 101
 102
 103 #----------------------------------------------------------------------------
 104 FOREACH(xmlfile ${${BBTK_PACKAGE_NAME}_XML_SOURCES})
 105   GET_FILENAME_COMPONENT(filename "${xmlfile}" NAME_WE)
 106
 107   SET(BBFY_CXX_OUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.cxx)
 108
 109   IF (WIN32)
 110     MAKE_DLL_PATH()
 111  #   SET(command00 Path=c:/creatis/dlls__RR__%WXWIN%/lib/vc_dll/__RR__%VTK_DIR%__RR__%ITK_DIR%/../../bin/__RR__%PATH%)
 112  #   STRING(REPLACE "__RR__" "\;" SETPATH ${command00} )
 113  #   SET(SETPATH set ${command0} &&)
 114
 115  ADD_CUSTOM_COMMAND(
 116     OUTPUT ${BBFY_CXX_OUT}
 117     COMMAND
 118     set Path=${DLL_PATH} && ${BBTK_BBFY} ${xmlfile} ${BBTK_PACKAGE_NAME} ${CMAKE_CURRENT_BINARY_DIR}/ -q
 119     DEPENDS ${xmlfile}
 120     ${BBTK_BBFY_DEPENDENCY}
 121     )
 122   ELSE(WIN32)
 123     SET(LD_LIBRARY_PATH "$ENV{LD_LIBRARY_PATH}:${LIBRARY_OUTPUT_PATH}")
 124     ADD_CUSTOM_COMMAND(
 125       OUTPUT ${BBFY_CXX_OUT}
 126       COMMAND
 127       export LD_LIBRARY_PATH=${LD_LIBRARY_PATH} && ${BBTK_BBFY} ${xmlfile} ${BBTK_PACKAGE_NAME} ${CMAKE_CURRENT_BINARY_DIR}/ -q
 128       DEPENDS ${xmlfile}
 129       ${BBTK_BBFY_DEPENDENCY}
 130       )
 131
 132   ENDIF(WIN32)
 133
 134
 135   SET_SOURCE_FILES_PROPERTIES(
 136     ${BBFY_CXX_OUT}
 137     PROPERTIES GENERATED ON)
 138
 139
 140  IF(NOT ${BBTK_PACKAGE_NAME}_CXX_SOURCES MATCHES "${filename}.cxx")
 141  # message ("EED Alert BBTKConfigurePackage_src  "  "IF NOT MATCHES" )
 142   SET(${BBTK_PACKAGE_NAME}_CXX_SOURCES
 143       ${${BBTK_PACKAGE_NAME}_CXX_SOURCES}
 144       ${filename}.cxx
 145       )
 146  ENDIF(NOT ${BBTK_PACKAGE_NAME}_CXX_SOURCES MATCHES "${filename}.cxx")
 147
 148   INSTALL(
 149     FILES       ${CMAKE_CURRENT_BINARY_DIR}/${filename}.h
 150     DESTINATION include/bb${BBTK_PACKAGE_NAME})
 151 ENDFOREACH(xmlfile)
 152 #----------------------------------------------------------------------------
 153
 154
 155
 156 #----------------------------------------------------------------------------
 157 # CREATES LIBRARY
 158 #----------------------------------------------------------------------------
 159 # TCL WRAPPING FOR KWWIDGETS
 160 IF(BBTK_USE_KWWIDGETS)
 161 #MESSAGE(STATUS "****TCL=${${BBTK_PACKAGE_NAME}_CXX_SOURCES_WRAP_TCL}")
 162 IF(${BBTK_PACKAGE_NAME}_CXX_SOURCES_WRAP_TCL )
 163 #MESSAGE(STATUS "****TCL OK")
 164 include("${KWWidgets_CMAKE_DIR}/KWWidgetsWrappingMacros.cmake")
 165 kwwidgets_wrap_tcl(bb${BBTK_PACKAGE_NAME} LIB_TCL_SRCS ${${BBTK_PACKAGE_NAME}_CXX_SOURCES_WRAP_TCL} "")
 166 SET(${BBTK_PACKAGE_NAME}_CXX_SOURCES
 167   ${${BBTK_PACKAGE_NAME}_CXX_SOURCES}
 168   ${LIB_TCL_SRCS})
 169 ENDIF(${BBTK_PACKAGE_NAME}_CXX_SOURCES_WRAP_TCL)
 170 ENDIF(BBTK_USE_KWWIDGETS)
 171 #----------------------------------------------------------------------------
 172 #MESSAGE(STATUS ${${BBTK_PACKAGE_NAME}_CXX_SOURCES})
 173
 174 ADD_LIBRARY(bb${BBTK_PACKAGE_NAME} SHARED
 175   ${${BBTK_PACKAGE_NAME}_CXX_SOURCES} ${${BBTK_PACKAGE_NAME}_H_SOURCES}
 176   )
 177
 178
 179 TARGET_LINK_LIBRARIES(bb${BBTK_PACKAGE_NAME}
 180   bbtk
 181   ${${BBTK_PACKAGE_NAME}_LIBS}
 182   )
 183 IF(UNIX)
 184 SET_TARGET_PROPERTIES(bb${BBTK_PACKAGE_NAME} PROPERTIES COMPILE_FLAGS -Wall)
 185 ENDIF(UNIX)
 186 #----------------------------------------------------------------------------
 187
 188
 189 #----------------------------------------------------------------------------
 190 # INSTALLS LIBRARY
 191 FILE(GLOB ${BBTK_PACKAGE_NAME}_HEADERS "*.h")
 192 INSTALL(
 193   FILES ${${BBTK_PACKAGE_NAME}_HEADERS}
 194   DESTINATION include/bb${BBTK_PACKAGE_NAME}
 195   )
 196 INSTALL(
 197   TARGETS bb${BBTK_PACKAGE_NAME}
 198   DESTINATION ${BBTK_PACKAGE_LIB_PATH}
 199   )
 200
 201
 202 # Preparing macro invocation : CREA_ADVANCED_INSTALL_LIBRARY_FOR_CMAKE
 203 SET( LIBRARY_NAME bb${BBTK_PACKAGE_NAME} )
 204 # SET THE LIB VERSION
 205 SET(${LIBRARY_NAME}_MAJOR_VERSION ${${BBTK_PACKAGE_NAME}_MAJOR_VERSION})
 206 SET(${LIBRARY_NAME}_MINOR_VERSION ${${BBTK_PACKAGE_NAME}_MINOR_VERSION})
 207 SET(${LIBRARY_NAME}_BUILD_VERSION ${${BBTK_PACKAGE_NAME}_BUILD_VERSION})
 208 #
 209 SET(${LIBRARY_NAME}_INSTALL_FOLDER bb${BBTK_PACKAGE_NAME})
 210 SET(${LIBRARY_NAME}_LIBRARIES bb${BBTK_PACKAGE_NAME})
 211
 212 FILE(RELATIVE_PATH
 213   ${LIBRARY_NAME}_BUILD_TREE_RELATIVE_INCLUDE_PATHS
 214   ${PROJECT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}
 215   )
 216
 217 IF ( ${PROJECT_BINARY_DIR} STREQUAL ${EXECUTABLE_OUTPUT_PATH} )
 218   SET(CILFC_EXECUTABLE_OUTPUT_REL_PATH ".")
 219 ELSE ( ${PROJECT_BINARY_DIR} STREQUAL ${EXECUTABLE_OUTPUT_PATH} )
 220   FILE(RELATIVE_PATH
 221     CILFC_EXECUTABLE_OUTPUT_REL_PATH
 222     ${PROJECT_BINARY_DIR} ${EXECUTABLE_OUTPUT_PATH})
 223 ENDIF ( ${PROJECT_BINARY_DIR} STREQUAL ${EXECUTABLE_OUTPUT_PATH} )
 224
 225 IF(UNIX)
 226   SET(${LIBRARY_NAME}_BUILD_TREE_RELATIVE_LIBRARY_PATHS
 227     ${CILFC_EXECUTABLE_OUTPUT_REL_PATH})
 228 ELSE(UNIX)
 229   SET(${LIBRARY_NAME}_BUILD_TREE_RELATIVE_LIBRARY_PATHS
 230     ${CILFC_EXECUTABLE_OUTPUT_REL_PATH})
 231 ENDIF(UNIX)
 232
 233 SET(${LIBRARY_NAME}_INSTALL_TREE_RELATIVE_INCLUDE_PATHS
 234   include/bb${BBTK_PACKAGE_NAME})
 235 SET(${LIBRARY_NAME}_INSTALL_TREE_RELATIVE_LIBRARY_PATHS ${BBTK_PACKAGE_LIB_PATH})
 236
 237 # REQUIRED BUILD FLAGS
 238 #SET(${LIBRARY_NAME}_REQUIRED_C_FLAGS "")
 239 #SET(${LIBRARY_NAME}_REQUIRED_CXX_FLAGS "")
 240 #SET(${LIBRARY_NAME}_REQUIRED_LINK_FLAGS "")
 241
 242 # Additional config/use
 243 # Prepare for configure
 244 SET(BBTK_PACKAGE_USE_VTK       ${${BBTK_PACKAGE_NAME}_USE_VTK})
 245 SET(BBTK_PACKAGE_USE_ITK       ${${BBTK_PACKAGE_NAME}_USE_ITK})
 246 SET(BBTK_PACKAGE_USE_QT        ${${BBTK_PACKAGE_NAME}_USE_QT})
 247 SET(BBTK_PACKAGE_USE_GDCM      ${${BBTK_PACKAGE_NAME}_USE_GDCM})
 248 SET(BBTK_PACKAGE_USE_GDCM2     ${${BBTK_PACKAGE_NAME}_USE_GDCM2})
 249 SET(BBTK_PACKAGE_USE_GSMIS     ${${BBTK_PACKAGE_NAME}_USE_GSMIS})
 250 SET(BBTK_PACKAGE_USE_WXWIDGETS ${${BBTK_PACKAGE_NAME}_USE_WXWIDGETS})
 251 SET(BBTK_PACKAGE_USE_PACKAGES  ${${BBTK_PACKAGE_NAME}_USE_PACKAGES})
 252 SET(BBTK_PACKAGE_INCLUDE_DIRS  ${${BBTK_PACKAGE_NAME}_INCLUDE_DIRS})
 253 SET(BBTK_PACKAGE_LIBS          ${${BBTK_PACKAGE_NAME}_LIBS})
 254
 255 SET(${LIBRARY_NAME}_HAS_ADDITIONAL_CONFIG_FILE TRUE)
 256 SET(${LIBRARY_NAME}_ADDITIONAL_CONFIG_FILE
 257   ${${BBTK_PACKAGE_NAME}_SOURCE_DIR}/PackageConfig.cmake.in)
 258 SET(${LIBRARY_NAME}_ADDITIONAL_USE_FILE
 259   ${${BBTK_PACKAGE_NAME}_SOURCE_DIR}/UsePackage.cmake.in)
 260 #-----------------------------------------------------------------------------
 261
 262 #-----------------------------------------------------------------------------
 263 CREA_ADVANCED_INSTALL_LIBRARY_FOR_CMAKE(${LIBRARY_NAME})
 264 #-----------------------------------------------------------------------------
 265
 266 #----------------------------------------------------------------------------
 267
 268
 269
 270
 271 #---------------------------------------------------------------------------
 272 IF(CHCON_LIBRARIES)
 273   # On recent linux running SELinux :
 274   # Have to change the context of the library created
 275   # to be able to load it dynamically and avoid the error :
 276   # "cannot restore segment prot after reloc: Permission denied"
 277   # see e.g.
 278   # http://www.ittvis.com/services/techtip.asp?ttid=3092
 279   # Try to find chcon
 280   FIND_PROGRAM(CHCON_EXECUTABLE
 281     NAMES chcon
 282     PATHS
 283     /usr/bin
 284     /usr/local/bin
 285     )
 286   MARK_AS_ADVANCED(CHCON_EXECUTABLE)
 287   IF(CHCON_EXECUTABLE)
 288     # chcon found
 289     # custom post_build command to change the context of the .so generated
 290     ADD_CUSTOM_COMMAND(
 291       TARGET bb${BBTK_PACKAGE_NAME}
 292       POST_BUILD
 293       COMMAND chcon -t texrel_shlib_t ${LIBRARY_OUTPUT_PATH}/libbb${BBTK_PACKAGE_NAME}.so
 294       )
 295     # custom post-install command to change the context of the .so installed
 296     INSTALL(CODE "EXEC_PROGRAM(chcon ARGS -t texrel_shlib_t ${CMAKE_INSTALL_PREFIX}/lib/libbb${BBTK_PACKAGE_NAME}.so)")
 297   ENDIF(CHCON_EXECUTABLE)
 298 ENDIF(CHCON_LIBRARIES)
 299 #----------------------------------------------------------------------------
 300