description "Example of posbile Recalage implementation"
author "jn.trillos44@uniandes.edu.co"
category "demo"

load vtk
include wxvtk
load std
load itk
include vtk
include wx
load itkvtk
load creaMaracasVisu
load PackRecalage

//File selection and file reader for the first image

new FileSelector openFileDialog
  set openFileDialog.Wildcard  "(*.mhd)|*.mhd"
new MetaImageReader reader
   connect openFileDialog.Out reader.In

//File selection and file reader for the second image

new FileSelector openFileDialog2
  set openFileDialog2.Wildcard  "(*.mhd)|*.mhd"
new MetaImageReader reader2
   connect openFileDialog2.Out reader2.In

//Viewer NV and ShowPoints for the first image

new ViewerNV viewer
  connect reader.Out viewer.In
  set viewer.nTypeView "5 1 2 0"

new ShowNPoints showNpoints
  connect reader.Out showNpoints.Image
  connect viewer.Renderer1 showNpoints.Renderer
  connect viewer.Point showNpoints.In
  connect viewer.BoxChange showNpoints.BoxExecute
  set showNpoints.Radio 10

//Viewer NV and ShowPoints for the second image

new ViewerNV viewer2
  connect reader2.Out viewer2.In
  set viewer2.nTypeView "5 1 2 0"

new ShowNPoints showNpoints2
  connect reader2.Out showNpoints2.Image
  connect viewer2.Renderer1 showNpoints2.Renderer
  connect viewer2.Point showNpoints2.In
  connect viewer2.BoxChange showNpoints2.BoxExecute
  set showNpoints2.Radio 10

/////////////////////////////////////////////////////
#Calculate Vector Box
/////////////////////////////////////////////////////

new CalculateVectorBox vector1
  connect showNpoints.lstPointsX vector1.PointsX1
  connect showNpoints2.lstPointsX vector1.PointsX2
  connect showNpoints.lstPointsY vector1.PointsY1
  connect showNpoints2.lstPointsY vector1.PointsY2
  connect showNpoints.lstPointsZ vector1.PointsZ1
  connect showNpoints2.lstPointsZ vector1.PointsZ2  
  
////////////////////////////////////////////////////

///////////////////////////////////////////////////
#Transformation Boxes
//////////////////////////////////////////////////

new Transform2DBox transform
  connect vector1.Origin transform.CenterPoint
  connect vector1.OutAngle transform.Angle
  connect vector1.OutScaleX transform.ScaleX
  connect vector1.OutScaleY transform.ScaleY
  connect vector1.OutScaleZ transform.ScaleZ
  connect vector1.TransformAxis transform.Axis
  set transform.3D true

new ReSlicerBox reslice1
  connect vector1.OriginReslicer reslice1.Origin
  connect transform.Out reslice1.Transform
  connect reader2.Out reslice1.In

//ViewerNV and ComandButton for the result image

new ViewerNV viewer3
  set viewer3.nTypeView "5 1 2 0"
  connect reslice1.Out viewer3.In

new CommandButton butExec
  set butExec.Label "Execute"
  connect butExec.BoxChange viewer3.BoxExecute

//Tab for the first image

new LayoutSplit tab1
   set tab1.Orientation H
   connect showNpoints.Widget tab1.Widget1
   connect viewer.Widget tab1.Widget2

//Tab for the second image

new LayoutSplit tab2
   set tab2.Orientation H
   connect showNpoints2.Widget tab2.Widget1
   connect viewer2.Widget tab2.Widget2

//Tab for the result image

new LayoutSplit result
  set result.Orientation H
  connect butExec.Widget result.Widget1
  connect viewer3.Widget result.Widget2

//Main window

new LayoutTab main
set main.Orientation H
connect tab1.Widget main.Widget1
connect tab2.Widget main.Widget2
connect result.Widget main.Widget3

exec main