CMakeLists.txt

   1 PROJECT(GDCM)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.0)
   3 # okay in fact you need at least cmake 2.0.4 to get swig working properly
   4 # and you cannot use cmake 2.0.6 out of the box due to a bug (patched in debian package)
   5
   6
   7      if(COMMAND cmake_policy)
   8        cmake_policy(SET CMP0003 NEW)
   9      endif(COMMAND cmake_policy)
  10
  11
  12
  13 #-----------------------------------------------------------------------------
  14 # GDCM version number, usefull for packaging and doxygen doc:
  15 SET(GDCM_MAJOR_VERSION 1)
  16 SET(GDCM_MINOR_VERSION 3)
  17 SET(GDCM_BUILD_VERSION 2)
  18 SET(GDCM_VERSION
  19     "${GDCM_MAJOR_VERSION}.${GDCM_MINOR_VERSION}.${GDCM_BUILD_VERSION}")
  20
  21 #-----------------------------------------------------------------------------
  22 # Provide compatibility options.
  23 OPTION(GDCM_LEGACY_REMOVE "Remove all legacy code completely." OFF)
  24 OPTION(GDCM_LEGACY_SILENT "Silence all legacy code messages." OFF)
  25 MARK_AS_ADVANCED(GDCM_LEGACY_REMOVE GDCM_LEGACY_SILENT)
  26
  27 # VS 2005 declared that some C functions were deprecated...
  28 IF(CMAKE_COMPILER_2005)
  29   ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
  30   ADD_DEFINITIONS(-D_SCL_SECURE_NO_DEPRECATE)
  31 ENDIF(CMAKE_COMPILER_2005)
  32
  33 #-----------------------------------------------------------------------------
  34 # Build shared lib by default
  35 OPTION(BUILD_SHARED_LIBS "Build GDCM with shared libraries." ON)
  36
  37 SET(GDCM_CMAKE_DIR "${GDCM_SOURCE_DIR}/Utilities/CMake")
  38 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${GDCM_CMAKE_DIR}")
  39
  40 SET(GDCM_CONFIGURATION_TYPES ${CMAKE_CONFIGURATION_TYPES})
  41
  42 OPTION(GDCM_DEBUG "Turn verbosity of some statement ON." OFF)
  43 MARK_AS_ADVANCED(GDCM_DEBUG)
  44
  45 # --------------------------------------------------------------------------
  46 SET (GDCM_NAME_SPACE gdcm    CACHE STRING "name space")
  47
  48 # --------------------------------------------------------------------------
  49 # Install directories
  50 STRING(TOLOWER ${PROJECT_NAME} project_name)
  51
  52 IF(NOT GDCM_INSTALL_BIN_DIR)
  53   SET(GDCM_INSTALL_BIN_DIR "/bin")
  54 ENDIF(NOT GDCM_INSTALL_BIN_DIR)
  55
  56 IF(NOT GDCM_INSTALL_LIB_DIR)
  57   SET(GDCM_INSTALL_LIB_DIR "/lib/${project_name}")
  58 ENDIF(NOT GDCM_INSTALL_LIB_DIR)
  59
  60 IF(NOT GDCM_INSTALL_DATA_DIR)
  61   SET(GDCM_INSTALL_DATA_DIR "/share/${project_name}")
  62 ENDIF(NOT GDCM_INSTALL_DATA_DIR)
  63
  64 IF(NOT GDCM_INSTALL_INCLUDE_DIR)
  65   SET(GDCM_INSTALL_INCLUDE_DIR "/include/${project_name}")
  66 ENDIF(NOT GDCM_INSTALL_INCLUDE_DIR)
  67
  68 IF(NOT GDCM_INSTALL_PACKAGE_DIR)
  69   SET(GDCM_INSTALL_PACKAGE_DIR ${GDCM_INSTALL_LIB_DIR})
  70 ENDIF(NOT GDCM_INSTALL_PACKAGE_DIR)
  71
  72 IF(NOT GDCM_VTK_INSTALL_PACKAGE_DIR)
  73   SET(GDCM_VTK_INSTALL_PACKAGE_DIR ${VTK_INSTALL_PACKAGE_DIR})
  74 ENDIF(NOT GDCM_VTK_INSTALL_PACKAGE_DIR)
  75
  76 IF(NOT GDCM_INSTALL_NO_DEVELOPMENT)
  77   SET(GDCM_INSTALL_NO_DEVELOPMENT 0)
  78 ENDIF(NOT GDCM_INSTALL_NO_DEVELOPMENT)
  79
  80 IF(NOT GDCM_INSTALL_NO_RUNTIME)
  81   SET(GDCM_INSTALL_NO_RUNTIME 0)
  82 ENDIF(NOT GDCM_INSTALL_NO_RUNTIME)
  83
  84 IF(NOT GDCM_INSTALL_NO_DOCUMENTATION)
  85   SET(GDCM_INSTALL_NO_DOCUMENTATION 0)
  86 ENDIF(NOT GDCM_INSTALL_NO_DOCUMENTATION)
  87
  88 SET(GDCM_INSTALL_NO_LIBRARIES)
  89 IF(GDCM_BUILD_SHARED_LIBS)
  90   IF(GDCM_INSTALL_NO_RUNTIME AND GDCM_INSTALL_NO_DEVELOPMENT)
  91     SET(GDCM_INSTALL_NO_LIBRARIES 1)
  92   ENDIF(GDCM_INSTALL_NO_RUNTIME AND GDCM_INSTALL_NO_DEVELOPMENT)
  93 ELSE(GDCM_BUILD_SHARED_LIBS)
  94   IF(GDCM_INSTALL_NO_DEVELOPMENT)
  95     SET(GDCM_INSTALL_NO_LIBRARIES 1)
  96   ENDIF(GDCM_INSTALL_NO_DEVELOPMENT)
  97 ENDIF(GDCM_BUILD_SHARED_LIBS)
  98
  99 #-----------------------------------------------------------------------------
 100 SET (EXECUTABLE_OUTPUT_PATH ${GDCM_BINARY_DIR}/bin CACHE PATH "Single output directory for building all executables.")
 101 SET (LIBRARY_OUTPUT_PATH ${GDCM_BINARY_DIR}/bin    CACHE PATH "Single output directory for building all libraries.")
 102 MARK_AS_ADVANCED(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
 103
 104
 105 #-----------------------------------------------------------------------------
 106 # Test if compiler defines the pseudo-macro __FUNCTION__
 107 IF("GDCM_COMPILER_HAS_FUNCTION" MATCHES "^GDCM_COMPILER_HAS_FUNCTION$")
 108   MESSAGE(STATUS "Checking support for __FUNCTION__ in compiler")
 109   TRY_COMPILE(GDCM_COMPILER_HAS_FUNCTION
 110               ${GDCM_BINARY_DIR}/CMakeTmp/Function
 111               ${GDCM_SOURCE_DIR}/CMake/gdcmTestFUNCTION.cxx
 112               OUTPUT_VARIABLE OUTPUT)
 113   IF(GDCM_COMPILER_HAS_FUNCTION)
 114     MESSAGE(STATUS "Checking support for __FUNCTION__ -- yes")
 115     SET(GDCM_COMPILER_HAS_FUNCTION 1 CACHE INTERNAL "Support for extension C __FUNCTION__")
 116     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeOutput.log
 117       "Determining if the C compiler supports __FUNCTION__ "
 118       "passed with the following output:\n"
 119       "${OUTPUT}\n" APPEND)
 120   ELSE(GDCM_COMPILER_HAS_FUNCTION)
 121     MESSAGE(STATUS "Checking support for __FUNCTION__ -- no")
 122     SET(GDCM_COMPILER_HAS_FUNCTION 0 CACHE INTERNAL "Support for extension C __FUNCTION__")
 123     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeError.log
 124       "Determining if the C compiler supports __FUNCTION__ "
 125       "failed with the following output:\n"
 126       "${OUTPUT}\n" APPEND)
 127   ENDIF(GDCM_COMPILER_HAS_FUNCTION)
 128 ENDIF("GDCM_COMPILER_HAS_FUNCTION" MATCHES "^GDCM_COMPILER_HAS_FUNCTION$")
 129
 130 #-----------------------------------------------------------------------------
 131 # Test is compiler support istringstream
 132 IF("GDCM_TEST_ISTRINGSTREAM" MATCHES "^GDCM_TEST_ISTRINGSTREAM$")
 133   MESSAGE(STATUS "Checking istringstream")
 134   TRY_RUN(GDCM_TEST_ISTRINGSTREAM GDCM_TEST_ISTRINGSTREAM_COMPILED
 135           ${GDCM_BINARY_DIR}/CMakeTmp/
 136           ${GDCM_SOURCE_DIR}/CMake/gdcmTestIstringStream.cxx)
 137   IF(GDCM_TEST_ISTRINGSTREAM_COMPILED)
 138     IF(GDCM_TEST_ISTRINGSTREAM)
 139       MESSAGE(STATUS "Checking istringstream works -- yes")
 140       SET(GDCM_TEST_ISTRINGSTREAM 1 CACHE INTERNAL "Whether istringstream works.")
 141     ELSE(GDCM_TEST_ISTRINGSTREAM)
 142       MESSAGE(STATUS "Checking istringstream works -- no")
 143       SET(GDCM_TEST_ISTRINGSTREAM 0 CACHE INTERNAL "Whether istringstream works.")
 144     ENDIF(GDCM_TEST_ISTRINGSTREAM)
 145   ELSE(GDCM_TEST_ISTRINGSTREAM_COMPILED)
 146     MESSAGE(STATUS "Checking istringstream -- failed")
 147   ENDIF(GDCM_TEST_ISTRINGSTREAM_COMPILED)
 148 ENDIF("GDCM_TEST_ISTRINGSTREAM" MATCHES "^GDCM_TEST_ISTRINGSTREAM$")
 149
 150 #-----------------------------------------------------------------------------
 151 # Build directory on which many applications depend
 152 SUBDIRS(
 153   Dicts
 154   src
 155 )
 156 #-----------------------------------------------------------------------------
 157 # Example subdir:
 158
 159 OPTION(BUILD_EXAMPLES "Build GDCM examples." ON)
 160 IF(BUILD_EXAMPLES)
 161   SUBDIRS(Example)
 162 ENDIF(BUILD_EXAMPLES)
 163
 164 #-----------------------------------------------------------------------------
 165 # Adding GDCM_DATA_ROOT
 166 FIND_PATH(GDCM_DATA_ROOT gdcm-ACR-LibIDO.acr
 167   ${GDCM_SOURCE_DIR}/../gdcmData
 168   $ENV{GDCM_DATA}
 169   $ENV{PUB_DICT_PATH}/../../gdcmData
 170 )
 171 # Adding GDCM_DATA_ROOT
 172 FIND_PATH(GDCM_DATA_EXTRA_ROOT gdcmData.tar.gz
 173   ${GDCM_SOURCE_DIR}/../gdcmDataExtra
 174 )
 175
 176 # Set the place for the public dictionary, must be set before gdcmConfigure.h
 177 FIND_PATH(GDCM_PUB_DICT_PATH dicomV3.dic
 178   ${GDCM_SOURCE_DIR}/Dicts
 179   $ENV{PUB_DICT_PATH}
 180 )
 181
 182 #-----------------------------------------------------------------------------
 183 # SunOS + old gcc fixes:
 184 INCLUDE (${CMAKE_ROOT}/Modules/CMakeBackwardCompatibilityCXX.cmake)
 185 IF(CMAKE_NO_ANSI_STRING_STREAM)
 186   SET(GDCM_NO_ANSI_STRING_STREAM 1)
 187 ENDIF(CMAKE_NO_ANSI_STRING_STREAM)
 188
 189 # Big endian thing:
 190 INCLUDE (${CMAKE_ROOT}/Modules/TestBigEndian.cmake)
 191 TEST_BIG_ENDIAN(GDCM_WORDS_BIGENDIAN)
 192
 193 INCLUDE (${CMAKE_ROOT}/Modules/CheckIncludeFile.cmake)
 194 CHECK_INCLUDE_FILE("stdint.h"       CMAKE_HAVE_STDINT_H)
 195 IF(UNIX) #Avoid polluting Win32 cmakecache
 196   CHECK_INCLUDE_FILE("inttypes.h"     CMAKE_HAVE_INTTYPES_H)
 197 ENDIF(UNIX)
 198 # Special Time support, two convention: *NIX vs Win32
 199 CHECK_INCLUDE_FILE("sys/times.h"     CMAKE_HAVE_SYS_TIMES_H)
 200 CHECK_INCLUDE_FILE("sys/timeb.h"     CMAKE_HAVE_SYS_TIMEB_H)
 201
 202 # Check if header file exists and add it to the list.
 203 INCLUDE (${CMAKE_ROOT}/Modules/CheckIncludeFiles.cmake)
 204 MACRO(CHECK_INCLUDE_FILE_CONCAT FILE VARIABLE)
 205   CHECK_INCLUDE_FILES("${GDCM_INCLUDES};${FILE}" ${VARIABLE})
 206   IF(${VARIABLE})
 207     SET(GDCM_INCLUDES ${GDCM_INCLUDES} ${FILE})
 208   ENDIF(${VARIABLE})
 209 ENDMACRO(CHECK_INCLUDE_FILE_CONCAT)
 210
 211 # Need those header for GetMacAddress in Util
 212 # This is tricky as you need to figure out the proper order to
 213 # test the inclusion of files
 214 CHECK_INCLUDE_FILE_CONCAT("unistd.h"       CMAKE_HAVE_UNISTD_H)
 215 CHECK_INCLUDE_FILE_CONCAT("stdlib.h"       CMAKE_HAVE_STDLIB_H)
 216 IF(UNIX) #Avoid polluting Win32 cmakecache
 217   CHECK_INCLUDE_FILE_CONCAT("sys/ioctl.h"    CMAKE_HAVE_SYS_IOCTL_H)
 218   CHECK_INCLUDE_FILE_CONCAT("sys/socket.h"   CMAKE_HAVE_SYS_SOCKET_H)
 219   CHECK_INCLUDE_FILE_CONCAT("sys/sockio.h"   CMAKE_HAVE_SYS_SOCKIO_H)
 220   CHECK_INCLUDE_FILE_CONCAT("net/if.h"       CMAKE_HAVE_NET_IF_H)
 221   CHECK_INCLUDE_FILE_CONCAT("netinet/in.h"   CMAKE_HAVE_NETINET_IN_H)
 222   CHECK_INCLUDE_FILE_CONCAT("net/if_dl.h"    CMAKE_HAVE_NET_IF_DL_H)
 223   CHECK_INCLUDE_FILE_CONCAT("net/if_arp.h"   CMAKE_HAVE_NET_IF_ARP_H)
 224 ENDIF(UNIX)
 225
 226 #-----------------------------------------------------------------------------
 227 # Test if os defines a length for sockaddr
 228 # only doing the test when we have sys/socket
 229 IF( ${CMAKE_HAVE_SYS_SOCKET_H} )
 230   IF("HAVE_SA_LEN" MATCHES "^HAVE_SA_LEN$")
 231     STRING(ASCII 35 POUND)
 232     FILE(WRITE ${GDCM_BINARY_DIR}/CMakeTmp/gdcmTestHAVESALEN.c
 233       "${POUND}include <sys/types.h>\n"
 234       "${POUND}include <sys/socket.h>\n"
 235       "int main() { struct sockaddr sa; sa.sa_len = 0; }\n")
 236     MESSAGE(STATUS "Checking if ifreq has a sa_len")
 237     TRY_COMPILE(HAVE_SA_LEN
 238       ${GDCM_BINARY_DIR}
 239       ${GDCM_BINARY_DIR}/CMakeTmp/gdcmTestHAVESALEN.c
 240       OUTPUT_VARIABLE OUTPUT)
 241     IF(HAVE_SA_LEN)
 242       MESSAGE(STATUS "Checking if ifreq has a sa_len -- yes")
 243       SET(HAVE_SA_LEN 1 CACHE INTERNAL "Support if ifreq has a sa_len")
 244       WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeOutput.log
 245         "Determining if ifreq has a sa_len"
 246         "passed with the following output:\n"
 247         "${OUTPUT}\n" APPEND)
 248     ELSE(HAVE_SA_LEN)
 249       MESSAGE(STATUS "Checking if ifreq has a sa_len -- no")
 250       SET(HAVE_SA_LEN 0 CACHE INTERNAL "Support if ifreq has a sa_len")
 251       WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeError.log
 252         "Determining if ifreq has a sa_len"
 253         "failed with the following output:\n"
 254         "${OUTPUT}\n" APPEND)
 255     ENDIF(HAVE_SA_LEN)
 256   ENDIF("HAVE_SA_LEN" MATCHES "^HAVE_SA_LEN$")
 257 ENDIF( ${CMAKE_HAVE_SYS_SOCKET_H} )
 258
 259 #-----------------------------------------------------------------------------
 260 # Force Big Endian emulation on little endian:
 261 OPTION(GDCM_FORCE_BIGENDIAN_EMULATION "Force Big Endian Emulation. Don't use if you don't know what you are doing." OFF)
 262
 263 CONFIGURE_FILE(${GDCM_SOURCE_DIR}/gdcmConfigure.h.in
 264                ${GDCM_BINARY_DIR}/gdcmConfigure.h @ONLY IMMEDIATE
 265                )
 266
 267 IF(NOT GDCM_INSTALL_NO_DEVELOPMENT)
 268   INSTALL_FILES(${GDCM_INSTALL_INCLUDE_DIR} FILES gdcmConfigure.h)
 269 ENDIF(NOT GDCM_INSTALL_NO_DEVELOPMENT)
 270
 271 #-----------------------------------------------------------------------------
 272 # Add the testing directories
 273 OPTION(BUILD_TESTING "Build testing." ON)
 274
 275 IF(BUILD_TESTING)
 276   CONFIGURE_FILE(${GDCM_SOURCE_DIR}/CMake/CTestCustom.ctest.in
 277       ${GDCM_BINARY_DIR}/CMake/CTestCustom.ctest @ONLY)
 278   FILE(WRITE ${GDCM_BINARY_DIR}/CTestCustom.cmake
 279     "INCLUDE(\"${GDCM_BINARY_DIR}/CMake/CTestCustom.ctest\")\n")
 280   ENABLE_TESTING()
 281   INCLUDE(CTest)
 282   SUBDIRS(Testing)
 283 ENDIF(BUILD_TESTING)
 284
 285
 286 #-----------------------------------------------------------------------------
 287 OPTION(GDCM_VTK "Build VTK-GDCM Lib." OFF)
 288 IF(GDCM_VTK)
 289   # Search VTK
 290   FIND_PACKAGE(VTK)
 291   # If vtk found
 292   IF(VTK_FOUND)
 293     #INCLUDE(${VTK_USE_FILE})
 294     SUBDIRS(vtk)
 295   ELSEIF(VTK_FOUND)
 296     message(FATAL_ERROR "VTK not found")
 297   ENDIF(VTK_FOUND)
 298 ENDIF(GDCM_VTK)
 299
 300 #-----------------------------------------------------------------------------
 301 OPTION(GDCM_WRAP_PYTHON "Wrap GDCM classes into the Python language." OFF)
 302 #if wrapping enable
 303 IF(GDCM_WRAP_PYTHON)
 304   # Search Python libs:
 305   FIND_PACKAGE(PythonLibs)
 306   # If PythonLibs found
 307   IF(PYTHON_LIBRARY)
 308     SUBDIRS(gdcmPython)
 309   ENDIF(PYTHON_LIBRARY)
 310 ENDIF(GDCM_WRAP_PYTHON)
 311
 312 #-----------------------------------------------------------------------------
 313 OPTION(GDCM_DOCUMENTATION "Build source documentation using doxygen." OFF)
 314 # if doxygen enable
 315 IF(GDCM_DOCUMENTATION)
 316   # Search Doxygen:
 317   FIND_PACKAGE(Doxygen)
 318   IF(DOXYGEN)
 319     SUBDIRS(Doc)
 320   ENDIF(DOXYGEN)
 321 ENDIF(GDCM_DOCUMENTATION)
 322
 323 #-----------------------------------------------------------------------------
 324 IF(WIN32)
 325   OPTION(GDCM_INSTALLER "Build the install setup using InnoSetup." OFF)
 326 ENDIF(WIN32)
 327 IF(UNIX)
 328   OPTION(GDCM_INSTALLER "Prepare the rpmBuild use." OFF)
 329 ENDIF(UNIX)
 330 IF(GDCM_INSTALLER)
 331   SUBDIRS(Builder)
 332 ENDIF(GDCM_INSTALLER)
 333
 334 # --------------------------------------------------------------------------
 335 # Configure the export configuration
 336
 337 SUBDIRS(CMake)
 338