CMakeLists.txt

   1 PROJECT(GDCM)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.0)
   3
   4 #-----------------------------------------------------------------------------
   5 # GDCM version number, usefull for packaging and doxygen doc:
   6 SET(GDCM_MAJOR_VERSION 1)
   7 SET(GDCM_MINOR_VERSION 0)
   8 SET(GDCM_BUILD_VERSION 1)
   9 SET(GDCM_VERSION
  10     "${GDCM_MAJOR_VERSION}.${GDCM_MINOR_VERSION}.${GDCM_BUILD_VERSION}")
  11
  12 #-----------------------------------------------------------------------------
  13 # datadir in CMake:
  14 SET(GDCM_DATA_DIR "/share/gdcm/" CACHE INTERNAL
  15   "Install location for data (relative to prefix).")
  16 MARK_AS_ADVANCED(GDCM_DATA_DIR)
  17
  18 #-----------------------------------------------------------------------------
  19 # Build shared lib by default
  20 OPTION(GDCM_BUILD_SHARED_LIBS "Build GDCM with shared libraries." ON)
  21 SET(BUILD_SHARED_LIBS ${GDCM_BUILD_SHARED_LIBS})
  22
  23 OPTION(GDCM_DEBUG "Turn verbosity of some statement ON." OFF)
  24 MARK_AS_ADVANCED(GDCM_DEBUG)
  25
  26 #-----------------------------------------------------------------------------
  27 SET (EXECUTABLE_OUTPUT_PATH ${GDCM_BINARY_DIR}/bin CACHE PATH "Single output directory for building all executables.")
  28 SET (LIBRARY_OUTPUT_PATH ${GDCM_BINARY_DIR}/bin CACHE PATH "Single output directory for building all libraries.")
  29 MARK_AS_ADVANCED(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
  30
  31 #-----------------------------------------------------------------------------
  32 # Help outside projects link against gdcm
  33
  34 EXPORT_LIBRARY_DEPENDENCIES(${GDCM_BINARY_DIR}/GDCMLibraryDepends.cmake)
  35
  36 # Save the compiler settings so another project can import them.
  37 INCLUDE(${CMAKE_ROOT}/Modules/CMakeExportBuildSettings.cmake)
  38 CMAKE_EXPORT_BUILD_SETTINGS(${GDCM_BINARY_DIR}/GDCMBuildSettings.cmake)
  39 #INSTALL_FILES(/lib/gdcm .cmake GDCMBuildSettings)
  40
  41 # For GDCM from build tree:
  42 SET(GDCM_USE_FILE ${GDCM_SOURCE_DIR}/GDCMUse.cmake)
  43 SET(GDCM_INCLUDE_DIRS
  44   ${GDCM_BINARY_DIR}/     #for gdcmConfigure.h
  45   ${GDCM_SOURCE_DIR}/src  #for main gdcm include
  46   )
  47 SET(GDCM_LIBRARY_DIRS ${LIBRARY_OUTPUT_PATH})
  48 SET(GDCM_LIBRARY_DEPENDS_FILE ${GDCM_BINARY_DIR}/GDCMLibraryDepends.cmake)
  49 CONFIGURE_FILE(${GDCM_SOURCE_DIR}/GDCMConfig.cmake.in
  50                ${GDCM_BINARY_DIR}/GDCMConfig.cmake @ONLY IMMEDIATE)
  51
  52 # For installed GDCM:
  53 SET(GDCM_USE_FILE ${CMAKE_INSTALL_PREFIX}/lib/GDCM-${GDCM_VERSION}/GDCMUse.cmake)
  54 SET(GDCM_INCLUDE_DIRS ${CMAKE_INSTALL_PREFIX}/include/GDCM-${GDCM_VERSION})
  55 SET(GDCM_LIBRARY_DIRS ${CMAKE_INSTALL_PREFIX}/lib/ExodusII-${GDCM_VERSION})
  56 SET(GDCM_LIBRARY_DEPENDS_FILE ${CMAKE_INSTALL_PREFIX}/lib/GDCM-${GDCM_VERSION}/GDCMLibraryDepends.cmake)
  57 CONFIGURE_FILE(${GDCM_SOURCE_DIR}/GDCMConfig.cmake.in
  58                ${GDCM_BINARY_DIR}/Utilities/GDCMConfig.cmake @ONLY IMMEDIATE)
  59
  60 #-----------------------------------------------------------------------------
  61 # Test if compiler defines the pseudo-macro __FUNCTION__
  62 IF("GDCM_COMPILER_HAS_FUNCTION" MATCHES "^GDCM_COMPILER_HAS_FUNCTION$")
  63   MESSAGE(STATUS "Checking support for __FUNCTION__ in compiler")
  64   TRY_COMPILE(GDCM_COMPILER_HAS_FUNCTION
  65               ${GDCM_BINARY_DIR}/CMakeTmp/Function
  66               ${GDCM_SOURCE_DIR}/CMake/gdcmTestFUNCTION.cxx
  67               OUTPUT_VARIABLE OUTPUT)
  68   IF(GDCM_COMPILER_HAS_FUNCTION)
  69     MESSAGE(STATUS "Checking support for __FUNCTION__ -- yes")
  70     SET(GDCM_COMPILER_HAS_FUNCTION 1 CACHE INTERNAL "Support for extension C __FUNCTION__")
  71     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeOutput.log
  72       "Determining if the C compiler supports __FUNCTION__ "
  73       "passed with the following output:\n"
  74       "${OUTPUT}\n" APPEND)
  75   ELSE(GDCM_COMPILER_HAS_FUNCTION)
  76     MESSAGE(STATUS "Checking support for __FUNCTION__ -- no")
  77     SET(GDCM_COMPILER_HAS_FUNCTION 0 CACHE INTERNAL "Support for extension C __FUNCTION__")
  78     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeError.log
  79       "Determining if the C compiler supports __FUNCTION__ "
  80       "failed with the following output:\n"
  81       "${OUTPUT}\n" APPEND)
  82   ENDIF(GDCM_COMPILER_HAS_FUNCTION)
  83 ENDIF("GDCM_COMPILER_HAS_FUNCTION" MATCHES "^GDCM_COMPILER_HAS_FUNCTION$")
  84
  85 #-----------------------------------------------------------------------------
  86 # Test if os defines a lenght for sockaddr
  87 IF("HAVE_SA_LEN" MATCHES "^HAVE_SA_LEN$")
  88   STRING(ASCII 35 POUND)
  89   FILE(WRITE ${GDCM_BINARY_DIR}/CMakeTmp/gdcmTestHAVESALEN.c
  90     "${POUND}include <sys/types.h>\n"
  91     "${POUND}include <sys/socket.h>\n"
  92     "int main() { struct sockaddr sa; sa.sa_len = 0; }")
  93   MESSAGE(STATUS "Checking if ifreq has a sa_len")
  94   TRY_COMPILE(HAVE_SA_LEN
  95               ${GDCM_BINARY_DIR}
  96               ${GDCM_BINARY_DIR}/CMakeTmp/gdcmTestHAVESALEN.c
  97               OUTPUT_VARIABLE OUTPUT)
  98   IF(HAVE_SA_LEN)
  99     MESSAGE(STATUS "Checking if ifreq has a sa_len -- yes")
 100     SET(HAVE_SA_LEN 1 CACHE INTERNAL "Support if ifreq has a sa_len")
 101     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeOutput.log
 102       "Determining if ifreq has a sa_len"
 103       "passed with the following output:\n"
 104       "${OUTPUT}\n" APPEND)
 105   ELSE(HAVE_SA_LEN)
 106     MESSAGE(STATUS "Checking if ifreq has a sa_len -- no")
 107     SET(HAVE_SA_LEN 0 CACHE INTERNAL "Support if ifreq has a sa_len")
 108     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeError.log
 109       "Determining if ifreq has a sa_len"
 110       "failed with the following output:\n"
 111       "${OUTPUT}\n" APPEND)
 112   ENDIF(HAVE_SA_LEN)
 113 ENDIF("HAVE_SA_LEN" MATCHES "^HAVE_SA_LEN$")
 114
 115 #-----------------------------------------------------------------------------
 116 # Build directory on which many applications depend
 117 SUBDIRS(
 118   Dicts
 119   src
 120 )
 121 #-----------------------------------------------------------------------------
 122 # Example subdir:
 123
 124 OPTION(BUILD_EXAMPLES "Build GDCM examples." ON)
 125 IF(BUILD_EXAMPLES)
 126   SUBDIRS(Example)
 127 ENDIF(BUILD_EXAMPLES)
 128
 129 #-----------------------------------------------------------------------------
 130 # Adding GDCM_DATA_ROOT
 131 FIND_PATH(GDCM_DATA_ROOT gdcm-ACR-LibIDO.acr
 132   ${GDCM_SOURCE_DIR}/../gdcmData
 133   $ENV{GDCM_DATA}
 134   $ENV{PUB_DICT_PATH}/../../gdcmData
 135 )
 136
 137 # Set the place for the public dictionary, must be set before gdcmConfigure.h
 138 #SET( GDCM_PUB_DICT_PATH "${CMAKE_INSTALL_PREFIX}${GDCM_DATA_DIR}")
 139 FIND_PATH(GDCM_PUB_DICT_PATH dicomV3.dic
 140   ${GDCM_SOURCE_DIR}/Dicts
 141   $ENV{PUB_DICT_PATH}
 142 )
 143
 144 #-----------------------------------------------------------------------------
 145 # SunOS + old gcc fixes:
 146 INCLUDE (${CMAKE_ROOT}/Modules/CMakeBackwardCompatibilityCXX.cmake)
 147 IF(CMAKE_NO_ANSI_STRING_STREAM)
 148   SET(GDCM_NO_ANSI_STRING_STREAM 1)
 149 ENDIF(CMAKE_NO_ANSI_STRING_STREAM)
 150 INCLUDE (${CMAKE_ROOT}/Modules/TestBigEndian.cmake)
 151 TEST_BIG_ENDIAN(GDCM_WORDS_BIGENDIAN)
 152
 153 INCLUDE (${CMAKE_ROOT}/Modules/CheckIncludeFile.cmake)
 154 CHECK_INCLUDE_FILE("stdint.h"       CMAKE_HAVE_STDINT_H)
 155 CHECK_INCLUDE_FILE("inttypes.h"     CMAKE_HAVE_INTTYPES_H)
 156
 157 # Check if header file exists and add it to the list.
 158 INCLUDE (${CMAKE_ROOT}/Modules/CheckIncludeFiles.cmake)
 159 MACRO(CHECK_INCLUDE_FILE_CONCAT FILE VARIABLE)
 160   CHECK_INCLUDE_FILES("${GDCM_INCLUDES};${FILE}" ${VARIABLE})
 161   IF(${VARIABLE})
 162     SET(GDCM_INCLUDES ${GDCM_INCLUDES} ${FILE})
 163   ENDIF(${VARIABLE})
 164 ENDMACRO(CHECK_INCLUDE_FILE_CONCAT)
 165
 166 # Need those header for GetMacAddress in Util
 167 # This is tricky as you need to figure out the proper order to
 168 # test the inclusion of files
 169 CHECK_INCLUDE_FILE_CONCAT("unistd.h"       CMAKE_HAVE_UNISTD_H)
 170 CHECK_INCLUDE_FILE_CONCAT("stdlib.h"       CMAKE_HAVE_STDLIB_H)
 171 CHECK_INCLUDE_FILE_CONCAT("sys/ioctl.h"    CMAKE_HAVE_SYS_IOCTL_H)
 172 CHECK_INCLUDE_FILE_CONCAT("sys/socket.h"   CMAKE_HAVE_SYS_SOCKET_H)
 173 CHECK_INCLUDE_FILE_CONCAT("sys/sockio.h"   CMAKE_HAVE_SYS_SOCKIO_H)
 174 CHECK_INCLUDE_FILE_CONCAT("net/if.h"       CMAKE_HAVE_NET_IF_H)
 175 CHECK_INCLUDE_FILE_CONCAT("netinet/in.h"   CMAKE_HAVE_NETINET_IN_H)
 176 CHECK_INCLUDE_FILE_CONCAT("net/if_dl.h"    CMAKE_HAVE_NET_IF_DL_H)
 177 CHECK_INCLUDE_FILE_CONCAT("net/if_arp.h"   CMAKE_HAVE_NET_IF_ARP_H)
 178
 179 #-----------------------------------------------------------------------------
 180 # Force Big Endian emulation on little endian:
 181 OPTION(GDCM_FORCE_BIGENDIAN_EMULATION "Force Big Endian Emulation. Do use if you don't know what you are doing." OFF)
 182
 183 CONFIGURE_FILE(${GDCM_SOURCE_DIR}/gdcmConfigure.h.in
 184                ${GDCM_BINARY_DIR}/gdcmConfigure.h @ONLY IMMEDIATE)
 185
 186 INSTALL_FILES(/include .h gdcmConfigure.h)
 187
 188 #-----------------------------------------------------------------------------
 189 # Add the testing directories
 190 OPTION(BUILD_TESTING "Build testing." ON)
 191
 192 IF(BUILD_TESTING)
 193   ENABLE_TESTING()
 194   INCLUDE (${CMAKE_ROOT}/Modules/Dart.cmake)
 195   MARK_AS_ADVANCED(DART_ROOT)
 196   SUBDIRS(Testing)
 197 ENDIF(BUILD_TESTING)
 198
 199
 200 #-----------------------------------------------------------------------------
 201 OPTION(GDCM_VTK "Build VTK-GDCM Lib." OFF)
 202 IF(GDCM_VTK)
 203   # Search VTK
 204   FIND_PACKAGE(VTK)
 205   # If vtk found
 206   IF(VTK_FOUND)
 207     #INCLUDE(${VTK_USE_FILE})
 208     SUBDIRS(vtk)
 209   ENDIF(VTK_FOUND)
 210 ENDIF(GDCM_VTK)
 211
 212 #-----------------------------------------------------------------------------
 213 OPTION(GDCM_WRAP_PYTHON "Wrap GDCM classes into the Python language." OFF)
 214 #if wrapping enable
 215 IF(GDCM_WRAP_PYTHON)
 216   # Search Python libs:
 217   FIND_PACKAGE(PythonLibs)
 218   # If PythonLibs found
 219   IF(PYTHON_LIBRARY)
 220     SUBDIRS(gdcmPython)
 221   ENDIF(PYTHON_LIBRARY)
 222 ENDIF(GDCM_WRAP_PYTHON)
 223
 224 #-----------------------------------------------------------------------------
 225 OPTION(GDCM_DOCUMENTATION "Build source documentation using doxygen." OFF)
 226 # if doxygen enable
 227 IF(GDCM_DOCUMENTATION)
 228   # Search Doxygen:
 229   FIND_PACKAGE(Doxygen)
 230   IF(DOXYGEN)
 231     SUBDIRS(Doc)
 232   ENDIF(DOXYGEN)
 233 ENDIF(GDCM_DOCUMENTATION)
 234
 235 #-----------------------------------------------------------------------------
 236 IF(WIN32)
 237   OPTION(GDCM_INSTALLER "Build the install setup using InnoSetup." OFF)
 238   IF(GDCM_INSTALLER)
 239     SUBDIRS(Builder)
 240   ENDIF(GDCM_INSTALLER)
 241 ENDIF(WIN32)
 242