## =====================
## == Get source code ==
## =====================

configure_file(Version.cxx.in "${CMAKE_CURRENT_BINARY_DIR}/Version.cxx" @ONLY)
configure_file(Config.h.in "${CMAKE_CURRENT_BINARY_DIR}/Config.h" @ONLY)
file(GLOB_RECURSE _base_src "${CMAKE_CURRENT_SOURCE_DIR}/Base/*.cxx")
file(GLOB_RECURSE _base_hdr "${CMAKE_CURRENT_SOURCE_DIR}/Base/*.h")
file(GLOB_RECURSE _base_hrc "${CMAKE_CURRENT_SOURCE_DIR}/Base/*.hxx")
file(GLOB_RECURSE _image_src "${CMAKE_CURRENT_SOURCE_DIR}/Image/*.cxx")
file(GLOB_RECURSE _image_hdr "${CMAKE_CURRENT_SOURCE_DIR}/Image/*.h")
file(GLOB_RECURSE _image_hrc "${CMAKE_CURRENT_SOURCE_DIR}/Image/*.hxx")

set(_src
  ${_base_src} ${_image_src}
  "${CMAKE_CURRENT_BINARY_DIR}/Version.cxx"
  )
set(
  _hdr
  ${_base_hdr} ${_image_hdr}
  "${CMAKE_CURRENT_BINARY_DIR}/Config.h"
  )
set(_hrc ${_base_hrc} ${_image_hrc})

## =====================
## == Compile library ==
## =====================

add_library(fpa SHARED ${_src} ${_hdr} ${_hrc})
generate_export_header(fpa)
set_property(TARGET fpa PROPERTY VERSION ${prj_VERSION})
set_property(TARGET fpa PROPERTY SOVERSION ${prj_SHORT_VERSION})
set_property(
  TARGET fpa PROPERTY INTERFACE_fpa_MAJOR_VERSION ${prj_MAJ_VERSION}
  )
set_property(
  TARGET fpa APPEND PROPERTY COMPATIBLE_INTERFACE_STRING ${prj_MAJ_VERSION}
  )
target_link_libraries(fpa PUBLIC ${VTK_LIBRARIES} ${ITK_LIBRARIES})

## ========================
## == Installation rules ==
## ========================

install(
  TARGETS fpa
  EXPORT "${targets_export_name}"
  LIBRARY DESTINATION "lib"
  ARCHIVE DESTINATION "lib"
  RUNTIME DESTINATION "bin"
  INCLUDES DESTINATION "${include_install_dir}"
  )
install(
  DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
  DESTINATION "${include_install_dir}"
  FILES_MATCHING PATTERN "*.h"
  )
install(
  DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
  DESTINATION "${include_install_dir}"
  FILES_MATCHING PATTERN "*.hxx"
  )
install(
  FILES "${CMAKE_CURRENT_BINARY_DIR}/fpa_export.h"
  DESTINATION "${include_install_dir}/fpa"
  )

## eof - $RCSfile$