description "More complex test of wx::Slider widget"
author "jpr[at]creatis[dot]insa[dash]lyon[dot]fr"
category "example"

load wx
// std needed for <std::string> to <int> adaptor
load std

new LayoutLine main
   set main.Orientation H
new LayoutLine left
new LayoutLine right
   set right.Orientation H
connect left.Widget  main.Widget1
connect right.Widget main.Widget2

// =============================================================

new Slider s1
   set s1.Title  "s1 : Simple Slider,  Init = 33, O.Text : Reactive"
   set s1.In 33
   
new OutputText o1
   set o1.Title "Sortie s1"
   set o1.BoxProcessMode Reactive
   
connect s1.Widget left.Widget1
connect s1.Out o1.In 

// -----------------------------------
new Slider s2
   set s2.Min -110
   set s2.Max 140
   set s2.In -1
   set s2.Title "s2 : Slider with Min, Max, ReactiveOnTrack, O.Text : Reactive"
   set s2.ReactiveOnTrack 1
        
new OutputText o2
   set o2.Title "Sortie s2"
   set o2.BoxProcessMode Reactive
connect s2.Widget left.Widget2
connect s2.Out o2.In

// -----------------------------------
new Slider s3
   set s3.Min 12
   set s3.Max 123456
   set s3.Title "s3 : Slider with ChangeResolution, Always, O.Text : Reactive"
   set s3.ChangeResolution True
        
new OutputText o3
   set o3.Title "Sortie s3"
   set o3.BoxProcessMode Reactive
   
connect s3.Widget left.Widget3
connect s3.Out o3.In

// -----------------------------------

new Add a
   connect s1.Out a.In1 
   connect s2.Out a.In2
   set a.BoxProcessMode Reactive

new Slider s4
   set s4.Title "s4 : Slider pos s1+s2"
   set s4.BoxProcessMode Reactive
connect a.Out s4.In
# Warning : 'In' is the initial position, nothing more
#            Don't try to modify it later!
   
connect s4.Widget left.Widget4

new OutputText o4
   set o4.Title "Entree s4 (Add s1, s2)"
   set o4.BoxProcessMode Reactive
connect a.Out o4.In

// -----------------------------------
connect o1.Widget left.Widget5
connect o2.Widget left.Widget6
connect o3.Widget left.Widget7
connect o4.Widget left.Widget8

// =======================================================

new OutputText ot11
   set ot11.In  "Simple Slider"
connect ot11.Widget right.Widget1
new Slider s11
   set s11.Orientation V
connect s11.Widget right.Widget2

new OutputText ot12
   set ot12.In "Slider with Min, Max"
   connect ot12.Widget right.Widget3
new Slider s12
   set s12.Orientation V
   set s12.Min -110
   set s12.Max 140   
connect s12.Widget right.Widget4

new OutputText ot13
   set ot13.In "Slider with ChangeResolution"
   connect ot13.Widget right.Widget5
new Slider s13
   set s13.Orientation V
   set s13.Min 230
   set s13.Max 1140 
   set s13.ChangeResolution True     
connect s13.Widget right.Widget6

// ---------------------------------------------------

new CommandButton cmdBtn
   set cmdBtn.In "exec s4; exec main"
   set cmdBtn.Label "Refresh main"
connect cmdBtn.Widget left.Widget9

exec main