load std
load wx
//                       ---------------
//                       |      |      |
//                       |  W1  |  W2  |
//                       |-------------|
//                       |             |
//                       |     W3      |
//                       ---------------

define LayoutTDown wx

description "Creates a 'T like' complex container : Down {UpLeft, UpRight} "
author "jean-pierre.roux@creatis.univ-lyon1.fr"
category "complex box, widget"

new LayoutSplit currentBox
 set currentBox.Orientation V
 new LayoutSplit up

 connect up.Widget currentBox.Widget1 
 
 set up.Orientation H

new MultipleInputs m
 connect currentBox.BoxChange m.In1
 connect up.BoxChange         m.In2
 
 input  WinTitle  currentBox.WinTitle  "Title of the window (*)"
 input  WinHeight currentBox.WinHeight "Height of the window (*)"
 input  WinHide   currentBox.WinHide   "Any signal received hides the window (*)"
 input  WinClose  currentBox.WinClose  "Any signal received closes the window (*)"
 input  WinWidth  currentBox.WinWidth  "Width of the window (* : only used if the widget is not connected to a Layout box)"

 input  Widget1   up.Widget1           "UpLeft container" 
 input  Widget2   up.Widget2           "UpRight container"  
 input  Widget3   currentBox.Widget2   "Down container"
 output Widget    currentBox.Widget    "Widget"
 
 output BoxChange m.Out                "BoxChange"
 
endefine