description "Creates a new bbtk package file structure on disk (Graphical user interface for the script bbCreatePackage)."
author "laurent.guigues at creatis.insa-lyon.fr"
category "bbtk tool"

load wx
load std 

new OutputText windowTitle
  set windowTitle.In "Package informations"

new DirectorySelector dir
    set dir.Message "Select the location of your new package"

new InputText name
    set name.Title "Name         (1 word)"
    set name.In "NEW_PACKAGE"

new InputText author
    set author.Title "Author(s)           (caracters   '<',  '>' not accepted...)"
    set author.In "_author_"

new InputText description
    set description.Title "Description            (caracters   '<',  '>' not accepted...)"
    set description.In "_description_"

new CommandButton createButton
    set createButton.In "exec command; quit"
    set createButton.Label "Go"

new LayoutLine main
    connect windowTitle.Widget main.Widget1
    connect name.Widget main.Widget2
    connect author.Widget main.Widget3
    connect description.Widget main.Widget4
    connect createButton.Widget main.Widget5
    set main.WinTitle "Create new black box package"
    set main.WinDialog true
    set main.WinWidth 400 
    set main.WinHeight 250 


new Configuration conf
new ConcatStrings concatStrCommand
#    set concatStrCommand.In1 "."
    connect conf.BinPath concatStrCommand.In1
    connect conf.FileSeparator concatStrCommand.In2 
    set concatStrCommand.In3 "bbCreatePackage "
new ConcatStrings concatStr
    connect  concatStrCommand.Out concatStr.In1 
    connect dir.Out concatStr.In2 
    set concatStr.In3 " "
    connect name.Out concatStr.In4 
    set concatStr.In5 " '"
    connect author.Out concatStr.In6 
    set concatStr.In7 "' '"
    connect description.Out concatStr.In8 
    set concatStr.In9 "'"


new ExecSystemCommand command
    connect concatStr.Out command.In
    print $concatStr.Out$

exec main