SET(LIBRARY_NAME cpExtensions)

CONFIGURE_FILE(
  Config.h.in
  ${PROJECT_BINARY_DIR}/lib/cpExtensions/Config.h
  @ONLY
  )

## ===============
## = Source code =
## ===============

SET(LIB_HEADERS_H   "")
SET(LIB_HEADERS_HPP "")
SET(LIB_HEADERS_HXX "")
SET(LIB_SOURCES_C   "")
SET(LIB_SOURCES_CPP "")
SET(LIB_SOURCES_CXX "")

SET(
  lib_DIRECTORIES
  .
  DataStructures
  Algorithms
  IO
  Interaction
  Visualization
  )
FOREACH(dir ${lib_DIRECTORIES})
  FILE(GLOB dir_LIB_HEADERS_H   "${dir}/*.h")
  FILE(GLOB dir_LIB_HEADERS_HPP "${dir}/*.hpp")
  FILE(GLOB dir_LIB_HEADERS_HXX "${dir}/*.hxx")
  FILE(GLOB dir_LIB_SOURCES_C   "${dir}/*.c")
  FILE(GLOB dir_LIB_SOURCES_CPP "${dir}/*.cpp")
  FILE(GLOB dir_LIB_SOURCES_CXX "${dir}/*.cxx")

  SET(LIB_HEADERS_H   "${LIB_HEADERS_H};${dir_LIB_HEADERS_H}")
  SET(LIB_HEADERS_HPP "${LIB_HEADERS_HPP};${dir_LIB_HEADERS_HPP}")
  SET(LIB_HEADERS_HXX "${LIB_HEADERS_HXX};${dir_LIB_HEADERS_HXX}")
  SET(LIB_SOURCES_C   "${LIB_SOURCES_C};${dir_LIB_SOURCES_C}")
  SET(LIB_SOURCES_CPP "${LIB_SOURCES_CPP};${dir_LIB_SOURCES_CPP}")
  SET(LIB_SOURCES_CXX "${LIB_SOURCES_CXX};${dir_LIB_SOURCES_CXX}")

  INSTALL(
    DIRECTORY ${dir}
    DESTINATION include/cpExtensions
    FILES_MATCHING PATTERN "*.h"
    )
  INSTALL(
    DIRECTORY ${dir}
    DESTINATION include/cpExtensions
    FILES_MATCHING PATTERN "*.hpp"
    )
  INSTALL(
    DIRECTORY ${dir}
    DESTINATION include/cpExtensions
    FILES_MATCHING PATTERN "*.hxx"
    )
ENDFOREACH(dir)

IF(USE_QT4)
  FILE(GLOB LIB_QT_UI "QT/*.ui")
  FILE(GLOB LIB_QT_Headers "QT/*.h")
  FILE(GLOB LIB_QT_Sources "QT/*.cxx")
  FILE(GLOB LIB_QT_Resources "QT/*.rc")

  QT4_WRAP_UI(LIB_QT_Wrapped_Headers ${LIB_QT_UI})
  QT4_WRAP_CPP(LIB_QT_Wrapped_MOC_Sources ${LIB_QT_Headers})
  QT4_ADD_RESOURCES(LIB_QT_Wrapped_Resources_Sources ${LIB_QT_Resources})

  SET(
    LIB_HEADERS_H
    ${LIB_HEADERS_H}
    ${LIB_QT_Wrapped_Headers}
    )
  SET(
    LIB_SOURCES_CXX
    ${LIB_SOURCES_CXX}
    ${LIB_QT_Sources}
    ${LIB_QT_Wrapped_Headers}
    ${LIB_QT_Wrapped_MOC_Sources}
    ${LIB_QT_Wrapped_Resources_Sources}
    )
ENDIF(USE_QT4)


## =====================
## = Compilation rules =
## =====================

ADD_LIBRARY(
  ${LIBRARY_NAME}
  ${LIBRARY_TYPE}
  ${LIB_SOURCES_C}
  ${LIB_SOURCES_CPP}
  ${LIB_SOURCES_CXX}
  )
GENERATE_EXPORT_HEADER(
  ${LIBRARY_NAME}
  BASE_NAME ${LIBRARY_NAME}
  EXPORT_MACRO_NAME ${LIBRARY_NAME}_EXPORT
  EXPORT_FILE_NAME ${PROJECT_BINARY_DIR}/lib/cpExtensions/${LIBRARY_NAME}_Export.h
  STATIC_DEFINE ${LIBRARY_NAME}_BUILT_AS_STATIC
  )
TARGET_LINK_LIBRARIES(
  ${LIBRARY_NAME}
  ${QT_LIBRARIES}
  ${ITK_LIBRARIES}
  ${VTK_LIBRARIES}
  )

## ========================
## -- Installation rules --
## ========================

INSTALL(
  TARGETS ${LIBRARY_NAME}
  RUNTIME DESTINATION bin
  LIBRARY DESTINATION lib
  ARCHIVE DESTINATION lib/static
  )
INSTALL(
  FILES
  ${PROJECT_BINARY_DIR}/lib/cpExtensions/${LIBRARY_NAME}_Export.h
  DESTINATION include/cpExtensions
  )

## eof - $RCSfile$