description "Creates the XML or C++ code for a new black box"
author "eduardo.davila at creatis.insa-lyon.fr"
category "toolsbbtk"

load std 
load wx

new OutputText windowTitle
  set windowTitle.In "Black box informations"

new DirectorySelector dir
    set dir.Message "Select the location of your new black box"

new InputText nameBlackbox
    set nameBlackbox.Title "Blackbox name         (1 word)"
    set nameBlackbox.In "NEW_BLACKBOX"

new InputText namePackage
    set namePackage.Title "Package name         (1 word)"
    set namePackage.In "__PACKAGE__"


new InputText author
    set author.Title "Author(s)           (caracters   '<',  '>' not accepted...)"
    set author.In "_author_"

new InputText description
    set description.Title "Description            (caracters   '<',  '>' not accepted...)"
    set description.In "_description_"

#---------------------------------------------------------------------


new RadioButton typeBlackbox
  set typeBlackbox.Title "Type of the blackbox :"
  set typeBlackbox.In0 "std-template"
  set typeBlackbox.In1 "VTK_PolyDataAlgorithm-template"
  set typeBlackbox.In2 "VTK_ImageAlgorithm-template"
  set typeBlackbox.In3 "widget-template "

new StringSelect stringselectorType
  set stringselectorType.In0 "std"
  set stringselectorType.In1 "VTK_PolyDataAlgorithm"
  set stringselectorType.In2 "VTK_ImageAlgorithm"
  set stringselectorType.In3 "widget"
  connect  typeBlackbox.Out stringselectorType.In

#---------------------------------------------------------------------

new RadioButton formatBlackbox
  set formatBlackbox.Title "Format of the output file :"
  set formatBlackbox.In 0
  set formatBlackbox.In0 "C++"
  set formatBlackbox.In1 "XML"

new StringSelect stringselectorFormat
  set stringselectorFormat.In0 "C++"
  set stringselectorFormat.In1 "XML"
  connect  formatBlackbox.Out stringselectorFormat.In

#---------------------------------------------------------------------

new OutputText dirOutput
  connect dir.Out dirOutput.In

new LayoutLine layoutHor
  set  layoutHor.Orientation H
  connect typeBlackbox.Widget layoutHor.Widget1
  connect formatBlackbox.Widget layoutHor.Widget2

#new CommandButton cancelButton
#    set cancelButton.In "quit"
#    set cancelButton.Label "Cancel"

new CommandButton createButton
    set createButton.In "print $concatStr.Out$; exec command; "
    set createButton.Label "Run"

new LayoutLine buttons
    set buttons.Orientation Horizontal
#    connect cancelButton.Widget buttons.Widget1
    connect createButton.Widget buttons.Widget2

new LayoutLine main
    connect windowTitle.Widget main.Widget1
    connect dirOutput.Widget main.Widget2
    connect nameBlackbox.Widget main.Widget3
    connect namePackage.Widget main.Widget4
    connect author.Widget main.Widget5
    connect description.Widget main.Widget6
    connect layoutHor.Widget main.Widget7
    connect buttons.Widget main.Widget8
    set main.WinTitle "Create new black box"
    set main.WinDialog true
    set main.WinWidth 350 
    set main.WinHeight 520 

#---------------------------------------------------------------------

new ASCII ascii
  set ascii.In 34

new ConcatStrings dirStr
 set dirStr.In1 " "
 connect ascii.Out dirStr.In2
 connect dir.Out dirStr.In3
 connect ascii.Out dirStr.In4
 set dirStr.In5 " "

new ConcatStrings packageNameStr
 connect namePackage.Out packageNameStr.In1
 set packageNameStr.In2 " "

new ConcatStrings blackboxNameStr
 connect nameBlackbox.Out blackboxNameStr.In1
 set blackboxNameStr.In2 " "

new ConcatStrings typeStr
 connect stringselectorType.Out typeStr.In1
 set typeStr.In2 " "

new ConcatStrings formatStr
 connect stringselectorFormat.Out formatStr.In1
 set formatStr.In2 " "

new ConcatStrings authorStr
 set authorStr.In1 " '"
 connect author.Out authorStr.In2
 set authorStr.In3 "' "

new ConcatStrings descriptionStr
 set descriptionStr.In1 " '"
 connect description.Out descriptionStr.In2
 set descriptionStr.In3 "' "

new Configuration conf

new ConcatStrings commandStr
    set						commandStr.In1 " "
    connect ascii.Out			commandStr.In2
    connect conf.BinPath		commandStr.In3
    connect conf.FileSeparator	commandStr.In4
    set						commandStr.In5 "bbCreateBlackBox"
    connect ascii.Out			commandStr.In6
    set						commandStr.In7 " "


new ConcatStrings concatStr
    connect  commandStr.Out		concatStr.In1 
    connect dirStr.Out				concatStr.In2 
    connect packageNameStr.Out	concatStr.In3 
    connect blackboxNameStr.Out	concatStr.In4
    connect typeStr.Out				concatStr.In5
    connect formatStr.Out			concatStr.In6
    connect authorStr.Out			concatStr.In7
    connect descriptionStr.Out		concatStr.In8

/*
LG : bug on linux 
new ConcatStrings concatStr2
    connect  ascii.Out				concatStr2.In1 
    connect concatStr.Out			concatStr2.In2 
    connect ascii.Out				concatStr2.In3
*/

new ExecSystemCommand command
//    connect concatStr2.Out command.In
    connect concatStr.Out command.In

exec dir
exec main