# Configure & install images 
BBTK_DOC_INSTALL_IMAGES(bbtkWebSite)

# Configure html pages for build tree and install 
FILE(GLOB HTML_PAGES "." "*.html")
FOREACH(page ${HTML_PAGES})  
  GET_FILENAME_COMPONENT(filename "${page}" NAME)
  CONFIGURE_FILE(
    ${page}
    ${BBTK_DOC_BUILD_PATH}/bbtkWebSite/${filename}
    @ONLY
    )
  # Install
  INSTALL(
    FILES ${BBTK_DOC_BUILD_PATH}/bbtkWebSite/${filename}
    DESTINATION ${BBTK_DOC_INSTALL_PATH}/bbtkWebSite
    )
ENDFOREACH(page)

# Index generation
SET(BBTK_INDEX_ALPHA_FILE ${BBTK_BBDOC_BUILD_PATH}/index-alpha.html)
SET(BBTK_INDEX_PACKAGES_FILE ${BBTK_BBDOC_BUILD_PATH}/index-package.html)
SET(BBTK_INDEX_CATEGORIES_FILE ${BBTK_BBDOC_BUILD_PATH}/index-category.html)
SET(INDEX_OUTPUT 
  ${BBTK_INDEX_ALPHA_FILE} ${BBTK_INDEX_PACKAGES_FILE} 
  ${BBTK_INDEX_CATEGORIES_FILE}
  )

CONFIGURE_FILE(
  ${CMAKE_CURRENT_SOURCE_DIR}/make-index.bbs.in
  ${CMAKE_CURRENT_BINARY_DIR}/make-index.bbs
  @ONLY
  )
ADD_CUSTOM_COMMAND(
  OUTPUT ${INDEX_OUTPUT}
  COMMAND 
  cd ${BBTK_BIN_PATH} && ${BBTK_BBI} -n ${CMAKE_CURRENT_BINARY_DIR}/make-index.bbs
  DEPENDS ${BBTK_BBI_DEPENDENCY} ${BBTK_PACKAGES_DEPS}
  )
ADD_CUSTOM_TARGET(bbdoc_index ALL
  DEPENDS ${INDEX_OUTPUT}
  )
INSTALL(
  FILES ${INDEX_OUTPUT} 
  DESTINATION ${BBTK_BBDOC_INSTALL_PATH}
  )

# create make-index.bbs for build / install tree
SET(BBTK_INDEX_ALPHA_FILE index-alpha.html)
SET(BBTK_INDEX_PACKAGES_FILE index-package.html)
SET(BBTK_INDEX_CATEGORIES_FILE index-category.html)
CONFIGURE_FILE(
  ${CMAKE_CURRENT_SOURCE_DIR}/make-index.bbs.in
  ${BBTK_BBDOC_BUILD_PATH}/make-index.bbs
  @ONLY
  )
INSTALL(
  FILES ${BBTK_BBDOC_BUILD_PATH}/make-index.bbs
  DESTINATION ${BBTK_BBDOC_INSTALL_PATH}
  )
# bbtk-make-index
CONFIGURE_FILE(
  ${CMAKE_CURRENT_SOURCE_DIR}/bbtk-make-index.sh.in
  ${BBTK_BBDOC_BUILD_PATH}/bbtk-make-index
  @ONLY
  )
INSTALL(
  PROGRAMS ${BBTK_BBDOC_BUILD_PATH}/bbtk-make-index
  DESTINATION bin
  )