CMakeLists.txt

   1 PROJECT(GDCM)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.0)
   3 # okay in fact you need at least cmake 2.0.4 to get swig working properly
   4
   5 #-----------------------------------------------------------------------------
   6 # GDCM version number, usefull for packaging and doxygen doc:
   7 SET(GDCM_MAJOR_VERSION 1)
   8 SET(GDCM_MINOR_VERSION 2)
   9 SET(GDCM_BUILD_VERSION 0)
  10 SET(GDCM_VERSION
  11     "${GDCM_MAJOR_VERSION}.${GDCM_MINOR_VERSION}.${GDCM_BUILD_VERSION}")
  12
  13 #-----------------------------------------------------------------------------
  14 # datadir in CMake:
  15 SET(GDCM_DATA_DIR "/share/gdcm/" CACHE INTERNAL
  16   "Install location for data (relative to prefix).")
  17 MARK_AS_ADVANCED(GDCM_DATA_DIR)
  18
  19 #-----------------------------------------------------------------------------
  20 # Provide compatibility options.
  21 OPTION(GDCM_LEGACY_REMOVE "Remove all legacy code completely." OFF)
  22 OPTION(GDCM_LEGACY_SILENT "Silence all legacy code messages." OFF)
  23 MARK_AS_ADVANCED(GDCM_LEGACY_REMOVE GDCM_LEGACY_SILENT)
  24
  25 #-----------------------------------------------------------------------------
  26 # Build shared lib by default
  27 OPTION(GDCM_BUILD_SHARED_LIBS "Build GDCM with shared libraries." ON)
  28 SET(BUILD_SHARED_LIBS ${GDCM_BUILD_SHARED_LIBS})
  29
  30 OPTION(GDCM_DEBUG "Turn verbosity of some statement ON." OFF)
  31 MARK_AS_ADVANCED(GDCM_DEBUG)
  32
  33 #-----------------------------------------------------------------------------
  34 SET (EXECUTABLE_OUTPUT_PATH ${GDCM_BINARY_DIR}/bin CACHE PATH "Single output directory for building all executables.")
  35 SET (LIBRARY_OUTPUT_PATH ${GDCM_BINARY_DIR}/bin CACHE PATH "Single output directory for building all libraries.")
  36 MARK_AS_ADVANCED(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
  37
  38 #-----------------------------------------------------------------------------
  39 # Help outside projects link against gdcm
  40
  41 EXPORT_LIBRARY_DEPENDENCIES(${GDCM_BINARY_DIR}/GDCMLibraryDepends.cmake)
  42
  43 # Save the compiler settings so another project can import them.
  44 INCLUDE(${CMAKE_ROOT}/Modules/CMakeExportBuildSettings.cmake)
  45 CMAKE_EXPORT_BUILD_SETTINGS(${GDCM_BINARY_DIR}/GDCMBuildSettings.cmake)
  46 #INSTALL_FILES(/lib/gdcm .cmake GDCMBuildSettings)
  47
  48 # For GDCM from build tree:
  49 SET(GDCM_USE_FILE ${GDCM_SOURCE_DIR}/GDCMUse.cmake)
  50 SET(GDCM_INCLUDE_DIRS
  51   ${GDCM_BINARY_DIR}/     #for gdcmConfigure.h
  52   ${GDCM_SOURCE_DIR}/src  #for main gdcm include
  53   )
  54 SET(GDCM_LIBRARY_DIRS ${LIBRARY_OUTPUT_PATH})
  55 SET(GDCM_LIBRARY_DEPENDS_FILE ${GDCM_BINARY_DIR}/GDCMLibraryDepends.cmake)
  56
  57 # For installed GDCM:
  58 SET(GDCM_USE_FILE ${CMAKE_INSTALL_PREFIX}/lib/GDCM-${GDCM_VERSION}/GDCMUse.cmake)
  59 SET(GDCM_INCLUDE_DIRS ${CMAKE_INSTALL_PREFIX}/include/GDCM-${GDCM_VERSION})
  60 SET(GDCM_LIBRARY_DIRS ${CMAKE_INSTALL_PREFIX}/lib/GDCM-${GDCM_VERSION})
  61 SET(GDCM_LIBRARY_DEPENDS_FILE ${CMAKE_INSTALL_PREFIX}/lib/GDCM-${GDCM_VERSION}/GDCMLibraryDepends.cmake)
  62 CONFIGURE_FILE(${GDCM_SOURCE_DIR}/GDCMConfig.cmake.in
  63                ${GDCM_BINARY_DIR}/GDCMConfig.cmake @ONLY IMMEDIATE)
  64
  65 #-----------------------------------------------------------------------------
  66 # Test if compiler defines the pseudo-macro __FUNCTION__
  67 IF("GDCM_COMPILER_HAS_FUNCTION" MATCHES "^GDCM_COMPILER_HAS_FUNCTION$")
  68   MESSAGE(STATUS "Checking support for __FUNCTION__ in compiler")
  69   TRY_COMPILE(GDCM_COMPILER_HAS_FUNCTION
  70               ${GDCM_BINARY_DIR}/CMakeTmp/Function
  71               ${GDCM_SOURCE_DIR}/CMake/gdcmTestFUNCTION.cxx
  72               OUTPUT_VARIABLE OUTPUT)
  73   IF(GDCM_COMPILER_HAS_FUNCTION)
  74     MESSAGE(STATUS "Checking support for __FUNCTION__ -- yes")
  75     SET(GDCM_COMPILER_HAS_FUNCTION 1 CACHE INTERNAL "Support for extension C __FUNCTION__")
  76     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeOutput.log
  77       "Determining if the C compiler supports __FUNCTION__ "
  78       "passed with the following output:\n"
  79       "${OUTPUT}\n" APPEND)
  80   ELSE(GDCM_COMPILER_HAS_FUNCTION)
  81     MESSAGE(STATUS "Checking support for __FUNCTION__ -- no")
  82     SET(GDCM_COMPILER_HAS_FUNCTION 0 CACHE INTERNAL "Support for extension C __FUNCTION__")
  83     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeError.log
  84       "Determining if the C compiler supports __FUNCTION__ "
  85       "failed with the following output:\n"
  86       "${OUTPUT}\n" APPEND)
  87   ENDIF(GDCM_COMPILER_HAS_FUNCTION)
  88 ENDIF("GDCM_COMPILER_HAS_FUNCTION" MATCHES "^GDCM_COMPILER_HAS_FUNCTION$")
  89
  90 #-----------------------------------------------------------------------------
  91 # Build directory on which many applications depend
  92 SUBDIRS(
  93   Dicts
  94   src
  95 )
  96 #-----------------------------------------------------------------------------
  97 # Example subdir:
  98
  99 OPTION(BUILD_EXAMPLES "Build GDCM examples." ON)
 100 IF(BUILD_EXAMPLES)
 101   SUBDIRS(Example)
 102 ENDIF(BUILD_EXAMPLES)
 103
 104 #-----------------------------------------------------------------------------
 105 # Adding GDCM_DATA_ROOT
 106 FIND_PATH(GDCM_DATA_ROOT gdcm-ACR-LibIDO.acr
 107   ${GDCM_SOURCE_DIR}/../gdcmData
 108   $ENV{GDCM_DATA}
 109   $ENV{PUB_DICT_PATH}/../../gdcmData
 110 )
 111
 112 # Set the place for the public dictionary, must be set before gdcmConfigure.h
 113 #SET( GDCM_PUB_DICT_PATH "${CMAKE_INSTALL_PREFIX}${GDCM_DATA_DIR}")
 114 FIND_PATH(GDCM_PUB_DICT_PATH dicomV3.dic
 115   ${GDCM_SOURCE_DIR}/Dicts
 116   $ENV{PUB_DICT_PATH}
 117 )
 118
 119 #-----------------------------------------------------------------------------
 120 # SunOS + old gcc fixes:
 121 INCLUDE (${CMAKE_ROOT}/Modules/CMakeBackwardCompatibilityCXX.cmake)
 122 IF(CMAKE_NO_ANSI_STRING_STREAM)
 123   SET(GDCM_NO_ANSI_STRING_STREAM 1)
 124 ENDIF(CMAKE_NO_ANSI_STRING_STREAM)
 125
 126 # Big endian thing:
 127 INCLUDE (${CMAKE_ROOT}/Modules/TestBigEndian.cmake)
 128 TEST_BIG_ENDIAN(GDCM_WORDS_BIGENDIAN)
 129
 130 INCLUDE (${CMAKE_ROOT}/Modules/CheckIncludeFile.cmake)
 131 CHECK_INCLUDE_FILE("stdint.h"       CMAKE_HAVE_STDINT_H)
 132 IF(UNIX) #Avoid polluting Win32 cmakecache
 133   CHECK_INCLUDE_FILE("inttypes.h"     CMAKE_HAVE_INTTYPES_H)
 134 ENDIF(UNIX)
 135
 136 # Check if header file exists and add it to the list.
 137 INCLUDE (${CMAKE_ROOT}/Modules/CheckIncludeFiles.cmake)
 138 MACRO(CHECK_INCLUDE_FILE_CONCAT FILE VARIABLE)
 139   CHECK_INCLUDE_FILES("${GDCM_INCLUDES};${FILE}" ${VARIABLE})
 140   IF(${VARIABLE})
 141     SET(GDCM_INCLUDES ${GDCM_INCLUDES} ${FILE})
 142   ENDIF(${VARIABLE})
 143 ENDMACRO(CHECK_INCLUDE_FILE_CONCAT)
 144
 145 # Need those header for GetMacAddress in Util
 146 # This is tricky as you need to figure out the proper order to
 147 # test the inclusion of files
 148 CHECK_INCLUDE_FILE_CONCAT("unistd.h"       CMAKE_HAVE_UNISTD_H)
 149 CHECK_INCLUDE_FILE_CONCAT("stdlib.h"       CMAKE_HAVE_STDLIB_H)
 150 IF(UNIX) #Avoid polluting Win32 cmakecache
 151   CHECK_INCLUDE_FILE_CONCAT("sys/ioctl.h"    CMAKE_HAVE_SYS_IOCTL_H)
 152   CHECK_INCLUDE_FILE_CONCAT("sys/socket.h"   CMAKE_HAVE_SYS_SOCKET_H)
 153   CHECK_INCLUDE_FILE_CONCAT("sys/sockio.h"   CMAKE_HAVE_SYS_SOCKIO_H)
 154   CHECK_INCLUDE_FILE_CONCAT("net/if.h"       CMAKE_HAVE_NET_IF_H)
 155   CHECK_INCLUDE_FILE_CONCAT("netinet/in.h"   CMAKE_HAVE_NETINET_IN_H)
 156   CHECK_INCLUDE_FILE_CONCAT("net/if_dl.h"    CMAKE_HAVE_NET_IF_DL_H)
 157   CHECK_INCLUDE_FILE_CONCAT("net/if_arp.h"   CMAKE_HAVE_NET_IF_ARP_H)
 158 ENDIF(UNIX)
 159
 160 #-----------------------------------------------------------------------------
 161 # Test if os defines a lenght for sockaddr
 162 # only doing the test when we have sys/socket
 163 IF( ${CMAKE_HAVE_SYS_SOCKET_H} )
 164   IF("HAVE_SA_LEN" MATCHES "^HAVE_SA_LEN$")
 165     STRING(ASCII 35 POUND)
 166     FILE(WRITE ${GDCM_BINARY_DIR}/CMakeTmp/gdcmTestHAVESALEN.c
 167       "${POUND}include <sys/types.h>\n"
 168       "${POUND}include <sys/socket.h>\n"
 169       "int main() { struct sockaddr sa; sa.sa_len = 0; }")
 170     MESSAGE(STATUS "Checking if ifreq has a sa_len")
 171     TRY_COMPILE(HAVE_SA_LEN
 172       ${GDCM_BINARY_DIR}
 173       ${GDCM_BINARY_DIR}/CMakeTmp/gdcmTestHAVESALEN.c
 174       OUTPUT_VARIABLE OUTPUT)
 175     IF(HAVE_SA_LEN)
 176       MESSAGE(STATUS "Checking if ifreq has a sa_len -- yes")
 177       SET(HAVE_SA_LEN 1 CACHE INTERNAL "Support if ifreq has a sa_len")
 178       WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeOutput.log
 179         "Determining if ifreq has a sa_len"
 180         "passed with the following output:\n"
 181         "${OUTPUT}\n" APPEND)
 182     ELSE(HAVE_SA_LEN)
 183       MESSAGE(STATUS "Checking if ifreq has a sa_len -- no")
 184       SET(HAVE_SA_LEN 0 CACHE INTERNAL "Support if ifreq has a sa_len")
 185       WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeError.log
 186         "Determining if ifreq has a sa_len"
 187         "failed with the following output:\n"
 188         "${OUTPUT}\n" APPEND)
 189     ENDIF(HAVE_SA_LEN)
 190   ENDIF("HAVE_SA_LEN" MATCHES "^HAVE_SA_LEN$")
 191 ENDIF( ${CMAKE_HAVE_SYS_SOCKET_H} )
 192
 193 #-----------------------------------------------------------------------------
 194 # Force Big Endian emulation on little endian:
 195 OPTION(GDCM_FORCE_BIGENDIAN_EMULATION "Force Big Endian Emulation. Do use if you don't know what you are doing." OFF)
 196
 197 CONFIGURE_FILE(${GDCM_SOURCE_DIR}/gdcmConfigure.h.in
 198                ${GDCM_BINARY_DIR}/gdcmConfigure.h @ONLY IMMEDIATE)
 199
 200 INSTALL_FILES(/include/gdcm .h gdcmConfigure.h)
 201 INSTALL_FILES(/lib .cmake GDCMBuildSettings  GDCMConfig  GDCMLibraryDepends)
 202
 203 #-----------------------------------------------------------------------------
 204 # Add the testing directories
 205 OPTION(BUILD_TESTING "Build testing." ON)
 206
 207 IF(BUILD_TESTING)
 208   CONFIGURE_FILE(${GDCM_SOURCE_DIR}/CMake/CTestCustom.ctest.in
 209       ${GDCM_BINARY_DIR}/CMake/CTestCustom.ctest @ONLY)
 210   ENABLE_TESTING()
 211   INCLUDE (${CMAKE_ROOT}/Modules/Dart.cmake)
 212   MARK_AS_ADVANCED(DART_ROOT)
 213   SUBDIRS(Testing)
 214 ENDIF(BUILD_TESTING)
 215
 216
 217 #-----------------------------------------------------------------------------
 218 OPTION(GDCM_VTK "Build VTK-GDCM Lib." OFF)
 219 IF(GDCM_VTK)
 220   # Search VTK
 221   FIND_PACKAGE(VTK)
 222   # If vtk found
 223   IF(VTK_FOUND)
 224     #INCLUDE(${VTK_USE_FILE})
 225     SUBDIRS(vtk)
 226   ENDIF(VTK_FOUND)
 227 ENDIF(GDCM_VTK)
 228
 229 #-----------------------------------------------------------------------------
 230 OPTION(GDCM_WRAP_PYTHON "Wrap GDCM classes into the Python language." OFF)
 231 #if wrapping enable
 232 IF(GDCM_WRAP_PYTHON)
 233   # Search Python libs:
 234   FIND_PACKAGE(PythonLibs)
 235   # If PythonLibs found
 236   IF(PYTHON_LIBRARY)
 237     SUBDIRS(gdcmPython)
 238   ENDIF(PYTHON_LIBRARY)
 239 ENDIF(GDCM_WRAP_PYTHON)
 240
 241 #-----------------------------------------------------------------------------
 242 OPTION(GDCM_DOCUMENTATION "Build source documentation using doxygen." OFF)
 243 # if doxygen enable
 244 IF(GDCM_DOCUMENTATION)
 245   # Search Doxygen:
 246   FIND_PACKAGE(Doxygen)
 247   IF(DOXYGEN)
 248     SUBDIRS(Doc)
 249   ENDIF(DOXYGEN)
 250 ENDIF(GDCM_DOCUMENTATION)
 251
 252 #-----------------------------------------------------------------------------
 253 IF(WIN32)
 254   OPTION(GDCM_INSTALLER "Build the install setup using InnoSetup." OFF)
 255 ENDIF(WIN32)
 256 IF(UNIX)
 257   OPTION(GDCM_INSTALLER "Prepare the rpmBuild use." OFF)
 258 ENDIF(UNIX)
 259 IF(GDCM_INSTALLER)
 260   SUBDIRS(Builder)
 261 ENDIF(GDCM_INSTALLER)
 262