load wx
load std
load vtk
load wxvtk
load creaMaracasVisu

load PackRecalage

include vtk/boxes/bbLoadHola 
new LoadHola image 

#Viewer containing image 1

new LayoutLine v1Layout
new ViewerNV viewer1
connect image.Out viewer1.In
set viewer1.nTypeView "0"
connect viewer1.Widget v1Layout.Widget1


#Viewer containing image 2

new LayoutLine v2Layout
new ViewerNV viewer2
connect image.Out viewer2.In
set viewer2.nTypeView "0"
connect viewer2.Widget v2Layout.Widget1

#LayoutSplit were the images will be

new LayoutSplit initialImages
set initialImages.Proportion "50"
set initialImages.Orientation H
connect v1Layout.Widget initialImages.Widget1
connect v2Layout.Widget initialImages.Widget2

#Layout line that will contain the buttons

new LayoutLine buttonsLayout
  set buttonsLayout.Orientation V

#Slider were the angle will be entered

new Slider slider
  set slider.Title "Angle"
  set slider.In 0
  set slider.Min 0
  set slider.Max 360
  set slider.ReactiveOnTrack "1"
  connect slider.Widget buttonsLayout.Widget1 



#Slider were the xScale will be entered

new Slider sliderX
  set sliderX.Title "% Scale in X"
  set sliderX.In 100
  set sliderX.Min 10
  set sliderX.Max 500
  set sliderX.ReactiveOnTrack "1"
  connect sliderX.Widget buttonsLayout.Widget2 



#Slider were the yScale will be entered

new Slider sliderY
  set sliderY.Title "% Scale in Y"
  set sliderY.In 100
  set sliderY.Min 10
  set sliderY.Max 500
  set sliderY.ReactiveOnTrack "1"
  connect sliderY.Widget buttonsLayout.Widget3 


#Box were the transformation will be made

new Transform2DBox transform
  connect viewer2.Point transform.CenterPoint
  connect slider.Out transform.Angle
  connect sliderX.Out transform.ScaleX
  connect sliderY.Out transform.ScaleY



new ReSlicerBox reslice1
  connect viewer1.Point reslice1.Origin
  connect transform.Out reslice1.Transform
  connect image.Out reslice1.In

new SliceImage slice1
   connect reslice1.Out slice1.In
   set slice1.Z "1"


#new ViewerNV viewer3
  #connect reslice1.Out viewer3.In
  #set viewer3.nTypeView "6"
  #set viewer3.WinWidth "600"

new Viewer2D viewer3
  connect reslice1.Out viewer3.In
  set viewer3.Orientation "2"
  set viewer3.Slice "1"

#Boton that will set the points and angle

new CommandButton botonfinal
  set botonfinal.Label "Set Information"
  connect botonfinal.Widget buttonsLayout.Widget4
  connect botonfinal.BoxChange viewer3.BoxExecute
  
#Layout were the images and the buttones will be displayed

new LayoutSplit window1
  set window1.WinWidth "600"
  set window1.Proportion "80"
  set window1.Orientation V
  connect initialImages.Widget window1.Widget1
  connect buttonsLayout.Widget window1.Widget2

new LayoutSplit main
  set main.WinWidth "1200"
  set main.Proportion "100"
  set main.Orientation H
  connect window1.Widget main.Widget1
  connect viewer3.Widget main.Widget2

exec main