CMakeLists.txt

   1 PROJECT(GDCM)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.0)
   3 # okay in fact you need at least cmake 2.0.4 to get swig working properly
   4 # and you cannot use cmake 2.0.6 out of the box due to a bug (patched in debian package)
   5
   6 #-----------------------------------------------------------------------------
   7 # GDCM version number, usefull for packaging and doxygen doc:
   8 SET(GDCM_MAJOR_VERSION 1)
   9 SET(GDCM_MINOR_VERSION 3)
  10 SET(GDCM_BUILD_VERSION 1)
  11 SET(GDCM_VERSION
  12     "${GDCM_MAJOR_VERSION}.${GDCM_MINOR_VERSION}.${GDCM_BUILD_VERSION}")
  13
  14 #-----------------------------------------------------------------------------
  15 # datadir in CMake:
  16 SET(GDCM_DATA_DIR "/share/gdcm/" CACHE INTERNAL
  17   "Install location for data (relative to prefix).")
  18 MARK_AS_ADVANCED(GDCM_DATA_DIR)
  19
  20 #-----------------------------------------------------------------------------
  21 # Provide compatibility options.
  22 OPTION(GDCM_LEGACY_REMOVE "Remove all legacy code completely." OFF)
  23 OPTION(GDCM_LEGACY_SILENT "Silence all legacy code messages." OFF)
  24 MARK_AS_ADVANCED(GDCM_LEGACY_REMOVE GDCM_LEGACY_SILENT)
  25
  26 #-----------------------------------------------------------------------------
  27 # Build shared lib by default
  28 OPTION(BUILD_SHARED_LIBS "Build GDCM with shared libraries." ON)
  29
  30 SET(GDCM_CMAKE_DIR "${GDCM_SOURCE_DIR}/Utilities/CMake")
  31 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${GDCM_CMAKE_DIR}")
  32
  33 SET(GDCM_CONFIGURATION_TYPES ${CMAKE_CONFIGURATION_TYPES})
  34
  35 OPTION(GDCM_DEBUG "Turn verbosity of some statement ON." OFF)
  36 MARK_AS_ADVANCED(GDCM_DEBUG)
  37
  38 # --------------------------------------------------------------------------
  39 # Install directories
  40
  41 IF(NOT GDCM_INSTALL_BIN_DIR)
  42   SET(GDCM_INSTALL_BIN_DIR "/bin")
  43 ENDIF(NOT GDCM_INSTALL_BIN_DIR)
  44
  45 IF(NOT GDCM_INSTALL_LIB_DIR)
  46   SET(GDCM_INSTALL_LIB_DIR "/lib/${PROJECT_NAME}")
  47 ENDIF(NOT GDCM_INSTALL_LIB_DIR)
  48
  49 IF(NOT GDCM_INSTALL_DATA_DIR)
  50   SET(GDCM_INSTALL_DATA_DIR "/share/${PROJECT_NAME}")
  51 ENDIF(NOT GDCM_INSTALL_DATA_DIR)
  52
  53 IF(NOT GDCM_INSTALL_INCLUDE_DIR)
  54   SET(GDCM_INSTALL_INCLUDE_DIR "/include/${PROJECT_NAME}")
  55 ENDIF(NOT GDCM_INSTALL_INCLUDE_DIR)
  56
  57 IF(NOT GDCM_INSTALL_PACKAGE_DIR)
  58   SET(GDCM_INSTALL_PACKAGE_DIR ${GDCM_INSTALL_LIB_DIR})
  59 ENDIF(NOT GDCM_INSTALL_PACKAGE_DIR)
  60
  61 IF(NOT GDCM_VTK_INSTALL_PACKAGE_DIR)
  62   SET(GDCM_VTK_INSTALL_PACKAGE_DIR ${VTK_INSTALL_PACKAGE_DIR})
  63 ENDIF(NOT GDCM_VTK_INSTALL_PACKAGE_DIR)
  64
  65 IF(NOT GDCM_INSTALL_NO_DEVELOPMENT)
  66   SET(GDCM_INSTALL_NO_DEVELOPMENT 0)
  67 ENDIF(NOT GDCM_INSTALL_NO_DEVELOPMENT)
  68
  69 IF(NOT GDCM_INSTALL_NO_RUNTIME)
  70   SET(GDCM_INSTALL_NO_RUNTIME 0)
  71 ENDIF(NOT GDCM_INSTALL_NO_RUNTIME)
  72
  73 IF(NOT GDCM_INSTALL_NO_DOCUMENTATION)
  74   SET(GDCM_INSTALL_NO_DOCUMENTATION 0)
  75 ENDIF(NOT GDCM_INSTALL_NO_DOCUMENTATION)
  76
  77 SET(GDCM_INSTALL_NO_LIBRARIES)
  78 IF(GDCM_BUILD_SHARED_LIBS)
  79   IF(GDCM_INSTALL_NO_RUNTIME AND GDCM_INSTALL_NO_DEVELOPMENT)
  80     SET(GDCM_INSTALL_NO_LIBRARIES 1)
  81   ENDIF(GDCM_INSTALL_NO_RUNTIME AND GDCM_INSTALL_NO_DEVELOPMENT)
  82 ELSE(GDCM_BUILD_SHARED_LIBS)
  83   IF(GDCM_INSTALL_NO_DEVELOPMENT)
  84     SET(GDCM_INSTALL_NO_LIBRARIES 1)
  85   ENDIF(GDCM_INSTALL_NO_DEVELOPMENT)
  86 ENDIF(GDCM_BUILD_SHARED_LIBS)
  87
  88 #-----------------------------------------------------------------------------
  89 SET (EXECUTABLE_OUTPUT_PATH ${GDCM_BINARY_DIR}/bin CACHE PATH "Single output directory for building all executables.")
  90 SET (LIBRARY_OUTPUT_PATH ${GDCM_BINARY_DIR}/bin CACHE PATH "Single output directory for building all libraries.")
  91 MARK_AS_ADVANCED(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
  92
  93
  94 #-----------------------------------------------------------------------------
  95 # Test if compiler defines the pseudo-macro __FUNCTION__
  96 IF("GDCM_COMPILER_HAS_FUNCTION" MATCHES "^GDCM_COMPILER_HAS_FUNCTION$")
  97   MESSAGE(STATUS "Checking support for __FUNCTION__ in compiler")
  98   TRY_COMPILE(GDCM_COMPILER_HAS_FUNCTION
  99               ${GDCM_BINARY_DIR}/CMakeTmp/Function
 100               ${GDCM_SOURCE_DIR}/CMake/gdcmTestFUNCTION.cxx
 101               OUTPUT_VARIABLE OUTPUT)
 102   IF(GDCM_COMPILER_HAS_FUNCTION)
 103     MESSAGE(STATUS "Checking support for __FUNCTION__ -- yes")
 104     SET(GDCM_COMPILER_HAS_FUNCTION 1 CACHE INTERNAL "Support for extension C __FUNCTION__")
 105     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeOutput.log
 106       "Determining if the C compiler supports __FUNCTION__ "
 107       "passed with the following output:\n"
 108       "${OUTPUT}\n" APPEND)
 109   ELSE(GDCM_COMPILER_HAS_FUNCTION)
 110     MESSAGE(STATUS "Checking support for __FUNCTION__ -- no")
 111     SET(GDCM_COMPILER_HAS_FUNCTION 0 CACHE INTERNAL "Support for extension C __FUNCTION__")
 112     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeError.log
 113       "Determining if the C compiler supports __FUNCTION__ "
 114       "failed with the following output:\n"
 115       "${OUTPUT}\n" APPEND)
 116   ENDIF(GDCM_COMPILER_HAS_FUNCTION)
 117 ENDIF("GDCM_COMPILER_HAS_FUNCTION" MATCHES "^GDCM_COMPILER_HAS_FUNCTION$")
 118
 119 #-----------------------------------------------------------------------------
 120 # Test is compiler support istringstream
 121 IF("GDCM_TEST_ISTRINGSTREAM" MATCHES "^GDCM_TEST_ISTRINGSTREAM$")
 122   MESSAGE(STATUS "Checking istringstream")
 123   TRY_RUN(GDCM_TEST_ISTRINGSTREAM GDCM_TEST_ISTRINGSTREAM_COMPILED
 124           ${GDCM_BINARY_DIR}/CMakeTmp/
 125           ${GDCM_SOURCE_DIR}/CMake/gdcmTestIstringStream.cxx)
 126   IF(GDCM_TEST_ISTRINGSTREAM_COMPILED)
 127     IF(GDCM_TEST_ISTRINGSTREAM)
 128       MESSAGE(STATUS "Checking istringstream works -- yes")
 129       SET(GDCM_TEST_ISTRINGSTREAM 1 CACHE INTERNAL "Whether istringstream works.")
 130     ELSE(GDCM_TEST_ISTRINGSTREAM)
 131       MESSAGE(STATUS "Checking istringstream works -- no")
 132       SET(GDCM_TEST_ISTRINGSTREAM 0 CACHE INTERNAL "Whether istringstream works.")
 133     ENDIF(GDCM_TEST_ISTRINGSTREAM)
 134   ELSE(GDCM_TEST_ISTRINGSTREAM_COMPILED)
 135     MESSAGE(STATUS "Checking istringstream -- failed")
 136   ENDIF(GDCM_TEST_ISTRINGSTREAM_COMPILED)
 137 ENDIF("GDCM_TEST_ISTRINGSTREAM" MATCHES "^GDCM_TEST_ISTRINGSTREAM$")
 138
 139 #-----------------------------------------------------------------------------
 140 # Build directory on which many applications depend
 141 SUBDIRS(
 142   Dicts
 143   src
 144 )
 145 #-----------------------------------------------------------------------------
 146 # Example subdir:
 147
 148 OPTION(BUILD_EXAMPLES "Build GDCM examples." ON)
 149 IF(BUILD_EXAMPLES)
 150   SUBDIRS(Example)
 151 ENDIF(BUILD_EXAMPLES)
 152
 153 #-----------------------------------------------------------------------------
 154 # Adding GDCM_DATA_ROOT
 155 FIND_PATH(GDCM_DATA_ROOT gdcm-ACR-LibIDO.acr
 156   ${GDCM_SOURCE_DIR}/../gdcmData
 157   $ENV{GDCM_DATA}
 158   $ENV{PUB_DICT_PATH}/../../gdcmData
 159 )
 160
 161 # Set the place for the public dictionary, must be set before gdcmConfigure.h
 162 #SET( GDCM_PUB_DICT_PATH "${CMAKE_INSTALL_PREFIX}${GDCM_DATA_DIR}")
 163 FIND_PATH(GDCM_PUB_DICT_PATH dicomV3.dic
 164   ${GDCM_SOURCE_DIR}/Dicts
 165   $ENV{PUB_DICT_PATH}
 166 )
 167
 168 #-----------------------------------------------------------------------------
 169 # SunOS + old gcc fixes:
 170 INCLUDE (${CMAKE_ROOT}/Modules/CMakeBackwardCompatibilityCXX.cmake)
 171 IF(CMAKE_NO_ANSI_STRING_STREAM)
 172   SET(GDCM_NO_ANSI_STRING_STREAM 1)
 173 ENDIF(CMAKE_NO_ANSI_STRING_STREAM)
 174
 175 # Big endian thing:
 176 INCLUDE (${CMAKE_ROOT}/Modules/TestBigEndian.cmake)
 177 TEST_BIG_ENDIAN(GDCM_WORDS_BIGENDIAN)
 178
 179 INCLUDE (${CMAKE_ROOT}/Modules/CheckIncludeFile.cmake)
 180 CHECK_INCLUDE_FILE("stdint.h"       CMAKE_HAVE_STDINT_H)
 181 IF(UNIX) #Avoid polluting Win32 cmakecache
 182   CHECK_INCLUDE_FILE("inttypes.h"     CMAKE_HAVE_INTTYPES_H)
 183 ENDIF(UNIX)
 184 # Special Time support, two convention: *NIX vs Win32
 185 CHECK_INCLUDE_FILE("sys/times.h"     CMAKE_HAVE_SYS_TIMES_H)
 186 CHECK_INCLUDE_FILE("sys/timeb.h"     CMAKE_HAVE_SYS_TIMEB_H)
 187
 188 # Check if header file exists and add it to the list.
 189 INCLUDE (${CMAKE_ROOT}/Modules/CheckIncludeFiles.cmake)
 190 MACRO(CHECK_INCLUDE_FILE_CONCAT FILE VARIABLE)
 191   CHECK_INCLUDE_FILES("${GDCM_INCLUDES};${FILE}" ${VARIABLE})
 192   IF(${VARIABLE})
 193     SET(GDCM_INCLUDES ${GDCM_INCLUDES} ${FILE})
 194   ENDIF(${VARIABLE})
 195 ENDMACRO(CHECK_INCLUDE_FILE_CONCAT)
 196
 197 # Need those header for GetMacAddress in Util
 198 # This is tricky as you need to figure out the proper order to
 199 # test the inclusion of files
 200 CHECK_INCLUDE_FILE_CONCAT("unistd.h"       CMAKE_HAVE_UNISTD_H)
 201 CHECK_INCLUDE_FILE_CONCAT("stdlib.h"       CMAKE_HAVE_STDLIB_H)
 202 IF(UNIX) #Avoid polluting Win32 cmakecache
 203   CHECK_INCLUDE_FILE_CONCAT("sys/ioctl.h"    CMAKE_HAVE_SYS_IOCTL_H)
 204   CHECK_INCLUDE_FILE_CONCAT("sys/socket.h"   CMAKE_HAVE_SYS_SOCKET_H)
 205   CHECK_INCLUDE_FILE_CONCAT("sys/sockio.h"   CMAKE_HAVE_SYS_SOCKIO_H)
 206   CHECK_INCLUDE_FILE_CONCAT("net/if.h"       CMAKE_HAVE_NET_IF_H)
 207   CHECK_INCLUDE_FILE_CONCAT("netinet/in.h"   CMAKE_HAVE_NETINET_IN_H)
 208   CHECK_INCLUDE_FILE_CONCAT("net/if_dl.h"    CMAKE_HAVE_NET_IF_DL_H)
 209   CHECK_INCLUDE_FILE_CONCAT("net/if_arp.h"   CMAKE_HAVE_NET_IF_ARP_H)
 210 ENDIF(UNIX)
 211
 212 #-----------------------------------------------------------------------------
 213 # Test if os defines a length for sockaddr
 214 # only doing the test when we have sys/socket
 215 IF( ${CMAKE_HAVE_SYS_SOCKET_H} )
 216   IF("HAVE_SA_LEN" MATCHES "^HAVE_SA_LEN$")
 217     STRING(ASCII 35 POUND)
 218     FILE(WRITE ${GDCM_BINARY_DIR}/CMakeTmp/gdcmTestHAVESALEN.c
 219       "${POUND}include <sys/types.h>\n"
 220       "${POUND}include <sys/socket.h>\n"
 221       "int main() { struct sockaddr sa; sa.sa_len = 0; }\n")
 222     MESSAGE(STATUS "Checking if ifreq has a sa_len")
 223     TRY_COMPILE(HAVE_SA_LEN
 224       ${GDCM_BINARY_DIR}
 225       ${GDCM_BINARY_DIR}/CMakeTmp/gdcmTestHAVESALEN.c
 226       OUTPUT_VARIABLE OUTPUT)
 227     IF(HAVE_SA_LEN)
 228       MESSAGE(STATUS "Checking if ifreq has a sa_len -- yes")
 229       SET(HAVE_SA_LEN 1 CACHE INTERNAL "Support if ifreq has a sa_len")
 230       WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeOutput.log
 231         "Determining if ifreq has a sa_len"
 232         "passed with the following output:\n"
 233         "${OUTPUT}\n" APPEND)
 234     ELSE(HAVE_SA_LEN)
 235       MESSAGE(STATUS "Checking if ifreq has a sa_len -- no")
 236       SET(HAVE_SA_LEN 0 CACHE INTERNAL "Support if ifreq has a sa_len")
 237       WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeError.log
 238         "Determining if ifreq has a sa_len"
 239         "failed with the following output:\n"
 240         "${OUTPUT}\n" APPEND)
 241     ENDIF(HAVE_SA_LEN)
 242   ENDIF("HAVE_SA_LEN" MATCHES "^HAVE_SA_LEN$")
 243 ENDIF( ${CMAKE_HAVE_SYS_SOCKET_H} )
 244
 245 #-----------------------------------------------------------------------------
 246 # Force Big Endian emulation on little endian:
 247 OPTION(GDCM_FORCE_BIGENDIAN_EMULATION "Force Big Endian Emulation. Do use if you don't know what you are doing." OFF)
 248
 249 CONFIGURE_FILE(${GDCM_SOURCE_DIR}/gdcmConfigure.h.in
 250                ${GDCM_BINARY_DIR}/gdcmConfigure.h @ONLY IMMEDIATE)
 251
 252 INSTALL_FILES(/include/gdcm .h gdcmConfigure.h)
 253
 254 #-----------------------------------------------------------------------------
 255 # Add the testing directories
 256 OPTION(BUILD_TESTING "Build testing." ON)
 257
 258 IF(BUILD_TESTING)
 259   CONFIGURE_FILE(${GDCM_SOURCE_DIR}/CMake/CTestCustom.ctest.in
 260       ${GDCM_BINARY_DIR}/CMake/CTestCustom.ctest @ONLY)
 261   ENABLE_TESTING()
 262   INCLUDE (${CMAKE_ROOT}/Modules/Dart.cmake)
 263   MARK_AS_ADVANCED(DART_ROOT)
 264   SUBDIRS(Testing)
 265 ENDIF(BUILD_TESTING)
 266
 267
 268 #-----------------------------------------------------------------------------
 269 OPTION(GDCM_VTK "Build VTK-GDCM Lib." OFF)
 270 IF(GDCM_VTK)
 271   # Search VTK
 272   FIND_PACKAGE(VTK)
 273   # If vtk found
 274   IF(VTK_FOUND)
 275     #INCLUDE(${VTK_USE_FILE})
 276     SUBDIRS(vtk)
 277   ENDIF(VTK_FOUND)
 278 ENDIF(GDCM_VTK)
 279
 280 #-----------------------------------------------------------------------------
 281 OPTION(GDCM_WRAP_PYTHON "Wrap GDCM classes into the Python language." OFF)
 282 #if wrapping enable
 283 IF(GDCM_WRAP_PYTHON)
 284   # Search Python libs:
 285   FIND_PACKAGE(PythonLibs)
 286   # If PythonLibs found
 287   IF(PYTHON_LIBRARY)
 288     SUBDIRS(gdcmPython)
 289   ENDIF(PYTHON_LIBRARY)
 290 ENDIF(GDCM_WRAP_PYTHON)
 291
 292 #-----------------------------------------------------------------------------
 293 OPTION(GDCM_DOCUMENTATION "Build source documentation using doxygen." OFF)
 294 # if doxygen enable
 295 IF(GDCM_DOCUMENTATION)
 296   # Search Doxygen:
 297   FIND_PACKAGE(Doxygen)
 298   IF(DOXYGEN)
 299     SUBDIRS(Doc)
 300   ENDIF(DOXYGEN)
 301 ENDIF(GDCM_DOCUMENTATION)
 302
 303 #-----------------------------------------------------------------------------
 304 IF(WIN32)
 305   OPTION(GDCM_INSTALLER "Build the install setup using InnoSetup." OFF)
 306 ENDIF(WIN32)
 307 IF(UNIX)
 308   OPTION(GDCM_INSTALLER "Prepare the rpmBuild use." OFF)
 309 ENDIF(UNIX)
 310 IF(GDCM_INSTALLER)
 311   SUBDIRS(Builder)
 312 ENDIF(GDCM_INSTALLER)
 313
 314 # --------------------------------------------------------------------------
 315 # Configure the export configuration
 316
 317 SUBDIRS(CMake)
 318