cmake/Functions.cmake

   1 ## -------------------------------------------------------------------------
   2 FUNCTION(NormPaths output_files)
   3 SET(_out)
   4 FOREACH(_f ${ARGN})
   5   SET(_d)
   6   FILE(TO_CMAKE_PATH ${_f} _d)
   7   LIST(APPEND _out ${_d})
   8 ENDFOREACH(_f)
   9 SET(${output_files} "${_out}" PARENT_SCOPE)
  10 ENDFUNCTION()
  11
  12 ## -------------------------------------------------------------------------
  13 FUNCTION(Wrap_Qt_CPP output_files)
  14 SET(_out)
  15 FOREACH(_f ${ARGN})
  16   IF(EXISTS ${_f})
  17     FILE(READ ${_f} _txt)
  18     STRING(FIND "${_txt}" "Q_OBJECT" _pos)
  19     IF(NOT ${_pos} EQUAL -1)
  20       SET(_s)
  21       QT4_WRAP_CPP(_s ${_f})
  22       SET(_out ${_out} ${_s})
  23     ENDIF(NOT ${_pos} EQUAL -1)
  24   ENDIF(EXISTS ${_f})
  25 ENDFOREACH(_f)
  26 SET(${output_files} "${_out}" PARENT_SCOPE)
  27 ENDFUNCTION()
  28
  29 ## -------------------------------------------------------------------------
  30 FUNCTION(Wrap_Qt_UI output_files)
  31 NormPaths(_source_dir ${PROJECT_SOURCE_DIR})
  32 NormPaths(_binary_dir ${PROJECT_BINARY_DIR})
  33 SET(_out)
  34 FOREACH(_f ${ARGN})
  35   IF(EXISTS ${_f})
  36     GET_FILENAME_COMPONENT(_name ${_f} NAME_WE)
  37     GET_FILENAME_COMPONENT(_dir ${_f} DIRECTORY)
  38     SET(_base_dir ${_source_dir})
  39     STRING(FIND "${_dir}" "${_base_dir}" _pos)
  40     IF(${_pos} EQUAL -1)
  41       SET(_base_dir ${_binary_dir})
  42       STRING(FIND "${_dir}" "${_base_dir}" _pos)
  43     ENDIF(${_pos} EQUAL -1)
  44     IF(NOT ${_pos} EQUAL -1)
  45       STRING(REPLACE "${_base_dir}/" "" _dir ${_dir})
  46       SET(_out_f ${_binary_dir}/${_dir}/ui_${_name}.h)
  47       LIST(APPEND _out ${_out_f})
  48       ADD_CUSTOM_COMMAND(
  49         OUTPUT ${_out_f}
  50         COMMAND Qt4::uic
  51         ARGS -o ${_out_f} ${_f}
  52         MAIN_DEPENDENCY ${_f} VERBATIM
  53         )
  54     ENDIF(NOT ${_pos} EQUAL -1)
  55   ENDIF(EXISTS ${_f})
  56 ENDFOREACH(_f)
  57 SET(${output_files} "${_out}" PARENT_SCOPE)
  58 ENDFUNCTION()
  59
  60 ## -------------------------------------------------------------------------
  61 FUNCTION(
  62   PrepareSourceFiles
  63   out_sources_list
  64   out_headers_list
  65   out_headers_paths
  66   )
  67 SET(_config_extensions .c.in .cpp.in .cxx.in .h.in .hpp.in .hxx.in .ui.in)
  68 SET(_sources_extensions .c .cpp .cxx)
  69 SET(_headers_extensions .h .hpp .hxx)
  70 SET(_qt_ui_extensions .ui)
  71 SET(_demangler_extensions .d)
  72
  73 ## -- Configure inputs
  74 SET(_all_files)
  75 FOREACH(_file ${ARGN})
  76   GET_FILENAME_COMPONENT(_ext ${_file} EXT)
  77   LIST(FIND _config_extensions ${_ext} _cfg)
  78   IF(NOT ${_cfg} EQUAL -1)
  79     STRING(
  80       REPLACE
  81       ${PROJECT_SOURCE_DIR}
  82       ${PROJECT_BINARY_DIR}
  83       _file_bin
  84       ${_file}
  85       )
  86     STRING(LENGTH ${_file_bin} _file_bin_len)
  87     MATH(EXPR _file_bin_len "${_file_bin_len}-3")
  88     STRING(SUBSTRING ${_file_bin} 0 ${_file_bin_len} _file_bin)
  89     CONFIGURE_FILE(${_file} ${_file_bin} @ONLY)
  90     LIST(APPEND _all_files ${_file_bin})
  91   ELSE(NOT ${_cfg} EQUAL -1)
  92     LIST(APPEND _all_files ${_file})
  93   ENDIF(NOT ${_cfg} EQUAL -1)
  94 ENDFOREACH(_file)
  95
  96 ## -- Separate files
  97 SET(_srcs)
  98 SET(_hdrs)
  99 SET(_qts)
 100 SET(_demanglers)
 101 FOREACH(_file ${_all_files})
 102   GET_FILENAME_COMPONENT(_ext ${_file} EXT)
 103   LIST(FIND _sources_extensions ${_ext} _src)
 104   LIST(FIND _headers_extensions ${_ext} _hdr)
 105   LIST(FIND _qt_ui_extensions ${_ext} _ui)
 106   LIST(FIND _demangler_extensions ${_ext} _dem)
 107   IF(NOT ${_src} EQUAL -1)
 108     LIST(APPEND _srcs ${_file})
 109   ENDIF(NOT ${_src} EQUAL -1)
 110   IF(NOT ${_hdr} EQUAL -1)
 111     LIST(APPEND _hdrs ${_file})
 112   ENDIF(NOT ${_hdr} EQUAL -1)
 113   IF(NOT ${_ui} EQUAL -1)
 114     LIST(APPEND _qts ${_file})
 115   ENDIF(NOT ${_ui} EQUAL -1)
 116   IF(NOT ${_dem} EQUAL -1)
 117     LIST(APPEND _demanglers ${_file})
 118   ENDIF(NOT ${_dem} EQUAL -1)
 119 ENDFOREACH(_file)
 120
 121 # -- Prepare Qt4-based code
 122 IF(Qt4_FOUND)
 123   ## -- Guess what headers sould be qt-moc'ed
 124   Wrap_Qt_CPP(_moc ${_hdrs})
 125   IF(_moc)
 126     LIST(APPEND _srcs ${_moc})
 127   ENDIF(_moc)
 128
 129   ## -- Guess what qt-ui's sould be qt-uic'ed
 130   ## -- Wrap qt-ui headers: this is equivalent to QT4_WRAP_UI except to change
 131   ## -- the output file
 132   Wrap_Qt_UI(_qt_hdrs ${_qts})
 133   IF(_qt_hdrs)
 134     LIST(APPEND _hdrs ${_qt_hdrs})
 135   ENDIF(_qt_hdrs)
 136 ENDIF(Qt4_FOUND)
 137
 138 ## -- Create demanglers
 139 FOREACH(_d ${_demanglers})
 140   STRING(
 141     REPLACE
 142     ${PROJECT_SOURCE_DIR}
 143     ${PROJECT_BINARY_DIR}
 144     _d_bin
 145     ${_d}
 146     )
 147   GET_FILENAME_COMPONENT(_d_path ${_d_bin} DIRECTORY)
 148   GET_FILENAME_COMPONENT(_out_name ${_d_bin} NAME_WE)
 149   SET(_d_out ${_d_path}/${_out_name}_Demanglers.h)
 150   ADD_CUSTOM_COMMAND(
 151     OUTPUT ${_d_out}
 152     COMMAND ${CMAKE_COMMAND} -E make_directory ${_d_path}
 153     COMMAND ${cpPlugins_bash_CreateDemanglers_APP} ${_d} ${_out_name} ${_d_out}
 154     DEPENDS ${cpPlugins_bash_CreateDemanglers_APP} ${_d}
 155     )
 156   LIST(APPEND _hdrs ${_d_out})
 157 ENDFOREACH(_d)
 158
 159 ## -- Real compilation
 160 SET(_hdrs_paths)
 161 FOREACH(_hdr ${_hdrs})
 162   GET_FILENAME_COMPONENT(_path ${_hdr} DIRECTORY)
 163   LIST(FIND _hdrs_paths ${_path} _path_idx)
 164   IF(${_path_idx} EQUAL -1)
 165     LIST(APPEND _hdrs_paths ${_path})
 166   ENDIF(${_path_idx} EQUAL -1)
 167 ENDFOREACH(_hdr)
 168
 169 SET(${out_sources_list} ${_srcs} PARENT_SCOPE)
 170 SET(${out_headers_list} ${_hdrs} PARENT_SCOPE)
 171 SET(${out_headers_paths} ${_hdrs_paths} PARENT_SCOPE)
 172
 173 ENDFUNCTION()
 174
 175 ## -------------------------------------------------------------------------
 176 FUNCTION(
 177   CreateLib
 178   lib_name
 179   lib_type
 180   )
 181 PrepareSourceFiles(_srcs _hdrs _paths ${ARGN})
 182 INCLUDE_DIRECTORIES(
 183   ${_paths}
 184   ${CMAKE_CURRENT_SOURCE_DIR}
 185   ${CMAKE_CURRENT_BINARY_DIR}
 186   )
 187 IF(_srcs)
 188   ADD_LIBRARY(${lib_name} ${lib_type} ${_srcs} ${_hdrs})
 189   GENERATE_EXPORT_HEADER(
 190     ${lib_name}
 191     BASE_NAME ${lib_name}
 192     EXPORT_MACRO_NAME ${lib_name}_EXPORT
 193     EXPORT_FILE_NAME ${lib_name}_Export.h
 194     STATIC_DEFINE ${lib_name}_BUILT_AS_STATIC
 195     )
 196 ENDIF(_srcs)
 197 ENDFUNCTION()
 198
 199 ## -------------------------------------------------------------------------
 200 FUNCTION(
 201   CompileLibFromDir
 202   lib_name
 203   lib_type
 204   lib_dir
 205   )
 206 FILE(GLOB_RECURSE _files "${lib_dir}/*")
 207 CreateLib(${lib_name} ${lib_type} ${_files} ${ARGN})
 208 ENDFUNCTION()
 209
 210 ## -------------------------------------------------------------------------
 211 FUNCTION(
 212   CompileInstances
 213   out_lib_name
 214   def_file
 215   number_of_files
 216   )
 217
 218 ### -- Configure inputs to be cmake-path compatible
 219 SET(_src_dir ${CMAKE_CURRENT_SOURCE_DIR})
 220 SET(_bin_dir ${CMAKE_CURRENT_BINARY_DIR})
 221 SET(_def_file "${_src_dir}/${def_file}")
 222
 223 ## -- Infere source code filenames
 224 MATH(EXPR _last_range "${number_of_files}-1")
 225 SET(_out_code "${_bin_dir}/${out_lib_name}.h")
 226 FOREACH(_n RANGE 0 ${_last_range})
 227   LIST(APPEND _out_code ${_bin_dir}/${out_lib_name}_${_n}.cxx)
 228 ENDFOREACH(_n)
 229
 230 ## -- Command to write source code
 231 ADD_CUSTOM_COMMAND(
 232   OUTPUT ${_out_code}
 233   DEPENDS ${cpPlugins_bash_CreateInstances_APP} ${_def_file}
 234   COMMAND ${cpPlugins_bash_CreateInstances_APP} ${_def_file} ${out_lib_name} ${_bin_dir} ${number_of_files}
 235   )
 236
 237 ## -- Create library
 238 CreateLib(${out_lib_name} SHARED "${_out_code}")
 239
 240 ENDFUNCTION()
 241
 242 ## -------------------------------------------------------------------------
 243 FUNCTION(
 244   CreatePlugin
 245   lib_name
 246   lib_dir
 247   number_of_files
 248   )
 249
 250 GET_FILENAME_COMPONENT(_lib_dir ${lib_dir} REALPATH)
 251 FILE(GLOB_RECURSE _files "${_lib_dir}/*")
 252 SET(_hdr_to_wrap)
 253 SET(_instances)
 254 FOREACH(_file ${_files})
 255   FILE(READ ${_file} _txt)
 256   STRING(FIND "${_txt}" "cpPluginsObject" _res)
 257   IF(NOT ${_res} EQUAL -1)
 258     LIST(APPEND _hdr_to_wrap ${_file})
 259   ENDIF(NOT ${_res} EQUAL -1)
 260   GET_FILENAME_COMPONENT(_ext ${_file} EXT)
 261   IF(${_ext} STREQUAL ".i")
 262     LIST(APPEND _instances ${_file})
 263   ENDIF(${_ext} STREQUAL ".i")
 264 ENDFOREACH(_file)
 265
 266 IF(_instances)
 267   FOREACH(_instance ${_instances})
 268     STRING(
 269       REPLACE
 270       ${PROJECT_SOURCE_DIR}
 271       ${PROJECT_BINARY_DIR}
 272       _out_dir
 273       ${_lib_dir}
 274       )
 275     MATH(EXPR _last_range "${number_of_files}-1")
 276     SET(_out_code "${_out_dir}/${lib_name}.h")
 277     FOREACH(_n RANGE 0 ${_last_range})
 278       LIST(APPEND _out_code ${_out_dir}/${lib_name}_${_n}.cxx)
 279     ENDFOREACH(_n)
 280
 281     ADD_CUSTOM_COMMAND(
 282       OUTPUT ${_out_code}
 283       DEPENDS ${cpPlugins_bash_CreateInstances_APP} ${_instance}
 284       COMMAND ${CMAKE_COMMAND} -E make_directory ${_out_dir}
 285       COMMAND ${cpPlugins_bash_CreateInstances_APP} ${_instance} ${lib_name} ${_out_dir} ${number_of_files}
 286       )
 287     LIST(APPEND _files ${_out_code})
 288   ENDFOREACH(_instance)
 289 ENDIF(_instances)
 290
 291 IF(_hdr_to_wrap)
 292   STRING(
 293     REPLACE
 294     ${PROJECT_SOURCE_DIR}
 295     ${PROJECT_BINARY_DIR}
 296     _out_dir
 297     ${_lib_dir}
 298     )
 299   SET(_host ${_out_dir}/${lib_name}_host.cxx)
 300   ADD_CUSTOM_COMMAND(
 301     OUTPUT ${_host}
 302     DEPENDS ${cpPlugins_bash_HostCreator_APP} ${_hdr_to_wrap}
 303     COMMAND ${CMAKE_COMMAND} -E make_directory ${_out_dir}
 304     COMMAND ${cpPlugins_bash_HostCreator_APP} ${lib_name} ${_host} ${_hdr_to_wrap}
 305     )
 306   LIST(APPEND _files ${_host})
 307 ENDIF(_hdr_to_wrap)
 308
 309 CreateLib(${lib_name} SHARED ${_files})
 310
 311 ENDFUNCTION()
 312
 313 ## -------------------------------------------------------------------------
 314 FUNCTION(
 315   CompileAppFromDir
 316   app_name
 317   app_dir
 318   )
 319 FILE(GLOB_RECURSE _files "${app_dir}/*")
 320 PrepareSourceFiles(_srcs _hdrs _paths ${_files} ${ARGN})
 321 INCLUDE_DIRECTORIES(
 322   ${_paths}
 323   ${CMAKE_CURRENT_SOURCE_DIR}
 324   ${CMAKE_CURRENT_BINARY_DIR}
 325   )
 326 IF(_srcs)
 327   SET(_app_os_target)
 328   IF(${CMAKE_SYSTEM_NAME} STREQUAL "Windows")
 329     SET(_app_os_target WIN32)
 330   ELSEIF(${CMAKE_SYSTEM_NAME} STREQUAL "Darwin")
 331     SET(_app_os_target MACOSX_BUNDLE)
 332   ENDIF(${CMAKE_SYSTEM_NAME} STREQUAL "Windows")
 333   ADD_EXECUTABLE(${app_name} ${_app_os_target} ${_srcs} ${_hdrs})
 334 ENDIF(_srcs)
 335 ENDFUNCTION()
 336
 337 ## eof - $RCSfile$