description "Creates a new bbtk package file structure on disk (Graphical user interface for the shell script bbCreatePackage)."
author "laurent.guigues@creatis.insa-lyon.fr"
category "toolsbbtk"

load wx
load std 


new DirectorySelector dir
    set dir.Message "Select the location of your new package"

#-----------------------------------------------------------------------------
new OutputText dirOutput
  connect dir.Out dirOutput.In

new OutputText windowTitle
  set windowTitle.In "Package informations"

new InputText name
    set name.Title "Name         (1 word)"
    set name.In "NEW_PACKAGE"

new InputText author
    set author.Title "Author(s)           "
    set author.In "_author_"

new InputText description
    set description.Title "Description            (html format)"
    set description.In "_description_"

new CommandButton cancelButton
    set cancelButton.In "print **CANCEL**"
    set cancelButton.Label "Cancel"

new CommandButton createButton
    set createButton.In "print $concatStr.Out$; exec command;"
    set createButton.Label "Run"
    

new LayoutLine buttons
    set buttons.Orientation Horizontal
    connect cancelButton.Widget buttons.Widget1
    connect createButton.Widget buttons.Widget2

new LayoutLine main
    connect windowTitle.Widget main.Widget1
    connect dirOutput.Widget main.Widget2
    connect name.Widget main.Widget3
    connect author.Widget main.Widget4
    connect description.Widget main.Widget5
    connect buttons.Widget main.Widget6
    set main.WinTitle "Create new black box package"
    set main.WinDialog true
    set main.WinWidth 400 
    set main.WinHeight 250 

new MultipleInputs close
    connect close.Out main.WinClose
    connect cancelButton.BoxChange close.In1
    connect createButton.BoxChange close.In2

#-----------------------------------------------------------------------------
new Configuration conf
# on windows : enclose paths between double quotes 
# if system==0 (Linux) dquote=space (ascci code 32)
# if system==1 (Win) dquote==" (ascii code 34)
new StringSelect onsystem
set onsystem.In0 "32"
set onsystem.In1 "34"
new ASCII dquote
connect conf.SystemType onsystem.In
connect onsystem.Out dquote.In
#set dquote.In 34

new ConcatStrings dirStr
 set dirStr.In1 " "
 connect dquote.Out dirStr.In2
 connect dir.Out dirStr.In3
 connect dquote.Out dirStr.In4
 set dirStr.In5 " "

new ConcatStrings nameStr
 set nameStr.In1 "  "
 connect name.Out nameStr.In2
 set nameStr.In3 " "

new ConcatStrings authorStr
 set authorStr.In1 " '"
 connect author.Out authorStr.In2
 set authorStr.In3 "' "

new ConcatStrings descriptionStr
 set descriptionStr.In1 " '"
 connect description.Out descriptionStr.In2
 set descriptionStr.In3 "' "



new ConcatStrings concatStrCommand
    set concatStrCommand.In1 " "
    connect dquote.Out			concatStrCommand.In2
    connect conf.BinPath		concatStrCommand.In3
    connect conf.FileSeparator	concatStrCommand.In4
    set						concatStrCommand.In5  "bbCreatePackage"
    connect dquote.Out			concatStrCommand.In6
    set						concatStrCommand.In7  " "

new ConcatStrings concatStr
    connect dquote.Out				concatStr.In1
    connect  concatStrCommand.Out concatStr.In2
    connect dirStr.Out				concatStr.In3
    connect nameStr.Out			concatStr.In4 
    connect authorStr.Out			concatStr.In5 
    connect descriptionStr.Out		concatStr.In6
    connect dquote.Out				concatStr.In7


new ExecSystemCommand command
    connect concatStr.Out command.In

/*
new OutputText FinalMessage
set FinalMessage.WinWidth 100
set FinalMessage.WinHeight 100
set FinalMessage.In "Done !"
*/

exec dir
#message all 9
exec main