description "Creates a new bbtk package file structure on disk (Graphical user interface for the script bbCreatePackage)."
author "laurent.guigues at creatis.insa-lyon.fr"
category "toolsbbtk"

load wx
load std 


new DirectorySelector dir
    set dir.Message "Select the location of your new package"

#-----------------------------------------------------------------------------
new OutputText dirOutput
  connect dir.Out dirOutput.In

new OutputText windowTitle
  set windowTitle.In "Package informations"

new InputText name
    set name.Title "Name         (1 word)"
    set name.In "NEW_PACKAGE"

new InputText author
    set author.Title "Author(s)           (caracters   '<',  '>' not accepted...)"
    set author.In "_author_"

new InputText description
    set description.Title "Description            (caracters   '<',  '>' not accepted...)"
    set description.In "_description_"

#new CommandButton cancelButton
#    set cancelButton.In "quit"
#    set cancelButton.Label "Cancel"

new CommandButton createButton
    set createButton.In "print $concatStr.Out$; exec command; "
    set createButton.Label "Run"

new LayoutLine buttons
    set buttons.Orientation Horizontal
 #   connect cancelButton.Widget buttons.Widget1
    connect createButton.Widget buttons.Widget2

new LayoutLine main
    connect windowTitle.Widget main.Widget1
    connect dirOutput.Widget main.Widget2
    connect name.Widget main.Widget3
    connect author.Widget main.Widget4
    connect description.Widget main.Widget5
    connect buttons.Widget main.Widget6
    set main.WinTitle "Create new black box package"
    set main.WinDialog true
    set main.WinWidth 400 
    set main.WinHeight 250 

#-----------------------------------------------------------------------------

new ASCII ascii
  set ascii.In 34

new ConcatStrings dirStr
 set dirStr.In1 " "
 connect ascii.Out dirStr.In2
 connect dir.Out dirStr.In3
 connect ascii.Out dirStr.In4
 set dirStr.In5 " "

new ConcatStrings nameStr
 set nameStr.In1 "  "
 connect name.Out nameStr.In2
 set nameStr.In3 " "

new ConcatStrings authorStr
 set authorStr.In1 " '"
 connect author.Out authorStr.In2
 set authorStr.In3 "' "

new ConcatStrings descriptionStr
 set descriptionStr.In1 " '"
 connect description.Out descriptionStr.In2
 set descriptionStr.In3 "' "



new Configuration conf
new ConcatStrings concatStrCommand
    set concatStrCommand.In1 " "
    connect ascii.Out			concatStrCommand.In2
    connect conf.BinPath		concatStrCommand.In3
    connect conf.FileSeparator	concatStrCommand.In4
    set						concatStrCommand.In5  "bbCreatePackage"
    connect ascii.Out			concatStrCommand.In6
    set						concatStrCommand.In7  " "

new ConcatStrings concatStr
    connect ascii.Out				concatStr.In1
    connect  concatStrCommand.Out concatStr.In2
    connect dirStr.Out				concatStr.In3
    connect nameStr.Out			concatStr.In4 
    connect authorStr.Out			concatStr.In5 
    connect descriptionStr.Out		concatStr.In6
    connect ascii.Out				concatStr.In7


new ExecSystemCommand command
    connect concatStr.Out command.In

exec dir
exec main