CMakeLists.txt

   1 PROJECT(GDCM)
   2 CMAKE_MINIMUM_REQUIRED(VERSION 2.0)
   3 # okay in fact you need at least cmake 2.0.4 to get swig working properly
   4
   5 #-----------------------------------------------------------------------------
   6 # GDCM version number, usefull for packaging and doxygen doc:
   7 SET(GDCM_MAJOR_VERSION 1)
   8 SET(GDCM_MINOR_VERSION 2)
   9 SET(GDCM_BUILD_VERSION 0)
  10 SET(GDCM_VERSION
  11     "${GDCM_MAJOR_VERSION}.${GDCM_MINOR_VERSION}.${GDCM_BUILD_VERSION}")
  12
  13 #-----------------------------------------------------------------------------
  14 # datadir in CMake:
  15 SET(GDCM_DATA_DIR "/share/gdcm/" CACHE INTERNAL
  16   "Install location for data (relative to prefix).")
  17 MARK_AS_ADVANCED(GDCM_DATA_DIR)
  18
  19 #-----------------------------------------------------------------------------
  20 # Provide compatibility options.
  21 OPTION(GDCM_LEGACY_REMOVE "Remove all legacy code completely." OFF)
  22 OPTION(GDCM_LEGACY_SILENT "Silence all legacy code messages." OFF)
  23 MARK_AS_ADVANCED(GDCM_LEGACY_REMOVE GDCM_LEGACY_SILENT)
  24
  25 #-----------------------------------------------------------------------------
  26 # Build shared lib by default
  27 OPTION(GDCM_BUILD_SHARED_LIBS "Build GDCM with shared libraries." ON)
  28 SET(BUILD_SHARED_LIBS ${GDCM_BUILD_SHARED_LIBS})
  29
  30 OPTION(GDCM_DEBUG "Turn verbosity of some statement ON." OFF)
  31 MARK_AS_ADVANCED(GDCM_DEBUG)
  32
  33 #-----------------------------------------------------------------------------
  34 SET (EXECUTABLE_OUTPUT_PATH ${GDCM_BINARY_DIR}/bin CACHE PATH "Single output directory for building all executables.")
  35 SET (LIBRARY_OUTPUT_PATH ${GDCM_BINARY_DIR}/bin CACHE PATH "Single output directory for building all libraries.")
  36 MARK_AS_ADVANCED(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
  37
  38 #-----------------------------------------------------------------------------
  39 # Help outside projects link against gdcm
  40
  41 EXPORT_LIBRARY_DEPENDENCIES(${GDCM_BINARY_DIR}/GDCMLibraryDepends.cmake)
  42
  43 # Save the compiler settings so another project can import them.
  44 INCLUDE(${CMAKE_ROOT}/Modules/CMakeExportBuildSettings.cmake)
  45 CMAKE_EXPORT_BUILD_SETTINGS(${GDCM_BINARY_DIR}/GDCMBuildSettings.cmake)
  46 #INSTALL_FILES(/lib/gdcm .cmake GDCMBuildSettings)
  47
  48 # For GDCM from build tree:
  49 SET(GDCM_USE_FILE ${GDCM_SOURCE_DIR}/GDCMUse.cmake)
  50 SET(GDCM_INCLUDE_DIRS
  51   ${GDCM_BINARY_DIR}/     #for gdcmConfigure.h
  52   ${GDCM_SOURCE_DIR}/src  #for main gdcm include
  53   )
  54 SET(GDCM_LIBRARY_DIRS ${LIBRARY_OUTPUT_PATH})
  55 SET(GDCM_LIBRARY_DEPENDS_FILE ${GDCM_BINARY_DIR}/GDCMLibraryDepends.cmake)
  56
  57 # For installed GDCM:
  58 SET(GDCM_USE_FILE ${CMAKE_INSTALL_PREFIX}/lib/GDCM-${GDCM_VERSION}/GDCMUse.cmake)
  59 SET(GDCM_INCLUDE_DIRS ${CMAKE_INSTALL_PREFIX}/include/GDCM-${GDCM_VERSION})
  60 SET(GDCM_LIBRARY_DIRS ${CMAKE_INSTALL_PREFIX}/lib/GDCM-${GDCM_VERSION})
  61 SET(GDCM_LIBRARY_DEPENDS_FILE ${CMAKE_INSTALL_PREFIX}/lib/GDCM-${GDCM_VERSION}/GDCMLibraryDepends.cmake)
  62 CONFIGURE_FILE(${GDCM_SOURCE_DIR}/GDCMConfig.cmake.in
  63                ${GDCM_BINARY_DIR}/GDCMConfig.cmake @ONLY IMMEDIATE)
  64
  65 #-----------------------------------------------------------------------------
  66 # Test if compiler defines the pseudo-macro __FUNCTION__
  67 IF("GDCM_COMPILER_HAS_FUNCTION" MATCHES "^GDCM_COMPILER_HAS_FUNCTION$")
  68   MESSAGE(STATUS "Checking support for __FUNCTION__ in compiler")
  69   TRY_COMPILE(GDCM_COMPILER_HAS_FUNCTION
  70               ${GDCM_BINARY_DIR}/CMakeTmp/Function
  71               ${GDCM_SOURCE_DIR}/CMake/gdcmTestFUNCTION.cxx
  72               OUTPUT_VARIABLE OUTPUT)
  73   IF(GDCM_COMPILER_HAS_FUNCTION)
  74     MESSAGE(STATUS "Checking support for __FUNCTION__ -- yes")
  75     SET(GDCM_COMPILER_HAS_FUNCTION 1 CACHE INTERNAL "Support for extension C __FUNCTION__")
  76     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeOutput.log
  77       "Determining if the C compiler supports __FUNCTION__ "
  78       "passed with the following output:\n"
  79       "${OUTPUT}\n" APPEND)
  80   ELSE(GDCM_COMPILER_HAS_FUNCTION)
  81     MESSAGE(STATUS "Checking support for __FUNCTION__ -- no")
  82     SET(GDCM_COMPILER_HAS_FUNCTION 0 CACHE INTERNAL "Support for extension C __FUNCTION__")
  83     WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeError.log
  84       "Determining if the C compiler supports __FUNCTION__ "
  85       "failed with the following output:\n"
  86       "${OUTPUT}\n" APPEND)
  87   ENDIF(GDCM_COMPILER_HAS_FUNCTION)
  88 ENDIF("GDCM_COMPILER_HAS_FUNCTION" MATCHES "^GDCM_COMPILER_HAS_FUNCTION$")
  89
  90 #-----------------------------------------------------------------------------
  91 # Build directory on which many applications depend
  92 SUBDIRS(
  93   Dicts
  94   src
  95 )
  96 #-----------------------------------------------------------------------------
  97 # Example subdir:
  98
  99 OPTION(BUILD_EXAMPLES "Build GDCM examples." ON)
 100 IF(BUILD_EXAMPLES)
 101   SUBDIRS(Example)
 102 ENDIF(BUILD_EXAMPLES)
 103
 104 #-----------------------------------------------------------------------------
 105 # Adding GDCM_DATA_ROOT
 106 FIND_PATH(GDCM_DATA_ROOT gdcm-ACR-LibIDO.acr
 107   ${GDCM_SOURCE_DIR}/../gdcmData
 108   $ENV{GDCM_DATA}
 109   $ENV{PUB_DICT_PATH}/../../gdcmData
 110 )
 111
 112 # Set the place for the public dictionary, must be set before gdcmConfigure.h
 113 #SET( GDCM_PUB_DICT_PATH "${CMAKE_INSTALL_PREFIX}${GDCM_DATA_DIR}")
 114 FIND_PATH(GDCM_PUB_DICT_PATH dicomV3.dic
 115   ${GDCM_SOURCE_DIR}/Dicts
 116   $ENV{PUB_DICT_PATH}
 117 )
 118
 119 #-----------------------------------------------------------------------------
 120 # SunOS + old gcc fixes:
 121 INCLUDE (${CMAKE_ROOT}/Modules/CMakeBackwardCompatibilityCXX.cmake)
 122 IF(CMAKE_NO_ANSI_STRING_STREAM)
 123   SET(GDCM_NO_ANSI_STRING_STREAM 1)
 124 ENDIF(CMAKE_NO_ANSI_STRING_STREAM)
 125
 126 # Big endian thing:
 127 INCLUDE (${CMAKE_ROOT}/Modules/TestBigEndian.cmake)
 128 TEST_BIG_ENDIAN(GDCM_WORDS_BIGENDIAN)
 129
 130 INCLUDE (${CMAKE_ROOT}/Modules/CheckIncludeFile.cmake)
 131 CHECK_INCLUDE_FILE("stdint.h"       CMAKE_HAVE_STDINT_H)
 132 IF(UNIX) #Avoid polluting Win32 cmakecache
 133   CHECK_INCLUDE_FILE("inttypes.h"     CMAKE_HAVE_INTTYPES_H)
 134 ENDIF(UNIX)
 135 # Special Time support, two convention: *NIX vs Win32
 136 CHECK_INCLUDE_FILE("sys/times.h"     CMAKE_HAVE_SYS_TIMES_H)
 137 CHECK_INCLUDE_FILE("sys/timeb.h"     CMAKE_HAVE_SYS_TIMEB_H)
 138
 139 # Check if header file exists and add it to the list.
 140 INCLUDE (${CMAKE_ROOT}/Modules/CheckIncludeFiles.cmake)
 141 MACRO(CHECK_INCLUDE_FILE_CONCAT FILE VARIABLE)
 142   CHECK_INCLUDE_FILES("${GDCM_INCLUDES};${FILE}" ${VARIABLE})
 143   IF(${VARIABLE})
 144     SET(GDCM_INCLUDES ${GDCM_INCLUDES} ${FILE})
 145   ENDIF(${VARIABLE})
 146 ENDMACRO(CHECK_INCLUDE_FILE_CONCAT)
 147
 148 # Need those header for GetMacAddress in Util
 149 # This is tricky as you need to figure out the proper order to
 150 # test the inclusion of files
 151 CHECK_INCLUDE_FILE_CONCAT("unistd.h"       CMAKE_HAVE_UNISTD_H)
 152 CHECK_INCLUDE_FILE_CONCAT("stdlib.h"       CMAKE_HAVE_STDLIB_H)
 153 IF(UNIX) #Avoid polluting Win32 cmakecache
 154   CHECK_INCLUDE_FILE_CONCAT("sys/ioctl.h"    CMAKE_HAVE_SYS_IOCTL_H)
 155   CHECK_INCLUDE_FILE_CONCAT("sys/socket.h"   CMAKE_HAVE_SYS_SOCKET_H)
 156   CHECK_INCLUDE_FILE_CONCAT("sys/sockio.h"   CMAKE_HAVE_SYS_SOCKIO_H)
 157   CHECK_INCLUDE_FILE_CONCAT("net/if.h"       CMAKE_HAVE_NET_IF_H)
 158   CHECK_INCLUDE_FILE_CONCAT("netinet/in.h"   CMAKE_HAVE_NETINET_IN_H)
 159   CHECK_INCLUDE_FILE_CONCAT("net/if_dl.h"    CMAKE_HAVE_NET_IF_DL_H)
 160   CHECK_INCLUDE_FILE_CONCAT("net/if_arp.h"   CMAKE_HAVE_NET_IF_ARP_H)
 161 ENDIF(UNIX)
 162
 163 #-----------------------------------------------------------------------------
 164 # Test if os defines a lenght for sockaddr
 165 # only doing the test when we have sys/socket
 166 IF( ${CMAKE_HAVE_SYS_SOCKET_H} )
 167   IF("HAVE_SA_LEN" MATCHES "^HAVE_SA_LEN$")
 168     STRING(ASCII 35 POUND)
 169     FILE(WRITE ${GDCM_BINARY_DIR}/CMakeTmp/gdcmTestHAVESALEN.c
 170       "${POUND}include <sys/types.h>\n"
 171       "${POUND}include <sys/socket.h>\n"
 172       "int main() { struct sockaddr sa; sa.sa_len = 0; }")
 173     MESSAGE(STATUS "Checking if ifreq has a sa_len")
 174     TRY_COMPILE(HAVE_SA_LEN
 175       ${GDCM_BINARY_DIR}
 176       ${GDCM_BINARY_DIR}/CMakeTmp/gdcmTestHAVESALEN.c
 177       OUTPUT_VARIABLE OUTPUT)
 178     IF(HAVE_SA_LEN)
 179       MESSAGE(STATUS "Checking if ifreq has a sa_len -- yes")
 180       SET(HAVE_SA_LEN 1 CACHE INTERNAL "Support if ifreq has a sa_len")
 181       WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeOutput.log
 182         "Determining if ifreq has a sa_len"
 183         "passed with the following output:\n"
 184         "${OUTPUT}\n" APPEND)
 185     ELSE(HAVE_SA_LEN)
 186       MESSAGE(STATUS "Checking if ifreq has a sa_len -- no")
 187       SET(HAVE_SA_LEN 0 CACHE INTERNAL "Support if ifreq has a sa_len")
 188       WRITE_FILE(${CMAKE_BINARY_DIR}/CMakeError.log
 189         "Determining if ifreq has a sa_len"
 190         "failed with the following output:\n"
 191         "${OUTPUT}\n" APPEND)
 192     ENDIF(HAVE_SA_LEN)
 193   ENDIF("HAVE_SA_LEN" MATCHES "^HAVE_SA_LEN$")
 194 ENDIF( ${CMAKE_HAVE_SYS_SOCKET_H} )
 195
 196 #-----------------------------------------------------------------------------
 197 # Force Big Endian emulation on little endian:
 198 OPTION(GDCM_FORCE_BIGENDIAN_EMULATION "Force Big Endian Emulation. Do use if you don't know what you are doing." OFF)
 199
 200 CONFIGURE_FILE(${GDCM_SOURCE_DIR}/gdcmConfigure.h.in
 201                ${GDCM_BINARY_DIR}/gdcmConfigure.h @ONLY IMMEDIATE)
 202
 203 INSTALL_FILES(/include/gdcm .h gdcmConfigure.h)
 204 INSTALL_FILES(/lib .cmake GDCMBuildSettings  GDCMConfig  GDCMLibraryDepends)
 205
 206 #-----------------------------------------------------------------------------
 207 # Add the testing directories
 208 OPTION(BUILD_TESTING "Build testing." ON)
 209
 210 IF(BUILD_TESTING)
 211   CONFIGURE_FILE(${GDCM_SOURCE_DIR}/CMake/CTestCustom.ctest.in
 212       ${GDCM_BINARY_DIR}/CMake/CTestCustom.ctest @ONLY)
 213   ENABLE_TESTING()
 214   INCLUDE (${CMAKE_ROOT}/Modules/Dart.cmake)
 215   MARK_AS_ADVANCED(DART_ROOT)
 216   SUBDIRS(Testing)
 217 ENDIF(BUILD_TESTING)
 218
 219
 220 #-----------------------------------------------------------------------------
 221 OPTION(GDCM_VTK "Build VTK-GDCM Lib." OFF)
 222 IF(GDCM_VTK)
 223   # Search VTK
 224   FIND_PACKAGE(VTK)
 225   # If vtk found
 226   IF(VTK_FOUND)
 227     #INCLUDE(${VTK_USE_FILE})
 228     SUBDIRS(vtk)
 229   ENDIF(VTK_FOUND)
 230 ENDIF(GDCM_VTK)
 231
 232 #-----------------------------------------------------------------------------
 233 OPTION(GDCM_WRAP_PYTHON "Wrap GDCM classes into the Python language." OFF)
 234 #if wrapping enable
 235 IF(GDCM_WRAP_PYTHON)
 236   # Search Python libs:
 237   FIND_PACKAGE(PythonLibs)
 238   # If PythonLibs found
 239   IF(PYTHON_LIBRARY)
 240     SUBDIRS(gdcmPython)
 241   ENDIF(PYTHON_LIBRARY)
 242 ENDIF(GDCM_WRAP_PYTHON)
 243
 244 #-----------------------------------------------------------------------------
 245 OPTION(GDCM_DOCUMENTATION "Build source documentation using doxygen." OFF)
 246 # if doxygen enable
 247 IF(GDCM_DOCUMENTATION)
 248   # Search Doxygen:
 249   FIND_PACKAGE(Doxygen)
 250   IF(DOXYGEN)
 251     SUBDIRS(Doc)
 252   ENDIF(DOXYGEN)
 253 ENDIF(GDCM_DOCUMENTATION)
 254
 255 #-----------------------------------------------------------------------------
 256 IF(WIN32)
 257   OPTION(GDCM_INSTALLER "Build the install setup using InnoSetup." OFF)
 258 ENDIF(WIN32)
 259 IF(UNIX)
 260   OPTION(GDCM_INSTALLER "Prepare the rpmBuild use." OFF)
 261 ENDIF(UNIX)
 262 IF(GDCM_INSTALLER)
 263   SUBDIRS(Builder)
 264 ENDIF(GDCM_INSTALLER)
 265