# ---------------------------------------------------------------------
 #
 # Copyright (c) CREATIS (Centre de Recherche en Acquisition et Traitement de l'Image
 #                        pour la SantÈ)
 # Authors : Eduardo Davila, Frederic Cervenansky, Claire Mouton
 # Previous Authors : Laurent Guigues, Jean-Pierre Roux
 # CreaTools website : www.creatis.insa-lyon.fr/site/fr/creatools_accueil
 #
 #  This software is governed by the CeCILL-B license under French law and
 #  abiding by the rules of distribution of free software. You can  use,
 #  modify and/ or redistribute the software under the terms of the CeCILL-B
 #  license as circulated by CEA, CNRS and INRIA at the following URL
 #  http://www.cecill.info/licences/Licence_CeCILL-B_V1-en.html
 #  or in the file LICENSE.txt.
 #
 #  As a counterpart to the access to the source code and  rights to copy,
 #  modify and redistribute granted by the license, users are provided only
 #  with a limited warranty  and the software's author,  the holder of the
 #  economic rights,  and the successive licensors  have only  limited
 #  liability.
 #
 #  The fact that you are presently reading this means that you have had
 #  knowledge of the CeCILL-B license and that you accept its terms.
 # ------------------------------------------------------------------------ */


description "A tour of wxvtk boxes"
author "laurent.guigues@creatis.insa-lyon.fr"
category "demo"

# put all include before or will be within echo 2 and generate many messages...
include wxvtk
include vtk
include std

# To avoid getting textual help
message Help 0

#==================================================================
print " "
print "====================================="
print "A simple 2D viewer"
print "====================================="
help Viewer2D
message echo 2

new LoadHola reader
new Viewer2D viewer
connect reader.Out viewer.In
set viewer.Slice 20
set viewer.WinDialog true
exec viewer

message echo 0
clear
print " "
print "====================================="
print "A simple 2D slicer"
print "====================================="
help SimpleSlicer
message echo 2

new LoadHola reader
new SimpleSlicer viewer
connect reader.Out viewer.In
set viewer.WinDialog true
exec viewer

message echo 0
clear
print " "
print "====================================="
print "A double 2D slicer"
print "====================================="
help DoubleSlicer
message echo 2

new LoadHola reader
new DoubleSlicer viewer 
connect reader.Out viewer.In1
connect reader.Out viewer.In2
set viewer.WinDialog true
exec viewer

message echo 0
clear
print " "
print "====================================="
print "Slicing an image in 3D"
print "====================================="
help ImagePlanes
message echo 2


new LoadHola reader
new ImagePlanes planes
new Viewer3D viewer
connect reader.Out planes.In
connect planes.PlaneX viewer.Obs1
connect planes.PlaneY viewer.Obs2
connect planes.PlaneZ viewer.Obs3
set viewer.WinDialog true
exec viewer

message echo 0
clear
print " "
print "====================================="
print "Viewing an iso-surface of an image in 3D"
print "====================================="
help SimpleIsoSurfaceViewer
message echo 2

new LoadHola reader
new SimpleIsoSurfaceViewer viewer
connect reader.Out viewer.In
set viewer.WinDialog true
exec viewer

message echo 0
clear
print " "
print "====================================="
print "Viewing both 3 slices and an iso-surface of an image in 3D"
print "====================================="
help IsoSurfaceWidget
message echo 2

new LoadHola reader
new Viewer3D viewer
new ImagePlanes planes
connect reader.Out planes.In
connect planes.PlaneX viewer.Obs1
connect planes.PlaneY viewer.Obs2
connect planes.PlaneZ viewer.Obs3
new IsoSurfaceWidget isosurface
connect reader.Out isosurface.In
connect isosurface.Out viewer.In1
connect isosurface.BoxChange viewer.BoxExecute

new LayoutSplit main
connect viewer.Widget main.Widget1
connect isosurface.Widget main.Widget2
set main.Proportion 70
set main.WinDialog true
exec main

message echo 0
clear
print " "
print "====================================="
print "Volume rendering"
print "====================================="
help VolumeRenderer
message echo 2

new LoadHola reader
new PiecewiseFunction color
new PiecewiseFunction opacity
new VolumeRenderer renderer
new Viewer3D viewer

connect reader.Out renderer.In
connect color.Out renderer.ColorFunction
connect opacity.Out renderer.OpacityFunction
connect renderer.Out viewer.In1

set color.X "0 500 1000"
set color.Y "0 0.01 1"
set opacity.X "0 500 1000"
set opacity.Y "0 0.01 0.1"

set viewer.WinDialog true
exec viewer

message echo 0
message Help 1
clear
print " "
print "====================================="
print " END OF TOUR"
print "====================================="