kernel/cmake/BBTKConfigurePackage_src.cmake

   1
   2 #----------------------------------------------------------------------------
   3 # BINARY DIR MUST BE IN INCLUDE DIRS
   4 # TO FIND .h OF AUTOMATICALLY GENERATED FILES (e.g. FROM XML)
   5 INCLUDE_DIRECTORIES( ${CMAKE_CURRENT_BINARY_DIR} )
   6 # SOURCES DIR MUST ALSO BE IN INCLUDE DIRS FOR FILES COMPILED IN BINARY DIR
   7 # WHICH NEED TO INCLUDE OTHER FILES OF THE PACKAGE
   8 INCLUDE_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR} )
   9 #----------------------------------------------------------------------------
  10
  11 #----------------------------------------------------------------------------
  12 # CREATES bb${BBTK_PACKAGE_NAME}_EXPORT.h
  13 CREA_DYNAMIC_LIBRARY_EXPORT(bb${BBTK_PACKAGE_NAME})
  14 INSTALL(
  15   FILES ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}_EXPORT.h
  16   DESTINATION include/bb${BBTK_PACKAGE_NAME}
  17   )
  18 #----------------------------------------------------------------------------
  19
  20 #----------------------------------------------------------------------------
  21 # CREATES bb${BBTK_PACKAGE_NAME}Package.h
  22 CONFIGURE_FILE(
  23   ${BBTK_CMAKE_DIR}/bbPackage.h.in
  24   ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.h
  25   @ONLY IMMEDIATE
  26   )
  27 INSTALL(
  28   FILES ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.h
  29   DESTINATION include/bb${BBTK_PACKAGE_NAME}
  30   )
  31 #----------------------------------------------------------------------------
  32
  33 #----------------------------------------------------------------------------
  34 # CREATES bb${BBTK_PACKAGE_NAME}Package.cxx
  35 CONFIGURE_FILE(
  36   ${BBTK_CMAKE_DIR}/bbPackage.cxx.in
  37   ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.cxx
  38   @ONLY IMMEDIATE
  39   )
  40 #----------------------------------------------------------------------------
  41
  42 #----------------------------------------------------------------------------
  43 SET_SOURCE_FILES_PROPERTIES(
  44   ${CMAKE_CURRENT_BINARY_DIR}/bb${BBTK_PACKAGE_NAME}Package.cxx
  45   PROPERTIES GENERATED ON)
  46 #----------------------------------------------------------------------------
  47
  48
  49 #----------------------------------------------------------------------------
  50 IF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_CXX)
  51   FILE(GLOB ${BBTK_PACKAGE_NAME}_CXX_SOURCES "." "*.cxx")
  52   FILE(GLOB ${BBTK_PACKAGE_NAME}_CPP_SOURCES "." "*.cpp")
  53   SET(${BBTK_PACKAGE_NAME}_CXX_SOURCES ${${BBTK_PACKAGE_NAME}_CXX_SOURCES} ${${BBTK_PACKAGE_NAME}_CPP_SOURCES})
  54   FILE(GLOB ${BBTK_PACKAGE_NAME}_H_SOURCES "." "*.h")
  55 ENDIF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_CXX)
  56 IF(NOT PROJECT_BINARY_DIR STREQUAL ${PROJECT_SOURCE_DIR})
  57   SET(${BBTK_PACKAGE_NAME}_CXX_SOURCES
  58     ${${BBTK_PACKAGE_NAME}_CXX_SOURCES}
  59     bb${BBTK_PACKAGE_NAME}Package
  60     )
  61 ENDIF(NOT PROJECT_BINARY_DIR STREQUAL ${PROJECT_SOURCE_DIR})
  62 #----------------------------------------------------------------------------
  63
  64
  65 #----------------------------------------------------------------------------
  66 #----------------------------------------------------------------------------
  67 # bbfy
  68 #----------------------------------------------------------------------------
  69
  70 #----------------------------------------------------------------------------
  71 IF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_XML)
  72   FILE(GLOB ${BBTK_PACKAGE_NAME}_XML_SOURCES "." "*.xml")
  73 ENDIF(${BBTK_PACKAGE_NAME}_COMPILE_ALL_XML)
  74 #----------------------------------------------------------------------------
  75 FOREACH(xmlfile ${${BBTK_PACKAGE_NAME}_XML_SOURCES})
  76
  77   GET_FILENAME_COMPONENT(filename "${xmlfile}" NAME_WE)
  78
  79   SET(BBFY_CXX_OUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.cxx)
  80
  81   IF (WIN32)
  82     MAKE_DLL_PATH()
  83  #   SET(command00 Path=c:/creatis/dlls__RR__%WXWIN%/lib/vc_dll/__RR__%VTK_DIR%__RR__%ITK_DIR%/../../bin/__RR__%PATH%)
  84  #   STRING(REPLACE "__RR__" "\;" SETPATH ${command00} )
  85  #   SET(SETPATH set ${command0} &&)
  86  ADD_CUSTOM_COMMAND(
  87     OUTPUT ${BBFY_CXX_OUT}
  88     COMMAND
  89     set Path=${DLL_PATH} && ${BBTK_BBFY} ${xmlfile} ${BBTK_PACKAGE_NAME} ${CMAKE_CURRENT_BINARY_DIR}/ -q
  90     DEPENDS ${xmlfile}
  91     ${BBTK_BBFY_DEPENDENCY}
  92     )
  93   ELSE(WIN32)
  94     SET(LD_LIBRARY_PATH "$ENV{LD_LIBRARY_PATH}:${LIBRARY_OUTPUT_PATH}")
  95     ADD_CUSTOM_COMMAND(
  96       OUTPUT ${BBFY_CXX_OUT}
  97       COMMAND
  98       export LD_LIBRARY_PATH=${LD_LIBRARY_PATH} && ${BBTK_BBFY} ${xmlfile} ${BBTK_PACKAGE_NAME} ${CMAKE_CURRENT_BINARY_DIR}/ -q
  99       DEPENDS ${xmlfile}
 100       ${BBTK_BBFY_DEPENDENCY}
 101       )
 102
 103   ENDIF(WIN32)
 104
 105
 106   SET_SOURCE_FILES_PROPERTIES(
 107     ${BBFY_CXX_OUT}
 108     PROPERTIES GENERATED ON)
 109
 110
 111  IF(NOT ${BBTK_PACKAGE_NAME}_CXX_SOURCES MATCHES "${filename}.cxx")
 112  # message ("EED Alert BBTKConfigurePackage_src  "  "IF NOT MATCHES" )
 113   SET(${BBTK_PACKAGE_NAME}_CXX_SOURCES
 114       ${${BBTK_PACKAGE_NAME}_CXX_SOURCES}
 115       ${filename}.cxx
 116       )
 117  ENDIF(NOT ${BBTK_PACKAGE_NAME}_CXX_SOURCES MATCHES "${filename}.cxx")
 118
 119   INSTALL(
 120     FILES       ${CMAKE_CURRENT_BINARY_DIR}/${filename}.h
 121     DESTINATION include/bb${BBTK_PACKAGE_NAME})
 122 ENDFOREACH(xmlfile)
 123 #----------------------------------------------------------------------------
 124
 125
 126
 127 #----------------------------------------------------------------------------
 128 # CREATES LIBRARY
 129 #----------------------------------------------------------------------------
 130 # TCL WRAPPING FOR KWWIDGETS
 131 IF(BBTK_USE_KWWIDGETS)
 132 #MESSAGE(STATUS "****TCL=${${BBTK_PACKAGE_NAME}_CXX_SOURCES_WRAP_TCL}")
 133 IF(${BBTK_PACKAGE_NAME}_CXX_SOURCES_WRAP_TCL )
 134 #MESSAGE(STATUS "****TCL OK")
 135 include("${KWWidgets_CMAKE_DIR}/KWWidgetsWrappingMacros.cmake")
 136 kwwidgets_wrap_tcl(bb${BBTK_PACKAGE_NAME} LIB_TCL_SRCS ${${BBTK_PACKAGE_NAME}_CXX_SOURCES_WRAP_TCL} "")
 137 SET(${BBTK_PACKAGE_NAME}_CXX_SOURCES
 138   ${${BBTK_PACKAGE_NAME}_CXX_SOURCES}
 139   ${LIB_TCL_SRCS})
 140 ENDIF(${BBTK_PACKAGE_NAME}_CXX_SOURCES_WRAP_TCL)
 141 ENDIF(BBTK_USE_KWWIDGETS)
 142 #----------------------------------------------------------------------------
 143 #MESSAGE(STATUS ${${BBTK_PACKAGE_NAME}_CXX_SOURCES})
 144
 145 ADD_LIBRARY(bb${BBTK_PACKAGE_NAME} SHARED
 146   ${${BBTK_PACKAGE_NAME}_CXX_SOURCES} ${${BBTK_PACKAGE_NAME}_H_SOURCES}
 147   )
 148 TARGET_LINK_LIBRARIES(bb${BBTK_PACKAGE_NAME}
 149   bbtk
 150   ${${BBTK_PACKAGE_NAME}_LIBS}
 151   )
 152 IF(UNIX)
 153 SET_TARGET_PROPERTIES(bb${BBTK_PACKAGE_NAME} PROPERTIES COMPILE_FLAGS -Wall)
 154 ENDIF(UNIX)
 155 #----------------------------------------------------------------------------
 156
 157
 158 #----------------------------------------------------------------------------
 159 # INSTALLS LIBRARY
 160 FILE(GLOB ${BBTK_PACKAGE_NAME}_HEADERS "*.h")
 161 INSTALL(
 162   FILES ${${BBTK_PACKAGE_NAME}_HEADERS}
 163   DESTINATION include/bb${BBTK_PACKAGE_NAME}
 164   )
 165 INSTALL(
 166   TARGETS bb${BBTK_PACKAGE_NAME}
 167   DESTINATION ${BBTK_PACKAGE_LIB_PATH})
 168
 169 # Preparing macro invocation : CREA_ADVANCED_INSTALL_LIBRARY_FOR_CMAKE
 170 SET( LIBRARY_NAME bb${BBTK_PACKAGE_NAME} )
 171 # SET THE LIB VERSION
 172 SET(${LIBRARY_NAME}_MAJOR_VERSION ${${BBTK_PACKAGE_NAME}_MAJOR_VERSION})
 173 SET(${LIBRARY_NAME}_MINOR_VERSION ${${BBTK_PACKAGE_NAME}_MINOR_VERSION})
 174 SET(${LIBRARY_NAME}_BUILD_VERSION ${${BBTK_PACKAGE_NAME}_BUILD_VERSION})
 175 #
 176 SET(${LIBRARY_NAME}_INSTALL_FOLDER bb${BBTK_PACKAGE_NAME})
 177 SET(${LIBRARY_NAME}_LIBRARIES bb${BBTK_PACKAGE_NAME})
 178
 179 FILE(RELATIVE_PATH
 180   ${LIBRARY_NAME}_BUILD_TREE_RELATIVE_INCLUDE_PATHS
 181   ${PROJECT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}
 182   )
 183
 184 IF ( ${PROJECT_BINARY_DIR} STREQUAL ${EXECUTABLE_OUTPUT_PATH} )
 185   SET(CILFC_EXECUTABLE_OUTPUT_REL_PATH ".")
 186 ELSE ( ${PROJECT_BINARY_DIR} STREQUAL ${EXECUTABLE_OUTPUT_PATH} )
 187   FILE(RELATIVE_PATH
 188     CILFC_EXECUTABLE_OUTPUT_REL_PATH
 189     ${PROJECT_BINARY_DIR} ${EXECUTABLE_OUTPUT_PATH})
 190 ENDIF ( ${PROJECT_BINARY_DIR} STREQUAL ${EXECUTABLE_OUTPUT_PATH} )
 191
 192 IF(UNIX)
 193   SET(${LIBRARY_NAME}_BUILD_TREE_RELATIVE_LIBRARY_PATHS
 194     ${CILFC_EXECUTABLE_OUTPUT_REL_PATH})
 195 ELSE(UNIX)
 196   SET(${LIBRARY_NAME}_BUILD_TREE_RELATIVE_LIBRARY_PATHS
 197     ${CILFC_EXECUTABLE_OUTPUT_REL_PATH})
 198 ENDIF(UNIX)
 199
 200 SET(${LIBRARY_NAME}_INSTALL_TREE_RELATIVE_INCLUDE_PATHS
 201   include/bb${BBTK_PACKAGE_NAME})
 202 SET(${LIBRARY_NAME}_INSTALL_TREE_RELATIVE_LIBRARY_PATHS ${BBTK_PACKAGE_LIB_PATH})
 203
 204 # REQUIRED BUILD FLAGS
 205 #SET(${LIBRARY_NAME}_REQUIRED_C_FLAGS "")
 206 #SET(${LIBRARY_NAME}_REQUIRED_CXX_FLAGS "")
 207 #SET(${LIBRARY_NAME}_REQUIRED_LINK_FLAGS "")
 208
 209 # Additional config/use
 210 # Prepare for configure
 211 SET(BBTK_PACKAGE_USE_VTK ${${BBTK_PACKAGE_NAME}_USE_VTK})
 212 SET(BBTK_PACKAGE_USE_ITK ${${BBTK_PACKAGE_NAME}_USE_ITK})
 213 SET(BBTK_PACKAGE_USE_GDCM ${${BBTK_PACKAGE_NAME}_USE_GDCM})
 214 SET(BBTK_PACKAGE_USE_GSMIS ${${BBTK_PACKAGE_NAME}_USE_GSMIS})
 215 SET(BBTK_PACKAGE_USE_WXWIDGETS ${${BBTK_PACKAGE_NAME}_USE_WXWIDGETS})
 216 SET(BBTK_PACKAGE_USE_PACKAGES  ${${BBTK_PACKAGE_NAME}_USE_PACKAGES})
 217 SET(BBTK_PACKAGE_INCLUDE_DIRS  ${${BBTK_PACKAGE_NAME}_INCLUDE_DIRS})
 218 SET(BBTK_PACKAGE_LIBS          ${${BBTK_PACKAGE_NAME}_LIBS})
 219
 220 SET(${LIBRARY_NAME}_HAS_ADDITIONAL_CONFIG_FILE TRUE)
 221 SET(${LIBRARY_NAME}_ADDITIONAL_CONFIG_FILE
 222   ${${BBTK_PACKAGE_NAME}_SOURCE_DIR}/PackageConfig.cmake.in)
 223 SET(${LIBRARY_NAME}_ADDITIONAL_USE_FILE
 224   ${${BBTK_PACKAGE_NAME}_SOURCE_DIR}/UsePackage.cmake.in)
 225 #-----------------------------------------------------------------------------
 226
 227 #-----------------------------------------------------------------------------
 228 CREA_ADVANCED_INSTALL_LIBRARY_FOR_CMAKE(${LIBRARY_NAME})
 229 #-----------------------------------------------------------------------------
 230
 231 #----------------------------------------------------------------------------
 232
 233
 234
 235
 236 #---------------------------------------------------------------------------
 237 IF(CHCON_LIBRARIES)
 238   # On recent linux running SELinux :
 239   # Have to change the context of the library created
 240   # to be able to load it dynamically and avoid the error :
 241   # "cannot restore segment prot after reloc: Permission denied"
 242   # see e.g.
 243   # http://www.ittvis.com/services/techtip.asp?ttid=3092
 244   # Try to find chcon
 245   FIND_PROGRAM(CHCON_EXECUTABLE
 246     NAMES chcon
 247     PATHS
 248     /usr/bin
 249     /usr/local/bin
 250     )
 251   MARK_AS_ADVANCED(CHCON_EXECUTABLE)
 252   IF(CHCON_EXECUTABLE)
 253     # chcon found
 254     # custom post_build command to change the context of the .so generated
 255     ADD_CUSTOM_COMMAND(
 256       TARGET bb${BBTK_PACKAGE_NAME}
 257       POST_BUILD
 258       COMMAND chcon -t texrel_shlib_t ${LIBRARY_OUTPUT_PATH}/libbb${BBTK_PACKAGE_NAME}.so
 259       )
 260     # custom post-install command to change the context of the .so installed
 261     INSTALL(CODE "EXEC_PROGRAM(chcon ARGS -t texrel_shlib_t ${CMAKE_INSTALL_PREFIX}/lib/libbb${BBTK_PACKAGE_NAME}.so)")
 262   ENDIF(CHCON_EXECUTABLE)
 263 ENDIF(CHCON_LIBRARIES)
 264 #----------------------------------------------------------------------------
 265