CMakeLists.txt

   1 PROJECT(GDCM)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.0)
   3
   4 #-----------------------------------------------------------------------------
   5 # GDCM version number, usefull for packaging and doxygen doc:
   6 SET(GDCM_MAJOR_VERSION 1)
   7 SET(GDCM_MINOR_VERSION 0)
   8 SET(GDCM_BUILD_VERSION 0)
   9 SET(GDCM_VERSION
  10     "${GDCM_MAJOR_VERSION}.${GDCM_MINOR_VERSION}.${GDCM_BUILD_VERSION}")
  11
  12 #-----------------------------------------------------------------------------
  13 # datadir in CMake:
  14 SET(GDCM_DATA_DIR "/share/gdcm/" CACHE INTERNAL
  15   "Install location for data (relative to prefix).")
  16 MARK_AS_ADVANCED(GDCM_DATA_DIR)
  17
  18 #-----------------------------------------------------------------------------
  19 # Build shared lib by default
  20 OPTION(BUILD_SHARED_LIBS "Build GDCM with shared libraries." ON)
  21
  22 OPTION(GDCM_DEBUG "Turn verbosity of some statement ON." OFF)
  23 MARK_AS_ADVANCED(GDCM_DEBUG)
  24
  25 #-----------------------------------------------------------------------------
  26 SET (EXECUTABLE_OUTPUT_PATH ${GDCM_BINARY_DIR}/bin CACHE PATH "Single output directory for building all executables.")
  27 SET (LIBRARY_OUTPUT_PATH ${GDCM_BINARY_DIR}/bin CACHE PATH "Single output directory for building all libraries.")
  28 MARK_AS_ADVANCED(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
  29
  30 #-----------------------------------------------------------------------------
  31 # Test if compiler defines the pseudo-macro __FUNCTION__
  32 IF("GDCM_COMPILER_HAS_FUNCTION" MATCHES "^GDCM_COMPILER_HAS_FUNCTION$")
  33   MESSAGE(STATUS "Checking support for __FUNCTION__ in compiler")
  34   TRY_COMPILE(GDCM_COMPILER_HAS_FUNCTION
  35               ${GDCM_BINARY_DIR}/CMakeTmp/Function
  36               ${GDCM_SOURCE_DIR}/CMake/gdcmTestFUNCTION.cxx
  37               OUTPUT_VARIABLE OUTPUT)
  38   IF(GDCM_COMPILER_HAS_FUNCTION)
  39     MESSAGE(STATUS "Checking support for __FUNCTION__ -- yes")
  40     SET(GDCM_COMPILER_HAS_FUNCTION 1 CACHE INTERNAL "Support for extension C __FUNCTION__")
  41     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeOutput.log
  42       "Determining if the C compiler supports __FUNCTION__ "
  43       "passed with the following output:\n"
  44       "${OUTPUT}\n" APPEND)
  45   ELSE(GDCM_COMPILER_HAS_FUNCTION)
  46     MESSAGE(STATUS "Checking support for __FUNCTION__ -- no")
  47     SET(GDCM_COMPILER_HAS_FUNCTION 0 CACHE INTERNAL "Support for extension C __FUNCTION__")
  48     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeError.log
  49       "Determining if the C compiler supports __FUNCTION__ "
  50       "failed with the following output:\n"
  51       "${OUTPUT}\n" APPEND)
  52   ENDIF(GDCM_COMPILER_HAS_FUNCTION)
  53 ENDIF("GDCM_COMPILER_HAS_FUNCTION" MATCHES "^GDCM_COMPILER_HAS_FUNCTION$")
  54
  55 #-----------------------------------------------------------------------------
  56 # Test if os defines a lenght for sockaddr
  57 IF("HAVE_SA_LEN" MATCHES "^HAVE_SA_LEN$")
  58   STRING(ASCII 35 POUND)
  59   FILE(WRITE ${GDCM_BINARY_DIR}/CMakeTmp/gdcmTestHAVESALEN.c
  60     "${POUND}include <sys/types.h>\n"
  61     "${POUND}include <sys/socket.h>\n"
  62     "int main() { struct sockaddr sa; sa.sa_len = 0; }")
  63   MESSAGE(STATUS "Checking if ifreq has a sa_len")
  64   TRY_COMPILE(HAVE_SA_LEN
  65               ${GDCM_BINARY_DIR}
  66               ${GDCM_BINARY_DIR}/CMakeTmp/gdcmTestHAVESALEN.c
  67               OUTPUT_VARIABLE OUTPUT)
  68   IF(HAVE_SA_LEN)
  69     MESSAGE(STATUS "Checking if ifreq has a sa_len -- yes")
  70     SET(HAVE_SA_LEN 1 CACHE INTERNAL "Support if ifreq has a sa_len")
  71     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeOutput.log
  72       "Determining if ifreq has a sa_len"
  73       "passed with the following output:\n"
  74       "${OUTPUT}\n" APPEND)
  75   ELSE(HAVE_SA_LEN)
  76     MESSAGE(STATUS "Checking if ifreq has a sa_len -- no")
  77     SET(HAVE_SA_LEN 0 CACHE INTERNAL "Support if ifreq has a sa_len")
  78     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeError.log
  79       "Determining if ifreq has a sa_len"
  80       "failed with the following output:\n"
  81       "${OUTPUT}\n" APPEND)
  82   ENDIF(HAVE_SA_LEN)
  83 ENDIF("HAVE_SA_LEN" MATCHES "^HAVE_SA_LEN$")
  84
  85 #-----------------------------------------------------------------------------
  86 # Build directory on which many applications depend
  87 SUBDIRS(
  88   Dicts
  89   src
  90 )
  91 #-----------------------------------------------------------------------------
  92 # Example subdir:
  93
  94 OPTION(BUILD_EXAMPLES "Build GDCM examples." ON)
  95 IF(BUILD_EXAMPLES)
  96   SUBDIRS(Example)
  97 ENDIF(BUILD_EXAMPLES)
  98
  99 #-----------------------------------------------------------------------------
 100 # Adding GDCM_DATA_ROOT
 101 FIND_PATH(GDCM_DATA_ROOT gdcm-ACR-LibIDO.acr
 102   ${GDCM_SOURCE_DIR}/../gdcmData
 103   $ENV{GDCM_DATA}
 104   $ENV{PUB_DICT_PATH}/../../gdcmData
 105 )
 106
 107 # Set the place for the public dictionary, must be set before gdcmConfigure.h
 108 SET( GDCM_PUB_DICT_PATH "${CMAKE_INSTALL_PREFIX}${GDCM_DATA_DIR}")
 109
 110 #-----------------------------------------------------------------------------
 111 # SunOS + old gcc fixes:
 112 INCLUDE (${CMAKE_ROOT}/Modules/CMakeBackwardCompatibilityCXX.cmake)
 113 IF(CMAKE_NO_ANSI_STRING_STREAM)
 114   SET(GDCM_NO_ANSI_STRING_STREAM 1)
 115 ENDIF(CMAKE_NO_ANSI_STRING_STREAM)
 116 INCLUDE (${CMAKE_ROOT}/Modules/TestBigEndian.cmake)
 117 TEST_BIG_ENDIAN(GDCM_WORDS_BIGENDIAN)
 118
 119 INCLUDE (${CMAKE_ROOT}/Modules/CheckIncludeFile.cmake)
 120 CHECK_INCLUDE_FILE("stdint.h"       CMAKE_HAVE_STDINT_H)
 121 CHECK_INCLUDE_FILE("inttypes.h"     CMAKE_HAVE_INTTYPES_H)
 122
 123 # Check if header file exists and add it to the list.
 124 INCLUDE (${CMAKE_ROOT}/Modules/CheckIncludeFiles.cmake)
 125 MACRO(CHECK_INCLUDE_FILE_CONCAT FILE VARIABLE)
 126   CHECK_INCLUDE_FILES("${GDCM_INCLUDES};${FILE}" ${VARIABLE})
 127   IF(${VARIABLE})
 128     SET(GDCM_INCLUDES ${GDCM_INCLUDES} ${FILE})
 129   ENDIF(${VARIABLE})
 130 ENDMACRO(CHECK_INCLUDE_FILE_CONCAT)
 131
 132 # Need those header for GetMacAddress in Util
 133 # This is tricky as you need to figure out the proper order to
 134 # test the inclusion of files
 135 CHECK_INCLUDE_FILE_CONCAT("unistd.h"       CMAKE_HAVE_UNISTD_H)
 136 CHECK_INCLUDE_FILE_CONCAT("stdlib.h"       CMAKE_HAVE_STDLIB_H)
 137 CHECK_INCLUDE_FILE_CONCAT("sys/ioctl.h"    CMAKE_HAVE_SYS_IOCTL_H)
 138 CHECK_INCLUDE_FILE_CONCAT("sys/socket.h"   CMAKE_HAVE_SYS_SOCKET_H)
 139 CHECK_INCLUDE_FILE_CONCAT("sys/sockio.h"   CMAKE_HAVE_SYS_SOCKIO_H)
 140 CHECK_INCLUDE_FILE_CONCAT("net/if.h"       CMAKE_HAVE_NET_IF_H)
 141 CHECK_INCLUDE_FILE_CONCAT("netinet/in.h"   CMAKE_HAVE_NETINET_IN_H)
 142 CHECK_INCLUDE_FILE_CONCAT("net/if_dl.h"    CMAKE_HAVE_NET_IF_DL_H)
 143 CHECK_INCLUDE_FILE_CONCAT("net/if_arp.h"   CMAKE_HAVE_NET_IF_ARP_H)
 144
 145 #-----------------------------------------------------------------------------
 146 # Force Big Endian emulation on little endian:
 147 OPTION(GDCM_FORCE_BIGENDIAN_EMULATION "Force Big Endian Emulation. Do use if you don't know what you are doing." OFF)
 148
 149 CONFIGURE_FILE(${GDCM_SOURCE_DIR}/gdcmConfigure.h.in
 150                ${GDCM_BINARY_DIR}/gdcmConfigure.h @ONLY IMMEDIATE)
 151
 152 INSTALL_FILES(/include .h gdcmConfigure.h)
 153
 154 #-----------------------------------------------------------------------------
 155 # Add the testing directories
 156 OPTION(BUILD_TESTING "Build testing." ON)
 157
 158 IF(BUILD_TESTING)
 159   ENABLE_TESTING()
 160   INCLUDE (${CMAKE_ROOT}/Modules/Dart.cmake)
 161   MARK_AS_ADVANCED(DART_ROOT)
 162   SUBDIRS(Testing)
 163 ENDIF(BUILD_TESTING)
 164
 165
 166 #-----------------------------------------------------------------------------
 167 OPTION(GDCM_VTK "Build VTK-GDCM Lib." OFF)
 168 IF(GDCM_VTK)
 169   # Search VTK
 170   FIND_PACKAGE(VTK)
 171   # If vtk found
 172   IF(VTK_FOUND)
 173     #INCLUDE(${VTK_USE_FILE})
 174     SUBDIRS(vtk)
 175   ENDIF(VTK_FOUND)
 176 ENDIF(GDCM_VTK)
 177
 178 #-----------------------------------------------------------------------------
 179 OPTION(GDCM_WRAP_PYTHON "Wrap GDCM classes into the Python language." OFF)
 180 #if wrapping enable
 181 IF(GDCM_WRAP_PYTHON)
 182   # Search Python libs:
 183   FIND_PACKAGE(PythonLibs)
 184   # If PythonLibs found
 185   IF(PYTHON_LIBRARY)
 186     SUBDIRS(gdcmPython)
 187   ENDIF(PYTHON_LIBRARY)
 188 ENDIF(GDCM_WRAP_PYTHON)
 189
 190 #-----------------------------------------------------------------------------
 191 OPTION(GDCM_DOCUMENTATION "Build source documentation using doxygen." OFF)
 192 # if doxygen enable
 193 IF(GDCM_DOCUMENTATION)
 194   # Search Doxygen:
 195   FIND_PACKAGE(Doxygen)
 196   IF(DOXYGEN)
 197     SUBDIRS(Doc)
 198   ENDIF(DOXYGEN)
 199 ENDIF(GDCM_DOCUMENTATION)
 200