kernel/cmake/BBTKConfigurePackage_src.cmake

   1
   2 #----------------------------------------------------------------------------
   3 # BINARY DIR MUST BE IN INCLUDE DIRS
   4 # TO FIND .h OF AUTOMATICALLY GENERATED FILES (e.g. FROM XML)
   5 INCLUDE_DIRECTORIES( ${CMAKE_CURRENT_BINARY_DIR} )
   6 # SOURCES DIR MUST ALSO BE IN INCLUDE DIRS FOR FILES COMPILED IN BINARY DIR
   7 # WHICH NEED TO INCLUDE OTHER FILES OF THE PACKAGE
   8 INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR} )
   9 #----------------------------------------------------------------------------
  10
  11
  12
  13 #----------------------------------------------------------------------------
  14
  15 #----------------------------------------------------------------------------
  16 # CREATES bb${BBTK_PACKAGE_NAME}Package.h
  17 CONFIGURE_FILE(
  18   ${BBTK_CMAKE_DIR}/bbPackage.h.in
  19   ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.h
  20   @ONLY IMMEDIATE
  21   )
  22 INSTALL(
  23   FILES ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.h
  24   DESTINATION include/bb${BBTK_PACKAGE_NAME}
  25   )
  26 #----------------------------------------------------------------------------
  27
  28 #----------------------------------------------------------------------------
  29 # CREATES bb${BBTK_PACKAGE_NAME}Package.cxx
  30 CONFIGURE_FILE(
  31   ${BBTK_CMAKE_DIR}/bbPackage.cxx.in
  32   ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.cxx
  33   @ONLY IMMEDIATE
  34   )
  35 #----------------------------------------------------------------------------
  36
  37 #----------------------------------------------------------------------------
  38 SET_SOURCE_FILES_PROPERTIES(
  39   ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.cxx
  40   PROPERTIES GENERATED ON)
  41 #----------------------------------------------------------------------------
  42
  43
  44 #----------------------------------------------------------------------------
  45 IF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_CXX)
  46   FILE(GLOB ${BBTK_PACKAGE_NAME}_CXX_SOURCES "." "*.cxx")
  47   FILE(GLOB ${BBTK_PACKAGE_NAME}_H_SOURCES "." "*.h")
  48 ENDIF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_CXX)
  49
  50
  51 SET(${BBTK_PACKAGE_NAME}_CXX_SOURCES
  52   ${${BBTK_PACKAGE_NAME}_CXX_SOURCES}
  53   #${CMAKE_CURRENT_BINARY_DIR_NAME}/
  54   bb${BBTK_PACKAGE_NAME}Package
  55   )
  56 #----------------------------------------------------------------------------
  57
  58
  59 #----------------------------------------------------------------------------
  60 #----------------------------------------------------------------------------
  61 # bbfy
  62 #----------------------------------------------------------------------------
  63
  64 #----------------------------------------------------------------------------
  65 IF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_XML)
  66   FILE(GLOB ${BBTK_PACKAGE_NAME}_XML_SOURCES "." "*.xml")
  67 ENDIF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_XML)
  68 #----------------------------------------------------------------------------
  69 FOREACH(xmlfile ${${BBTK_PACKAGE_NAME}_XML_SOURCES})
  70
  71   GET_FILENAME_COMPONENT(filename "${xmlfile}" NAME_WE)
  72
  73   SET(BBFY_CXX_OUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.cxx)
  74
  75   IF (WIN32)
  76     SET(command00 Path=%WXWIN%/lib/vc_dll/__RR__%VTK_DIR%__RR__%ITK_DIR%/../../bin/__RR__%PATH%)
  77     STRING(REPLACE "__RR__" "\;" SETPATH ${command00} )
  78         #    SET(SETPATH set ${command0} &&)
  79  ADD_CUSTOM_COMMAND(
  80     OUTPUT ${BBFY_CXX_OUT}
  81     COMMAND
  82     set ${SETPATH} && ${BBTK_BBFY} ${xmlfile} ${BBTK_PACKAGE_NAME} ${CMAKE_CURRENT_BINARY_DIR}/ -q
  83     DEPENDS ${xmlfile}
  84     ${BBTK_BBFY_DEPENDENCY}
  85     )
  86   ELSE(WIN32)
  87  ADD_CUSTOM_COMMAND(
  88     OUTPUT ${BBFY_CXX_OUT}
  89     COMMAND
  90     ${BBTK_BBFY} ${xmlfile} ${BBTK_PACKAGE_NAME} ${CMAKE_CURRENT_BINARY_DIR}/ -q
  91     DEPENDS ${xmlfile}
  92     ${BBTK_BBFY_DEPENDENCY}
  93     )
  94
  95         ENDIF(WIN32)
  96
  97
  98   SET_SOURCE_FILES_PROPERTIES(
  99     ${BBFY_CXX_OUT}
 100     PROPERTIES GENERATED ON)
 101
 102
 103  IF(NOT ${BBTK_PACKAGE_NAME}_CXX_SOURCES MATCHES "${filename}.cxx")
 104  # message ("EED Alert BBTKConfigurePackage_src  "  "IF NOT MATCHES" )
 105   SET(${BBTK_PACKAGE_NAME}_CXX_SOURCES
 106       ${${BBTK_PACKAGE_NAME}_CXX_SOURCES}
 107       ${filename}.cxx
 108       )
 109  ENDIF(NOT ${BBTK_PACKAGE_NAME}_CXX_SOURCES MATCHES "${filename}.cxx")
 110
 111   INSTALL(
 112     FILES       ${CMAKE_CURRENT_BINARY_DIR}/${filename}.h
 113     DESTINATION include/bb${BBTK_PACKAGE_NAME})
 114 ENDFOREACH(xmlfile)
 115 #----------------------------------------------------------------------------
 116
 117
 118
 119 #----------------------------------------------------------------------------
 120 # CREATES LIBRARY
 121 ADD_LIBRARY(bb${BBTK_PACKAGE_NAME} SHARED
 122   ${${BBTK_PACKAGE_NAME}_CXX_SOURCES} ${${BBTK_PACKAGE_NAME}_H_SOURCES}
 123   )
 124 TARGET_LINK_LIBRARIES(bb${BBTK_PACKAGE_NAME}
 125   bbtk
 126   ${${BBTK_PACKAGE_NAME}_LIBS}
 127   )
 128 #----------------------------------------------------------------------------
 129
 130
 131 #----------------------------------------------------------------------------
 132 # INSTALLS LIBRARY
 133 FILE(GLOB ${BBTK_PACKAGE_NAME}_HEADERS "*.h")
 134 INSTALL(
 135   FILES ${${BBTK_PACKAGE_NAME}_HEADERS}
 136   DESTINATION include/bb${BBTK_PACKAGE_NAME}
 137   )
 138 INSTALL(
 139   TARGETS bb${BBTK_PACKAGE_NAME}
 140   DESTINATION lib)
 141
 142 # CreateFindPackage
 143 SET( LIBRARY_NAME bb${BBTK_PACKAGE_NAME} )
 144 # SET THE LIB VERSION
 145 SET(${LIBRARY_NAME}_MAJOR_VERSION ${${BBTK_PACKAGE_NAME}_MAJOR_VERSION})
 146 SET(${LIBRARY_NAME}_MINOR_VERSION ${${BBTK_PACKAGE_NAME}_MINOR_VERSION})
 147 SET(${LIBRARY_NAME}_BUILD_VERSION ${${BBTK_PACKAGE_NAME}_BUILD_VERSION})
 148 #
 149 SET(${LIBRARY_NAME}_INSTALL_FOLDER bb${BBTK_PACKAGE_NAME})
 150 SET(${LIBRARY_NAME}_LIBRARIES bb${BBTK_PACKAGE_NAME})
 151
 152 FILE(RELATIVE_PATH
 153   ${LIBRARY_NAME}_BUILD_TREE_RELATIVE_INCLUDE_PATHS
 154   ${PROJECT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}
 155   )
 156
 157 IF(UNIX)
 158   SET(${LIBRARY_NAME}_BUILD_TREE_RELATIVE_LIBRARY_PATHS
 159     ${EXECUTABLE_OUTPUT_REL_PATH})
 160 ELSE(UNIX)
 161   SET(${LIBRARY_NAME}_BUILD_TREE_RELATIVE_LIBRARY_PATHS
 162     ${EXECUTABLE_OUTPUT_REL_PATH}/Debug
 163     ${EXECUTABLE_OUTPUT_REL_PATH}/Release)
 164 ENDIF(UNIX)
 165 SET(${LIBRARY_NAME}_INSTALL_TREE_RELATIVE_INCLUDE_PATHS
 166   include/bb${BBTK_PACKAGE_NAME})
 167 SET(${LIBRARY_NAME}_INSTALL_TREE_RELATIVE_LIBRARY_PATHS lib)
 168
 169 # REQUIRED BUILD FLAGS
 170 #SET(${LIBRARY_NAME}_REQUIRED_C_FLAGS "")
 171 #SET(${LIBRARY_NAME}_REQUIRED_CXX_FLAGS "")
 172 #SET(${LIBRARY_NAME}_REQUIRED_LINK_FLAGS "")
 173
 174 # Additional config/use
 175 # Prepare for configure
 176 SET(BBTK_PACKAGE_USE_VTK ${${BBTK_PACKAGE_NAME}_USE_VTK})
 177 SET(BBTK_PACKAGE_USE_ITK ${${BBTK_PACKAGE_NAME}_USE_ITK})
 178 SET(BBTK_PACKAGE_USE_GDCM ${${BBTK_PACKAGE_NAME}_USE_GDCM})
 179 SET(BBTK_PACKAGE_USE_GSMIS ${${BBTK_PACKAGE_NAME}_USE_GSMIS})
 180 SET(BBTK_PACKAGE_USE_WXWIDGETS ${${BBTK_PACKAGE_NAME}_USE_WXWIDGETS})
 181 SET(BBTK_PACKAGE_USE_PACKAGES  ${${BBTK_PACKAGE_NAME}_USE_PACKAGES})
 182 SET(BBTK_PACKAGE_INCLUDE_DIRS  ${${BBTK_PACKAGE_NAME}_INCLUDE_DIRS})
 183 SET(BBTK_PACKAGE_LIBS          ${${BBTK_PACKAGE_NAME}_LIBS})
 184
 185 SET(${LIBRARY_NAME}_HAS_ADDITIONAL_CONFIG_FILE TRUE)
 186 SET(${LIBRARY_NAME}_ADDITIONAL_CONFIG_FILE
 187   ${${BBTK_PACKAGE_NAME}_SOURCE_DIR}/PackageConfig.cmake.in)
 188 SET(${LIBRARY_NAME}_ADDITIONAL_USE_FILE
 189   ${${BBTK_PACKAGE_NAME}_SOURCE_DIR}/UsePackage.cmake.in)
 190 #-----------------------------------------------------------------------------
 191
 192 #-----------------------------------------------------------------------------
 193 # Includes CMakeCreateFindPackage
 194 INCLUDE(${CMakeCreateFindPackage_DIR}/CMakeCreateFindPackage.cmake)
 195 CMAKE_CREATE_FIND_PACKAGE(${LIBRARY_NAME})
 196 #-----------------------------------------------------------------------------
 197
 198 #----------------------------------------------------------------------------
 199
 200
 201
 202
 203 #---------------------------------------------------------------------------
 204 IF(CHCON_LIBRARIES)
 205   # On recent linux running SELinux :
 206   # Have to change the context of the library created
 207   # to be able to load it dynamically and avoid the error :
 208   # "cannot restore segment prot after reloc: Permission denied"
 209   # see e.g.
 210   # http://www.ittvis.com/services/techtip.asp?ttid=3092
 211   # Try to find chcon
 212   FIND_PROGRAM(CHCON_EXECUTABLE
 213     NAMES chcon
 214     PATHS
 215     /usr/bin
 216     /usr/local/bin
 217     )
 218   MARK_AS_ADVANCED(CHCON_EXECUTABLE)
 219   IF(CHCON_EXECUTABLE)
 220     # chcon found
 221     # custom post_build command to change the context of the .so generated
 222     ADD_CUSTOM_COMMAND(
 223       TARGET bb${BBTK_PACKAGE_NAME}
 224       POST_BUILD
 225       COMMAND chcon -t texrel_shlib_t ${LIBRARY_OUTPUT_PATH}/libbb${BBTK_PACKAGE_NAME}.so
 226       )
 227     # custom post-install command to change the context of the .so installed
 228     INSTALL(CODE "EXEC_PROGRAM(chcon ARGS -t texrel_shlib_t ${CMAKE_INSTALL_PREFIX}/lib/libbb${BBTK_PACKAGE_NAME}.so)")
 229   ENDIF(CHCON_EXECUTABLE)
 230 ENDIF(CHCON_LIBRARIES)
 231 #----------------------------------------------------------------------------
 232