vv/CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.4)
   2
   3 #=========================================================
   4 # To avoid warning with some version
   5 if(COMMAND cmake_policy)
   6   cmake_policy(SET CMP0003 NEW)
   7 endif(COMMAND cmake_policy)
   8 #=========================================================
   9
  10
  11 #=========================================================
  12 #List of vv tools to compile
  13 SET(vv_TOOLS
  14   vvToolMedianFilter
  15   vvToolRigidReg
  16   vvToolCropImage
  17   vvToolBinarize
  18   vvToolImageArithm
  19   vvToolResample
  20 #   vvToolExtractPatient
  21 #  vvToolExtractLung
  22   vvToolStructureSetManager
  23   vvToolMIP
  24   vvToolConvert ## with dummy vvToolConvert.ui
  25   vvToolROIManager
  26   vvToolSegmentation
  27
  28   ## these ones are for tests (not working)
  29   # vvToolFoo
  30   # vvToolFooWithWidgetBase
  31   # vvToolPlastimatch
  32   # vvToolConnectedComponentLabeling
  33 )
  34 # dependencies of the tools
  35 # Future issues : when tool depend on other tools ... how to manage that ?
  36 #  >> add the relevant $_LIBS variable to the tool that has dependencies?
  37 SET(vvToolBinarize_LIBS clitkBinarizeImageLib)
  38 SET(vvToolResample_LIBS clitkResampleImageLib)
  39 SET(vvToolConvert_LIBS clitkImageConvertLib)
  40 SET(vvToolExtractPatient_LIBS clitkSegmentationGgoLib)
  41 SET(vvToolExtractLung_LIBS clitkSegmentationGgoLib)
  42 SET(vvToolCropImage_LIBS clitkCropImageLib)
  43 SET(vvToolMIP_LIBS clitkMIPLib)
  44 SET(vvToolMedianFilter_LIBS clitkMedianImageFilterLib)
  45 SET(vvToolImageArithm_LIBS clitkImageArithmImageLib)
  46
  47 #=========================================================
  48 # List of vv source files
  49
  50 # in COMMON_WITH_UI -> must have .h and .cxx and .ui
  51 SET(vv_COMMON_WITH_UI
  52   vvInfoPanel
  53   vvMainWindow
  54   vvLinkPanel
  55   vvOverlayPanel
  56   vvLandmarksPanel
  57   vvProgressDialog
  58   vvSegmentationDialog
  59   vvSurfaceViewerDialog
  60   vvDeformationDialog
  61   vvStructSelector
  62   vvIntensityValueSlider
  63   vvLabelImageLoaderWidget
  64   vvToolWidgetBase
  65   vvToolSimpleInputSelectorWidget
  66   vvToolInputSelectorWidget
  67   vvRegisterForm
  68 )
  69
  70 # All others sources
  71 SET(vv_SRCS
  72   vvQProgressDialogITKCommand.cxx
  73   vvQDicomSeriesSelector.cxx
  74   QTreePushButton.cxx
  75   vvMainWindowBase.cxx
  76   vvImageWarp.cxx
  77   vvDeformableRegistration.cxx
  78   vtkVOXImageWriter.cxx
  79   vvInteractorStyleNavigator.cxx
  80   vvSlicer.cxx
  81   vvLandmarks.cxx
  82   vvLandmarksGlyph.cxx
  83   vvClipPolyData.cxx
  84   vvGlyphSource.cxx
  85   vvGlyph2D.cxx
  86   vvSlicerManager.cxx
  87   vvSlicerManagerCommand.cxx
  88   vvUtils.cxx
  89 #  vvMaximumIntensityProjection.cxx
  90   vvMesh.cxx
  91   vvMeshActor.cxx
  92   vvMeshReader.cxx
  93   vvMidPosition.cxx
  94   vvImageContour.cxx
  95   vvBinaryImageOverlayActor.cxx
  96   vvStructureSetActor.cxx
  97   vvSaveState.cxx
  98   vvReadState.cxx
  99   vvROIActor.cxx
 100   vvBlendImageActor.cxx
 101   vvToolManager.cxx
 102   vvToolCreatorBase.cxx
 103   vvToolBaseBase.cxx
 104 )
 105
 106 #=========================================================
 107 # Qt related commands
 108 FIND_PACKAGE(Qt4 REQUIRED)
 109
 110 QT4_WRAP_CPP(vv_SRCS
 111   vvMainWindowBase.h
 112   QTreePushButton.h
 113   vvDocumentation.h
 114   vvHelpDialog.h
 115   vvQDicomSeriesSelector.h
 116   vvSlicerManager.h
 117   vvStructureSetActor.h
 118   vvROIActor.h
 119   vvToolCreatorBase.h
 120   )
 121
 122 QT4_WRAP_UI(vv_UI_CXX
 123   qt_ui/vvHelpDialog.ui
 124   qt_ui/vvDocumentation.ui
 125   qt_ui/vvDicomSeriesSelector.ui
 126   qt_ui/vvDummyWindow.ui #For testing
 127   )
 128
 129 QT4_ADD_RESOURCES(vv_SRCS vvIcons.qrc)
 130
 131 # Add the autotools in the header vvToolsList.h for initialization of the dummy
 132 # variables in vv.cxx for the tools contained in vvLib
 133 if(${CMAKE_CURRENT_SOURCE_DIR}/CMakeLists.txt IS_NEWER_THAN ${CMAKE_CURRENT_BINARY_DIR}/vvToolsList.h)
 134   file(REMOVE ${CMAKE_CURRENT_BINARY_DIR}/vvToolsList.h)
 135   foreach(tool ${vv_TOOLS})
 136     FILE(APPEND ${CMAKE_CURRENT_BINARY_DIR}/vvToolsList.h "#include \"${tool}.h\"\n")
 137     FILE(APPEND ${CMAKE_CURRENT_BINARY_DIR}/vvToolsList.h "extern const vvToolCreator<${tool}> *dummy${tool};\n")
 138     FILE(APPEND ${CMAKE_CURRENT_BINARY_DIR}/vvToolsList.h "const vvToolCreator<${tool}> *dummy${tool}2 = dummy${tool};\n\n")
 139   endforeach(tool)
 140 endif(${CMAKE_CURRENT_SOURCE_DIR}/CMakeLists.txt IS_NEWER_THAN ${CMAKE_CURRENT_BINARY_DIR}/vvToolsList.h)
 141
 142 # Add the autotools and the common files ui
 143 foreach(tool ${vv_TOOLS} ${vv_COMMON_WITH_UI})
 144     SET(vv_SRCS ${vv_SRCS} ${tool}.cxx)
 145     QT4_WRAP_CPP(vv_SRCS ${tool}.h)
 146     QT4_WRAP_UI(vv_UI_CXX qt_ui/${tool}.ui)
 147 endforeach(tool)
 148
 149 # Add the common source files
 150 foreach(tool ${vv_COMMON})
 151     SET(vv_SRCS ${vv_SRCS} ${tool}.cxx)
 152     QT4_WRAP_CPP(vv_SRCS ${tool}.h)
 153 endforeach(tool)
 154
 155 # if Windows and Qt was built as a static lib then don't set QT_DLL flag
 156 SET(QT_STATIC 0)
 157 IF (WIN32)
 158   IF(EXISTS ${QT_LIBRARY_DIR}/QtCore.prl)
 159     FILE(READ ${QT_LIBRARY_DIR}/QtCore.prl QT_CORE_PRL)
 160     IF(${QT_CORE_PRL} MATCHES "static")
 161       SET(QT_STATIC 1)
 162     ENDIF(${QT_CORE_PRL} MATCHES "static")
 163   ENDIF(EXISTS ${QT_LIBRARY_DIR}/QtCore.prl)
 164 ENDIF(WIN32)
 165 IF(NOT QT_STATIC)
 166   ADD_DEFINITIONS(-DQT_DLL)
 167 ENDIF(NOT QT_STATIC)
 168
 169 ADD_DEFINITIONS(-DQT_THREAD_SUPPORT)
 170
 171 INCLUDE_DIRECTORIES(
 172   ${QT_INCLUDES}
 173   ${QT_INCLUDE_DIR}
 174   ${QT_QTGUI_INCLUDE_DIR}
 175   ${QT_QTCORE_INCLUDE_DIR}
 176   ${CMAKE_CURRENT_BINARY_DIR}
 177   ${CMAKE_CURRENT_SOURCE_DIR}
 178 )
 179 #=========================================================
 180
 181 #=========================================================
 182 #support for parallel deformable registration with OpenMP
 183 IF(NOT APPLE)
 184 IF(CMAKE_COMPILER_IS_GNUCC)
 185   SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fopenmp")
 186 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 187 ENDIF(NOT APPLE)
 188 #=========================================================
 189
 190 #=========================================================
 191 INCLUDE_DIRECTORIES(
 192   ../common
 193   ../tools
 194   ../segmentation
 195   )
 196
 197 LINK_DIRECTORIES(${QT_LIBRARY_DIR})
 198 #=========================================================
 199 #Add each tool's dependencies
 200 foreach(tool ${vv_TOOLS})
 201   SET(toolLibs ${toolLibs} ${${tool}_LIBS})
 202 endforeach(tool)
 203 #=========================================================
 204 #Add Foundation Libraries (this should be after our libraries, since we depend
 205 #on them)
 206 SET(foundationLibraries clitkCommon ${ITK_LIBRARIES} QVTK vtkHybrid)
 207
 208 #=========================================================
 209 # Use CxImage to create animated gifs
 210 IF(CLITK_EXPERIMENTAL)
 211   SET(vvCxImage clitkCxImage)
 212   SET(vv_SRCS ${vv_SRCS} vvAnimatedGIFWriter.cxx)
 213   INCLUDE_DIRECTORIES(${CLITK_SOURCE_DIR}/utilities/CxImage)
 214   ADD_SUBDIRECTORY(${CLITK_SOURCE_DIR}/utilities/CxImage ${PROJECT_BINARY_DIR}/utilities/CxImage)
 215 ENDIF(CLITK_EXPERIMENTAL)
 216 #=========================================================
 217
 218 #=========================================================
 219 #Create binary and libs for tests
 220 SET(vvExternalLibs ${QT_QTNETWORK_LIBRARY} clitkSegmentationGgoLib clitkDicomRTStruct ${toolLibs} ${foundationLibraries} ${vvCxImage})
 221 # QtNetwork is required by vvRegisterForm
 222
 223 ADD_LIBRARY(vvLib ${vv_SRCS} ${vv_UI_CXX})
 224 TARGET_LINK_LIBRARIES(vvLib ${vvExternalLibs})
 225
 226 IF(WIN32)
 227   ADD_EXECUTABLE(vv WIN32 vv.cxx vvIcon.rc)
 228 ELSE(WIN32)
 229   ADD_EXECUTABLE(vv vv.cxx)
 230 ENDIF(WIN32)
 231
 232 #TARGET_LINK_LIBRARIES(vv vvLib)
 233 TARGET_LINK_LIBRARIES(vv vvLib)
 234
 235
 236 #=========================================================
 237 # Install options (also used by CPack)
 238 IF(UNIX OR APPLE)
 239 #   SET_TARGET_PROPERTIES(vv
 240 #     PROPERTIES INSTALL_RPATH "${VTK_DIR}:${ITK_DIR}")
 241   INSTALL (TARGETS vv DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_EXECUTE WORLD_EXECUTE)
 242   #  INSTALL (FILES ${CMAKE_CURRENT_SOURCE_DIR}/icons/ducky.png DESTINATION .)
 243
 244   #QT
 245   #FOREACH(LIB QtCore QtGui QtOpenGL QtNetwork QtSql)
 246   #  INSTALL(FILES "${QT_LIBRARY_DIR}/lib${LIB}.so.${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH}"
 247   #          RENAME "lib${LIB}.so.${QT_VERSION_MAJOR}"
 248   #          DESTINATION .)
 249   #ENDFOREACH(LIB)
 250 ENDIF(UNIX OR APPLE)
 251
 252 IF(WIN32)
 253   #INCLUDE(InstallRequiredSystemLibraries)
 254   INSTALL(TARGETS vv DESTINATION bin)
 255   #INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/icons/ducky.png DESTINATION .)
 256 ENDIF(WIN32)
 257 #=========================================================
 258
 259 #=========================================================
 260 # CPack options
 261 SET(CPACK_PACKAGE_NAME "vv")
 262 SET(CPACK_SOURCE_PACKAGE_FILE_NAME "vv-src")
 263 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "vv, the 4D slicer : let's jump into a new dimension !")
 264 SET(CPACK_PACKAGE_VENDOR "Creatis-CLB")
 265 SET(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/ReadMe.txt")
 266 SET(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/License.txt")
 267 SET(CPACK_PACKAGE_VERSION_MAJOR "1")
 268 SET(CPACK_PACKAGE_VERSION_MINOR "3")
 269 SET(CPACK_PACKAGE_VERSION_PATCH "0")
 270 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "vv")
 271 SET(CPACK_STRIP_FILES TRUE)
 272
 273 IF(WIN32)
 274   # There is a bug in NSI that does not handle full unix paths properly. Make
 275   # sure there is at least one set of four (4) backlasshes.
 276   SET(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\icons\\\\ducky.ico")
 277   SET(CPACK_NSIS_INSTALLED_ICON_NAME "vv.exe")
 278   SET(CPACK_NSIS_DISPLAY_NAME "vv - The 4D slicer")
 279   SET(CPACK_NSIS_HELP_LINK "http://www.creatis.insa-lyon.fr/rio/vv")
 280   SET(CPACK_NSIS_URL_INFO_ABOUT "http://www.creatis.insa-lyon.fr/rio")
 281   SET(CPACK_NSIS_CONTACT "vv@creatis.insa-lyon.fr")
 282   SET(CPACK_NSIS_CREATE_ICONS_EXTRA "CreateShortCut \\\"$SMPROGRAMS\\\\$STARTMENU_FOLDER\\\\vv.lnk\\\" \\\"$INSTDIR\\\\vv.exe\\\" ")
 283   SET(CPACK_NSIS_DELETE_ICONS_EXTRA "Delete \\\"$SMPROGRAMS\\\\$MUI_TEMP\\\\vv.lnk\\\" ")
 284   #SET(CPACK_NSIS_MODIFY_PATH ON) SR: buggy, wait for cmake updates for a fix
 285   #SET(CPACK_BINARY_ZIP ON)
 286 ELSE(WIN32)
 287   SET(CPACK_GENERATOR "STGZ")
 288   SET(CPACK_SOURCE_GENERATOR "TGZ")
 289 ENDIF(WIN32)
 290 INCLUDE(CPack)
 291 #=========================================================
 292 #=========================================================
 293 configure_file(vvConfiguration.h.in vvConfiguration.h)
 294 #=========================================================