description "Example of posible Recalage implementation"
author "jn.trillos44@uniandes.edu.co"
category "demo"

load vtk
include wxvtk
load std
load itk
include vtk
include wx
load itkvtk
load creaMaracasVisu
load PackRecalage

//File selection and file reader for the first image

new FileSelector openFileDialog
  set openFileDialog.Wildcard  "(*.mhd)|*.mhd"
new MetaImageReader reader
   connect openFileDialog.Out reader.In

//File selection and file reader for the second image

new FileSelector openFileDialog2
  set openFileDialog2.Wildcard  "(*.mhd)|*.mhd"
new MetaImageReader reader2
   connect openFileDialog2.Out reader2.In

//Viewer NV and ShowPoints for the first image

new ViewerNV viewer
  connect reader.Out viewer.In
  set viewer.nTypeView "5"

new ShowNPoints showNpoints
  connect reader.Out showNpoints.Image
  connect viewer.Renderer1 showNpoints.Renderer
  connect viewer.Point showNpoints.In
  connect viewer.BoxChange showNpoints.BoxExecute
  set showNpoints.Radio 10

//Viewer NV and ShowPoints for the second image

new ViewerNV viewer2
  connect reader2.Out viewer2.In
  set viewer2.nTypeView "5"

new ShowNPoints showNpoints2
  connect reader2.Out showNpoints2.Image
  connect viewer2.Renderer1 showNpoints2.Renderer
  connect viewer2.Point showNpoints2.In
  connect viewer2.BoxChange showNpoints2.BoxExecute
  set showNpoints2.Radio 10

//////////////////////////////////////////
#Transform Box
//////////////////////////////////////////

new Transform3D3PointsBox transform
  connect showNpoints.lstPointsX transform.InX1
  connect showNpoints2.lstPointsX transform.InX2
  connect showNpoints.lstPointsY transform.InY1
  connect showNpoints2.lstPointsY transform.InY2
  connect showNpoints.lstPointsZ transform.InZ1
  connect showNpoints2.lstPointsZ transform.InZ2  

 connect showNpoints.lstLabels transform.Labels1 
 connect showNpoints2.lstLabels transform.Labels2
  
new ReSlicerBox reslice1

  set reslice1.Origin "0,0,0"

  connect transform.Out reslice1.Transform
  connect reader2.Out reslice1.In

//ViewerNV and ComandButton for the result image


new ViewerNV viewer3
  set viewer3.nTypeView "5"
  connect reslice1.Out viewer3.In

new CommandButton butExec
  set butExec.Label "Execute"

//Tab for the first image

new LayoutSplit tab1
   set tab1.Orientation H

////////////////////

new LayoutSplit hello
  set hello.Orientation V

  connect showNpoints.Widget hello.Widget1
  connect butExec.Widget hello.Widget2

   connect hello.Widget tab1.Widget1
   connect viewer.Widget tab1.Widget2

//Tab for the second image

new LayoutSplit tab2
   set tab2.Orientation H
   connect showNpoints2.Widget tab2.Widget1
   connect viewer2.Widget tab2.Widget2

//Tab for the result image

  connect butExec.BoxChange transform.BoxExecute
  connect butExec.BoxChange reslice1.BoxExecute
  connect butExec.BoxChange viewer3.BoxExecute


//Main window

new LayoutTab main
set main.Orientation H
connect tab1.Widget main.Widget1
connect tab2.Widget main.Widget2

exec main