load std
load wx

new Sizer sizer
new StaticText statictext
new StaticText statictextDirectory
new TextCtrl textctrl
new CommandButton commandbutton
new CommandButton dirbutton
new DirDialog dirdialog
new ExecSys execsys
#new ConcatStrings concatstringPackagename
new MakeFileName makeFilePackagename
new ConcatStrings concatstringCommand
new Print print
new StaticText msg1
new StaticText msg2
new Execbbi execbbi

set sizer.Title "Creat Package"
set sizer.WxWidth 400
set sizer.WxHeight 200

set statictext.In "This script creates a new BBTK Package" 
set textctrl.Title "2)    Name of the Package" 
set textctrl.In "MyPackageBBTK" 
set commandbutton.Label  "3)    Create Package" 
set msg1.In "Missing directory ..?????"
set msg2.In "Ok, See result of the command in the console window"
set commandbutton.In  "exec msg1" 
set dirbutton.Label  "1)    Choose directory" 
set execbbi.In "exec print;  exec msg2; exec execsys;"
set dirbutton.In  "connect dirdialog.Out statictextDirectory.In; exec dirdialog; exec statictextDirectory;   set commandbutton.In  'exec execbbi' " 
set statictextDirectory.Title "Directory" 
set statictextDirectory.ProcessMode 1 


connect dirdialog.Out makeFilePackagename.Directory
connect textctrl.Out makeFilePackagename.File

set msg1.WxWidth 600
set msg1.WxHeight 80
set msg2.WxWidth 600
set msg2.WxHeight 80

set concatstringCommand.In1 "bbCreatePackage "
connect makeFilePackagename.Out concatstringCommand.In2
connect concatstringCommand.Out execsys.In  
connect concatstringCommand.Out print.In  

connect sizer.Child statictext.Parent
connect sizer.Child dirbutton.Parent
connect sizer.Child statictextDirectory.Parent
connect sizer.Child textctrl.Parent
connect sizer.Child commandbutton.Parent

set dirbutton.ProcessMode 1
graph CURRENT 0
exec sizer