CMakeLists.txt

   1 PROJECT(GDCM)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.0)
   3
   4 #MESSAGE("MATHIEU: ${CMAKE_VERSION_RELEASE}")
   5 #MESSAGE("MATHIEU: ${CMAKE_VERSION}")
   6 #MESSAGE("MATHIEU: ${CMAKE_CACHE_RELEASE_VERSION}")
   7 #IF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} EQUAL 2.0)
   8 #  IF(${CMAKE_CACHE_RELEASE_VERSION} EQUAL "patch 5")
   9 #    MESSAGE("MAHTIEU FOO")
  10 #  ENDIF(${CMAKE_CACHE_RELEASE_VERSION} EQUAL "patch 5")
  11 #ENDIF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} EQUAL 2.0)
  12
  13
  14 #-----------------------------------------------------------------------------
  15 # GDCM version number, usefull for packaging and doxygen doc:
  16 SET(GDCM_MAJOR_VERSION 0)
  17 SET(GDCM_MINOR_VERSION 7)
  18 SET(GDCM_BUILD_VERSION 0)
  19 SET(GDCM_VERSION
  20     "${GDCM_MAJOR_VERSION}.${GDCM_MINOR_VERSION}.${GDCM_BUILD_VERSION}")
  21
  22 #-----------------------------------------------------------------------------
  23 # datadir in CMake:
  24 SET(GDCM_DATA_DIR "/share/gdcm/" CACHE INTERNAL
  25   "Install location for data (relative to prefix).")
  26 MARK_AS_ADVANCED(GDCM_DATA_DIR)
  27
  28 #-----------------------------------------------------------------------------
  29 # Build shared lib by default
  30 OPTION(BUILD_SHARED_LIBS "Build GDCM with shared libraries." ON)
  31
  32 OPTION(GDCM_DEBUG "Turn verbosity of some statement ON." OFF)
  33 MARK_AS_ADVANCED(GDCM_DEBUG)
  34
  35 #-----------------------------------------------------------------------------
  36 SET (EXECUTABLE_OUTPUT_PATH ${GDCM_BINARY_DIR}/bin CACHE PATH "Single output directory for building all executables.")
  37 SET (LIBRARY_OUTPUT_PATH ${GDCM_BINARY_DIR}/bin CACHE PATH "Single output directory for building all libraries.")
  38 MARK_AS_ADVANCED(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
  39
  40 #-----------------------------------------------------------------------------
  41 # Test if compiler defines the pseudo-macro __FUNCTION__
  42 IF("GDCM_COMPILER_HAS_FUNCTION" MATCHES "^GDCM_COMPILER_HAS_FUNCTION$")
  43   MESSAGE(STATUS "Checking support for __FUNCTION__ in compiler")
  44   TRY_COMPILE(GDCM_COMPILER_HAS_FUNCTION
  45               ${GDCM_BINARY_DIR}/CMakeTmp/Function
  46               ${GDCM_SOURCE_DIR}/CMake/gdcmTestFUNCTION.cxx
  47               OUTPUT_VARIABLE OUTPUT)
  48   IF(GDCM_COMPILER_HAS_FUNCTION)
  49     MESSAGE(STATUS "Checking support for __FUNCTION__ -- yes")
  50     SET(GDCM_COMPILER_HAS_FUNCTION 1 CACHE INTERNAL "Support for extention C __FUNCTION__")
  51     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeOutput.log
  52       "Determining if the C compiler supports __FUNCTION__ "
  53       "passed with the following output:\n"
  54       "${OUTPUT}\n" APPEND)
  55   ELSE(GDCM_COMPILER_HAS_FUNCTION)
  56     MESSAGE(STATUS "Checking support for __FUNCTION__ -- no")
  57     SET(GDCM_COMPILER_HAS_FUNCTION 0 CACHE INTERNAL "Support for extension C __FUNCTION__")
  58     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeError.log
  59       "Determining if the C compiler supports __FUNCTION__ "
  60       "failed with the following output:\n"
  61       "${OUTPUT}\n" APPEND)
  62   ENDIF(GDCM_COMPILER_HAS_FUNCTION)
  63 ENDIF("GDCM_COMPILER_HAS_FUNCTION" MATCHES "^GDCM_COMPILER_HAS_FUNCTION$")
  64
  65 #-----------------------------------------------------------------------------
  66 # Test if os defines a lenght for sockaddr
  67 IF("HAVE_SA_LEN" MATCHES "^HAVE_SA_LEN$")
  68   STRING(ASCII 35 POUND)
  69   FILE(WRITE ${GDCM_BINARY_DIR}/CMakeTmp/gdcmTestHAVESALEN.c
  70     "${POUND}include <sys/types.h>\n"
  71     "${POUND}include <sys/socket.h>\n"
  72     "int main() { struct sockaddr sa; sa.sa_len = 0; }")
  73   MESSAGE(STATUS "Checking if ifreq has a sa_len")
  74   TRY_COMPILE(HAVE_SA_LEN
  75               ${GDCM_BINARY_DIR}
  76               ${GDCM_BINARY_DIR}/CMakeTmp/gdcmTestHAVESALEN.c
  77               OUTPUT_VARIABLE OUTPUT)
  78   IF(HAVE_SA_LEN)
  79     MESSAGE(STATUS "Checking if ifreq has a sa_len -- yes")
  80     SET(HAVE_SA_LEN 1 CACHE INTERNAL "Support if ifreq has a sa_len")
  81     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeOutput.log
  82       "Determining if ifreq has a sa_len"
  83       "passed with the following output:\n"
  84       "${OUTPUT}\n" APPEND)
  85   ELSE(HAVE_SA_LEN)
  86     MESSAGE(STATUS "Checking if ifreq has a sa_len -- no")
  87     SET(HAVE_SA_LEN 0 CACHE INTERNAL "Support if ifreq has a sa_len")
  88     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeError.log
  89       "Determining if ifreq has a sa_len"
  90       "failed with the following output:\n"
  91       "${OUTPUT}\n" APPEND)
  92   ENDIF(HAVE_SA_LEN)
  93 ENDIF("HAVE_SA_LEN" MATCHES "^HAVE_SA_LEN$")
  94
  95 #-----------------------------------------------------------------------------
  96 # Build directory on which many applications depend
  97 SUBDIRS(
  98   Dicts
  99   src
 100 )
 101 #-----------------------------------------------------------------------------
 102 # Example subdir:
 103
 104 OPTION(BUILD_EXAMPLES "Build GDCM examples." ON)
 105 IF(BUILD_EXAMPLES)
 106   SUBDIRS(Example)
 107 ENDIF(BUILD_EXAMPLES)
 108
 109 #-----------------------------------------------------------------------------
 110 # Adding GDCM_DATA_ROOT
 111 FIND_PATH(GDCM_DATA_ROOT gdcm-ACR-LibIDO.acr
 112   ${GDCM_SOURCE_DIR}/../gdcmData
 113   $ENV{GDCM_DATA}
 114   $ENV{PUB_DICT_PATH}/../../gdcmData
 115 )
 116
 117 # Set the place for the public dictionary, must be set before gdcmConfigure.h
 118 SET( GDCM_PUB_DICT_PATH "${CMAKE_INSTALL_PREFIX}${GDCM_DATA_DIR}")
 119
 120 #-----------------------------------------------------------------------------
 121 # SunOS + old gcc fixes:
 122 INCLUDE (${CMAKE_ROOT}/Modules/CMakeBackwardCompatibilityCXX.cmake)
 123 IF(CMAKE_NO_ANSI_STRING_STREAM)
 124   SET(GDCM_NO_ANSI_STRING_STREAM 1)
 125 ENDIF(CMAKE_NO_ANSI_STRING_STREAM)
 126 INCLUDE (${CMAKE_ROOT}/Modules/TestBigEndian.cmake)
 127 TEST_BIG_ENDIAN(GDCM_WORDS_BIGENDIAN)
 128
 129 INCLUDE (${CMAKE_ROOT}/Modules/CheckIncludeFile.cmake)
 130 CHECK_INCLUDE_FILE("stdint.h"       CMAKE_HAVE_STDINT_H)
 131 CHECK_INCLUDE_FILE("inttypes.h"     CMAKE_HAVE_INTTYPES_H)
 132
 133 # Check if header file exists and add it to the list.
 134 INCLUDE (${CMAKE_ROOT}/Modules/CheckIncludeFiles.cmake)
 135 MACRO(CHECK_INCLUDE_FILE_CONCAT FILE VARIABLE)
 136   CHECK_INCLUDE_FILES("${GDCM_INCLUDES};${FILE}" ${VARIABLE})
 137   IF(${VARIABLE})
 138     SET(GDCM_INCLUDES ${GDCM_INCLUDES} ${FILE})
 139   ENDIF(${VARIABLE})
 140 ENDMACRO(CHECK_INCLUDE_FILE_CONCAT)
 141
 142 # Need those header for GetMacAddress in Util
 143 # This is tricky as you need to figure out the proper order to
 144 # test the inclusion of files
 145 CHECK_INCLUDE_FILE_CONCAT("unistd.h"       CMAKE_HAVE_UNISTD_H)
 146 CHECK_INCLUDE_FILE_CONCAT("stdlib.h"       CMAKE_HAVE_STDLIB_H)
 147 CHECK_INCLUDE_FILE_CONCAT("sys/ioctl.h"    CMAKE_HAVE_SYS_IOCTL_H)
 148 CHECK_INCLUDE_FILE_CONCAT("sys/socket.h"   CMAKE_HAVE_SYS_SOCKET_H)
 149 CHECK_INCLUDE_FILE_CONCAT("sys/sockio.h"   CMAKE_HAVE_SYS_SOCKIO_H)
 150 CHECK_INCLUDE_FILE_CONCAT("net/if.h"       CMAKE_HAVE_NET_IF_H)
 151 CHECK_INCLUDE_FILE_CONCAT("netinet/in.h"   CMAKE_HAVE_NETINET_IN_H)
 152 CHECK_INCLUDE_FILE_CONCAT("net/if_dl.h"    CMAKE_HAVE_NET_IF_DL_H)
 153 CHECK_INCLUDE_FILE_CONCAT("net/if_arp.h"   CMAKE_HAVE_NET_IF_ARP_H)
 154
 155 CONFIGURE_FILE(${GDCM_SOURCE_DIR}/gdcmConfigure.h.in
 156                ${GDCM_BINARY_DIR}/gdcmConfigure.h @ONLY IMMEDIATE)
 157
 158 INSTALL_FILES(/include .h gdcmConfigure.h)
 159
 160 #-----------------------------------------------------------------------------
 161 # Add the testing directories
 162 OPTION(BUILD_TESTING "Build testing." ON)
 163
 164 IF(BUILD_TESTING)
 165   ENABLE_TESTING()
 166   INCLUDE (${CMAKE_ROOT}/Modules/Dart.cmake)
 167   MARK_AS_ADVANCED(DART_ROOT)
 168   SUBDIRS(Testing)
 169 ENDIF(BUILD_TESTING)
 170
 171
 172 #-----------------------------------------------------------------------------
 173 OPTION(GDCM_VTK "Build VTK-GDCM Lib." OFF)
 174 IF(GDCM_VTK)
 175   # Search VTK
 176   FIND_PACKAGE(VTK)
 177   # If vtk found
 178   IF(VTK_FOUND)
 179     #INCLUDE(${VTK_USE_FILE})
 180     SUBDIRS(vtk)
 181   ENDIF(VTK_FOUND)
 182 ENDIF(GDCM_VTK)
 183
 184 #-----------------------------------------------------------------------------
 185 OPTION(GDCM_WRAP_PYTHON "Wrap GDCM classes into the Python language." OFF)
 186 #if wrapping enable
 187 IF(GDCM_WRAP_PYTHON)
 188   # Search Python libs:
 189   FIND_PACKAGE(PythonLibs)
 190   # If PythonLibs found
 191   IF(PYTHON_LIBRARY)
 192     SUBDIRS(gdcmPython)
 193   ENDIF(PYTHON_LIBRARY)
 194 ENDIF(GDCM_WRAP_PYTHON)
 195
 196 #-----------------------------------------------------------------------------
 197 OPTION(GDCM_DOCUMENTATION "Build source documentation using doxygen." OFF)
 198 # if doxygen enable
 199 IF(GDCM_DOCUMENTATION)
 200   # Search Doxygen:
 201   FIND_PACKAGE(Doxygen)
 202   IF(DOXYGEN)
 203     SUBDIRS(Doc)
 204   ENDIF(DOXYGEN)
 205 ENDIF(GDCM_DOCUMENTATION)
 206