description "A tour of wxvtk boxes"
author "laurent.guigues@creatis.insa-lyon.fr"
category "demo"

# put all include before or will be within echo 2 and generate many messages...
include wxvtk
include vtk
include std

# To avoid getting textual help
message Help 0

#==================================================================
print " "
print "====================================="
print "A simple 2D viewer"
print "====================================="
help Viewer2D
message echo 2

new LoadHola image
new Viewer2D viewer
connect image.Out viewer.In
set viewer.Slice 20
set viewer.WinDialog true
exec viewer

message echo 0
clear
print " "
print "====================================="
print "A simple 2D slicer"
print "====================================="
help SimpleSlicer
message echo 2

new LoadHola image
new SimpleSlicer viewer
connect image.Out viewer.In
set viewer.WinDialog true
exec viewer

message echo 0
clear
print " "
print "====================================="
print "A double 2D slicer"
print "====================================="
help DoubleSlicer
message echo 2

new LoadHola image
new DoubleSlicer viewer 
connect image.Out viewer.In1
connect image.Out viewer.In2
set viewer.WinDialog true
exec viewer

message echo 0
clear
print " "
print "====================================="
print "Slicing an image in 3D"
print "====================================="
help ImagePlanes
message echo 2


new LoadHola image
new ImagePlanes planes
new Viewer3D viewer
connect image.Out planes.In
connect planes.PlaneX viewer.Obs1
connect planes.PlaneY viewer.Obs2
connect planes.PlaneZ viewer.Obs3
set viewer.WinDialog true
exec viewer

message echo 0
clear
print " "
print "====================================="
print "Viewing an iso-surface of an image in 3D"
print "====================================="
help SimpleIsoSurfaceViewer
message echo 2

new LoadHola image
new SimpleIsoSurfaceViewer viewer
connect image.Out viewer.In
set viewer.WinDialog true
exec viewer

message echo 0
clear
print " "
print "====================================="
print "Viewing both 3 slices and an iso-surface of an image in 3D"
print "====================================="
help IsoSurfaceWidget
message echo 2

new LoadHola image
new Viewer3D viewer
new ImagePlanes planes
connect image.Out planes.In
connect planes.PlaneX viewer.Obs1
connect planes.PlaneY viewer.Obs2
connect planes.PlaneZ viewer.Obs3
new IsoSurfaceWidget isosurface
connect image.Out isosurface.In
connect isosurface.Out viewer.In1
connect isosurface.BoxChange viewer.BoxExecute

new LayoutSplit main
connect viewer.Widget main.Widget1
connect isosurface.Widget main.Widget2
set main.Proportion 70
set main.WinDialog true
exec main

message echo 0
clear
print " "
print "====================================="
print "Volume rendering"
print "====================================="
help VolumeRenderer
message echo 2

new LoadHola image
new PiecewiseFunction color
new PiecewiseFunction opacity
new VolumeRenderer renderer
new Viewer3D viewer

connect image.Out renderer.In
connect color.Out renderer.ColorFunction
connect opacity.Out renderer.OpacityFunction
connect renderer.Out viewer.In1

set color.X "0 500 1000"
set color.Y "0 0.01 1"
set opacity.X "0 500 1000"
set opacity.Y "0 0.01 0.1"

set viewer.WinDialog true
exec viewer

message echo 0
message Help 1
clear
print " "
print "====================================="
print " END OF TOUR"
print "====================================="