## ====================
## == Base libraries ==
## ====================

CompileLibFromDir(cp_tinyxml2 SHARED tinyxml2)
IF(USE_QT4)
  CompileLibFromDir(cp_QCustomPlot SHARED QCustomPlot)
  TARGET_LINK_LIBRARIES(cp_QCustomPlot ${QT_LIBRARIES})
ENDIF(USE_QT4)
CompileLibFromDir(cpExtensions SHARED cpExtensions)
TARGET_LINK_LIBRARIES(
  cpExtensions ${QT_LIBRARIES} ${ITK_LIBRARIES} ${VTK_LIBRARIES}
  )

## ===============
## == Instances ==
## ===============

SUBDIRS(Instances)

## ==================
## == Main library ==
## ==================

ADD_CUSTOM_COMMAND(
  OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/cpPlugins/RealConfig.h
  COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_CURRENT_BINARY_DIR}/cpPlugins
  COMMAND ${cpPlugins_bash_CreateRealConfig_APP} ${CMAKE_CURRENT_BINARY_DIR}/cpPlugins/RealConfig.h
  DEPENDS ${cpPlugins_bash_CreateRealConfig_APP}
  )
INCLUDE_DIRECTORIES(${CMAKE_CURRENT_BINARY_DIR}/Instances)
CompileLibFromDir(cpPlugins SHARED cpPlugins ${CMAKE_CURRENT_BINARY_DIR}/cpPlugins/RealConfig.h)
TARGET_LINK_LIBRARIES(
  cpPlugins
  cp_tinyxml2
  cpExtensions
  ${QT_LIBRARIES} ${ITK_LIBRARIES} ${VTK_LIBRARIES}
  ${cpPlugins_Instances}
  )

## =========================
## == Even more libraries ==
## =========================

CompileLibFromDir(cpBaseQtApplication SHARED cpBaseQtApplication)
TARGET_LINK_LIBRARIES(cpBaseQtApplication cpPlugins)

## ===================================
## == Libraries to dynamically load ==
## ===================================

SET(cpPlugins_DynLibs "${CMAKE_INSTALL_PREFIX}/bin|cpExtensions")
LIST(APPEND cpPlugins_DynLibs "${CMAKE_INSTALL_PREFIX}/lib|cpExtensions")
LIST(APPEND cpPlugins_DynLibs "${LIBRARY_OUTPUT_PATH}|cpExtensions")
FOREACH(_lib ${cpPlugins_Instances})
  LIST(APPEND cpPlugins_DynLibs "${CMAKE_INSTALL_PREFIX}/bin|${_lib}")
  LIST(APPEND cpPlugins_DynLibs "${CMAKE_INSTALL_PREFIX}/lib|${_lib}")
  LIST(APPEND cpPlugins_DynLibs "${LIBRARY_OUTPUT_PATH}|${_lib}")
ENDFOREACH(_lib)
LIST(APPEND cpPlugins_DynLibs "${VTK_INSTALL_PREFIX}/bin|vtk*")
LIST(APPEND cpPlugins_DynLibs "${VTK_INSTALL_PREFIX}/lib|vtk*")
LIST(APPEND cpPlugins_DynLibs "${ITK_INSTALL_PREFIX}/bin|itk*")
LIST(APPEND cpPlugins_DynLibs "${ITK_INSTALL_PREFIX}/lib|itk*")
LIST(APPEND cpPlugins_DynLibs "${ITK_INSTALL_PREFIX}/bin|ITK*")
LIST(APPEND cpPlugins_DynLibs "${ITK_INSTALL_PREFIX}/lib|ITK*")
FILE(WRITE ${PROJECT_BINARY_DIR}/cpPlugins_Libraries.config "")
FOREACH(_lib ${cpPlugins_DynLibs})
  FILE(APPEND ${PROJECT_BINARY_DIR}/cpPlugins_Libraries.config "${_lib}\n")
ENDFOREACH(_lib)

## eof - $RCSfilfe$