CMakeLists.txt

   1 ## =========================================================================
   2 ## @author Leonardo Florez Valencia
   3 ## @email florez-l@javeriana.edu.co
   4 ## =========================================================================
   5
   6 cmake_minimum_required(VERSION 3.0)
   7
   8 ## ========================
   9 ## == Project definition ==
  10 ## ========================
  11
  12 set(prj_MAJ_VER 0)
  13 set(prj_MIN_VER 1)
  14 set(prj_REL_VER 0)
  15 set(prj_VER "${prj_MAJ_VER}.${prj_MIN_VER}.${prj_REL_VER}")
  16 set(prj_SHORT_VER "${prj_MAJ_VER}")
  17 project(fpa VERSION ${prj_VER})
  18
  19 ## ==========================
  20 ## == Some useful policies ==
  21 ## ==========================
  22
  23 set(_policies CMP0015 CMP0020 CMP0042 CMP0053)
  24 foreach(_p ${_policies})
  25   if(POLICY ${_p})
  26     cmake_policy(SET ${_p} NEW)
  27   endif(POLICY ${_p})
  28 endforeach(_p)
  29
  30 ## =========================================================
  31 ## == If working on a MacOSX, activate the use of RPATH's ==
  32 ## ==   Furthermore: prepare the type of executables      ==
  33 ## =========================================================
  34
  35 set(EXECUTABLE_TYPE "" CACHE STRING "Executable linking." FORCE)
  36 if(APPLE)
  37   set(EXECUTABLE_TYPE "MACOSX_BUNDLE" CACHE STRING "Executable linking." FORCE)
  38   set(CMAKE_MACOSX_RPATH true CACHE BOOL "Use RPATH's on MacOSX." FORCE)
  39   mark_as_advanced(CMAKE_MACOSX_RPATH)
  40 elseif(WIN32)
  41   set(EXECUTABLE_TYPE "WIN32" CACHE STRING "Executable linking." FORCE)
  42 endif(APPLE)
  43 mark_as_advanced(EXECUTABLE_TYPE)
  44
  45 ## =======================================================================
  46 ## == Force c++11 language version                                      ==
  47 ## == NOTE: It seems that by default on Visual Studio Compiler supports ==
  48 ## ==       c++11, so it only need to be tested on other OS.            ==
  49 ## =======================================================================
  50
  51 if(NOT MSVC)
  52   include(CheckCXXCompilerFlag)
  53   check_cxx_compiler_flag("-std=c++11" COMPILER_SUPPORTS_CXX11)
  54   if(COMPILER_SUPPORTS_CXX11)
  55     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
  56   else(COMPILER_SUPPORTS_CXX11)
  57     check_cxx_compiler_flag("-std=c++0x" COMPILER_SUPPORTS_CXX0X)
  58     if(COMPILER_SUPPORTS_CXX0X)
  59       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
  60     else(COMPILER_SUPPORTS_CXX0X)
  61       message(
  62         FATAL_ERROR
  63         "The compiler ${CMAKE_CXX_COMPILER} has no C++11 support."
  64         )
  65     endif(COMPILER_SUPPORTS_CXX0X)
  66   endif(COMPILER_SUPPORTS_CXX11)
  67 endif(NOT MSVC)
  68
  69 ## ===================================================
  70 ## == Prepare header generator to build shared libs ==
  71 ## ===================================================
  72
  73 include(GenerateExportHeader)
  74
  75 ## ==================================================
  76 ## == Do not allow to build inside the source tree ==
  77 ## ==================================================
  78
  79 if(PROJECT_BINARY_DIR STREQUAL ${PROJECT_SOURCE_DIR})
  80   message(FATAL_ERROR "Building in the source tree is not allowed.")
  81 endif(PROJECT_BINARY_DIR STREQUAL ${PROJECT_SOURCE_DIR})
  82
  83 ## =================================================
  84 ## == Where to put targets (executables and libs) ==
  85 ## =================================================
  86
  87 set(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR})
  88 set(LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR})
  89 mark_as_advanced(
  90   CMAKE_BACKWARDS_COMPATIBILITY
  91   EXECUTABLE_OUTPUT_PATH
  92   LIBRARY_OUTPUT_PATH
  93   )
  94
  95 ## ===========================================
  96 ## == Find needed packages and dependencies ==
  97 ## ===========================================
  98
  99 find_package(ITK CONFIG REQUIRED)
 100 include(${ITK_USE_FILE})
 101 if(ITKVtkGlue_LOADED)
 102   find_package(VTK CONFIG REQUIRED)
 103   include(${VTK_USE_FILE})
 104 endif(ITKVtkGlue_LOADED)
 105
 106 ## =========================
 107 ## == Installation values ==
 108 ## =========================
 109
 110 set(config_install_dir "lib/cmake/${PROJECT_NAME}")
 111 set(include_install_dir "include")
 112 set(generated_dir "${CMAKE_CURRENT_BINARY_DIR}/generated")
 113 set(version_config "${generated_dir}/${PROJECT_NAME}ConfigVersion.cmake")
 114 set(project_config "${generated_dir}/${PROJECT_NAME}Config.cmake")
 115 set(targets_export_name "${PROJECT_NAME}Targets")
 116 set(namespace "${PROJECT_NAME}::")
 117
 118 ## ===========================
 119 ## == Build different parts ==
 120 ## ===========================
 121
 122 subdirs(appli lib tests)
 123
 124 ## ===============================
 125 ## == Global installation rules ==
 126 ## ===============================
 127
 128 include(CMakePackageConfigHelpers)
 129 write_basic_package_version_file(
 130   "${version_config}" COMPATIBILITY SameMajorVersion
 131   )
 132 configure_package_config_file(
 133   "cmake/${PROJECT_NAME}Config.cmake.in"
 134   "${project_config}"
 135   INSTALL_DESTINATION "${config_install_dir}"
 136   )
 137 install(
 138   EXPORT "${targets_export_name}"
 139   NAMESPACE "${namespace}"
 140   DESTINATION "${config_install_dir}"
 141   )
 142 install(
 143   FILES "${project_config}"
 144   DESTINATION "${config_install_dir}"
 145   )
 146
 147 ## eof - $RCSfile$
 148