kernel/doc/bbtkWebSite/CMakeLists.txt

   1 # Configure & install images
   2 BBTK_DOC_INSTALL_IMAGES(bbtkWebSite)
   3
   4 # Configure html pages for build tree and install
   5 FILE(GLOB HTML_PAGES "." "*.html")
   6 FOREACH(page ${HTML_PAGES})
   7   GET_FILENAME_COMPONENT(filename "${page}" NAME)
   8   CONFIGURE_FILE(
   9     ${page}
  10     ${BBTK_DOC_BUILD_PATH}/bbtkWebSite/${filename}
  11     @ONLY
  12     )
  13   # Install
  14   INSTALL(
  15     FILES ${BBTK_DOC_BUILD_PATH}/bbtkWebSite/${filename}
  16     DESTINATION ${BBTK_DOC_INSTALL_PATH}/bbtkWebSite
  17     )
  18 ENDFOREACH(page)
  19
  20 # Index generation
  21 SET(BBTK_INDEX_ALPHA_FILE ${BBTK_BBDOC_BUILD_PATH}/index-alpha.html)
  22 SET(BBTK_INDEX_PACKAGES_FILE ${BBTK_BBDOC_BUILD_PATH}/index-package.html)
  23 SET(BBTK_INDEX_CATEGORIES_FILE ${BBTK_BBDOC_BUILD_PATH}/index-category.html)
  24 SET(INDEX_OUTPUT
  25   ${BBTK_INDEX_ALPHA_FILE} ${BBTK_INDEX_PACKAGES_FILE}
  26   ${BBTK_INDEX_CATEGORIES_FILE}
  27   )
  28
  29 CONFIGURE_FILE(
  30   ${CMAKE_CURRENT_SOURCE_DIR}/make-index.bbs.in
  31   ${CMAKE_CURRENT_BINARY_DIR}/make-index.bbs
  32   @ONLY
  33   )
  34 ADD_CUSTOM_COMMAND(
  35   OUTPUT ${INDEX_OUTPUT}
  36   COMMAND
  37   cd ${BBTK_BIN_PATH} && ${BBTK_BBI} -n ${CMAKE_CURRENT_BINARY_DIR}/make-index.bbs
  38   DEPENDS ${BBTK_BBI_DEPENDENCY} ${BBTK_PACKAGES_DEPS}
  39   )
  40 ADD_CUSTOM_TARGET(bbdoc_index ALL
  41   DEPENDS ${INDEX_OUTPUT}
  42   )
  43 INSTALL(
  44   FILES ${INDEX_OUTPUT}
  45   DESTINATION ${BBTK_BBDOC_INSTALL_PATH}
  46   )
  47
  48 # create make-index.bbs for build / install tree
  49 SET(BBTK_INDEX_ALPHA_FILE index-alpha.html)
  50 SET(BBTK_INDEX_PACKAGES_FILE index-package.html)
  51 SET(BBTK_INDEX_CATEGORIES_FILE index-category.html)
  52 CONFIGURE_FILE(
  53   ${CMAKE_CURRENT_SOURCE_DIR}/make-index.bbs.in
  54   ${BBTK_BBDOC_BUILD_PATH}/make-index.bbs
  55   @ONLY
  56   )
  57 INSTALL(
  58   FILES ${BBTK_BBDOC_BUILD_PATH}/make-index.bbs
  59   DESTINATION ${BBTK_BBDOC_INSTALL_PATH}
  60   )
  61 # bbtk-make-index
  62 CONFIGURE_FILE(
  63   ${CMAKE_CURRENT_SOURCE_DIR}/bbtk-make-index.sh.in
  64   ${BBTK_BBDOC_BUILD_PATH}/bbtk-make-index
  65   @ONLY
  66   )
  67 INSTALL(
  68   PROGRAMS ${BBTK_BBDOC_BUILD_PATH}/bbtk-make-index
  69   DESTINATION bin
  70   )