# ---------------------------------------------------------------------
 #
 # Copyright (c) CREATIS (Centre de Recherche en Acquisition et Traitement de l'Image
 #                        pour la SantÈ)
 # Authors : Eduardo Davila, Frederic Cervenansky, Claire Mouton
 # Previous Authors : Laurent Guigues, Jean-Pierre Roux
 # CreaTools website : www.creatis.insa-lyon.fr/site/fr/creatools_accueil
 #
 #  This software is governed by the CeCILL-B license under French law and
 #  abiding by the rules of distribution of free software. You can  use,
 #  modify and/ or redistribute the software under the terms of the CeCILL-B
 #  license as circulated by CEA, CNRS and INRIA at the following URL
 #  http://www.cecill.info/licences/Licence_CeCILL-B_V1-en.html
 #  or in the file LICENSE.txt.
 #
 #  As a counterpart to the access to the source code and  rights to copy,
 #  modify and redistribute granted by the license, users are provided only
 #  with a limited warranty  and the software's author,  the holder of the
 #  economic rights,  and the successive licensors  have only  limited
 #  liability.
 #
 #  The fact that you are presently reading this means that you have had
 #  knowledge of the CeCILL-B license and that you accept its terms.
 # ------------------------------------------------------------------------ */


include wx
include vtk
include std
include wxvtk

define IsoSurfaceWidget wxvtk
  author "laurent.guigues@creatis.insa-lyon.fr"
  description "Image iso-surface extractor (vtk::IsoSurfaceExtractor) with associated control panel (isovalue, opacity and colour)"
  category "image;mesh;widget;viewer"

  new LayoutLine controls
  new LayoutLine sliders
  new IsoSurfaceExtractor surface
  new Slider isovalue
  new Slider opacity
  new LayoutLine colourFrame
  new ColourSelectorButton colour
  new MultipleInputs refresh  
  new Div div

  connect sliders.Widget controls.Widget1
  connect colourFrame.Widget controls.Widget2

  connect colour.Widget colourFrame.Widget1
  connect isovalue.Widget sliders.Widget1
  connect opacity.Widget sliders.Widget2
  
  connect isovalue.Out surface.Isovalue
  connect opacity.Out div.In1
  set div.In2 100
  connect div.Out surface.Opacity 
  connect colour.Out surface.Colour

  connect isovalue.BoxChange refresh.In1
  connect opacity.BoxChange refresh.In2
  connect colour.BoxChange refresh.In3

#  connect colourButton.BoxChange colour.BoxExecute

  set colourFrame.WinTitle "Colour"
  set controls.Orientation HORIZONTAL
  set isovalue.Title "Isovalue"
  set opacity.Title "Opacity"
  set opacity.Min 0
  set opacity.Max 100
  set opacity.In 100
 
#  set colourButton.Label "Colour"

  input Title controls.WinTitle "Title of the control panel" 
  input In surface.In "Input image"

  input Opacity opacity.In "Initial opacity"
  input Isovalue isovalue.In "Initial isovalue"
  input Colour colour.In "Initial colour"

  input BoxExecute surface.BoxExecute "Box execution"

  input Vertical controls.Orientation "Set to 1 to have controls arranged vertically"

  output Out surface.Out "Output surface"
  output BoxChange refresh.Out "BoxChange" 
  output Widget controls.Widget "Widget"

endefine